`bicep(BCP338)` when dynamically building inputs in `.bicepparam` files to reduce duplication

[DrEsteban]

Bicep version
Bicep CLI version 0.29.47 (132ade51bc)

Describe the bug
To reduce duplication, I attempted to dynamically build a parameter in a .bicepparam file using vars, [for]s, and array functions which appears to be valid according to documentation. However it resulted in error:

Failed to evaluate parameter "<foo>": Unhandled exception during evaluating template language function 'variables' is not handled. bicep(BCP338)

To Reproduce
deploy.bicep

@export()
type FleetConfig = {
  namePrefix: string
  sku: string
  capacity: int
  clusteringPolicy: ClusteringPolicy
}

param testMatrix FleetConfig[]

output testMatrix

deploy.bicepparams

using './deploy.bicep'

var matrix = [
  {
    namePrefix: 'e10impactx4'
    sku: 'Enterprise_E10'
    capacity: 4
  }
  {
    namePrefix: 'e10impact'
    sku: 'Enterprise_E10'
    capacity: 2
  }
  {
    namePrefix: 'e5impactx4'
    sku: 'Enterprise_E5'
    capacity: 4
  }
  {
    namePrefix: 'e5impact'
    sku: 'Enterprise_E5'
    capacity: 2
  }
]
var type1 = [for item in matrix: {
  namePrefix: item.namePrefix
  sku: item.sku
  capacity: item.capacity
  clusteringPolicy: 'EnterpriseCluster'
}]
var type2 = [for item in matrix: {
  namePrefix: '${item.namePrefix}-ent'
  sku: item.sku
  capacity: item.capacity
  clusteringPolicy: 'OSSCluster'
}]
param testMatrix = concat(type1, type2) // <- doesn't work

Additional context
Basically, I wanted to build a test matrix input where all items had the same properties except for clusteringPolicy. I tried restructuring the above lots of ways, but none of them worked 😢 In the end I had to manually copy/paste/update.

Note, though, that the following does work:

var matrix = [
  {
    namePrefix: 'e10impactx4'
    sku: 'Enterprise_E10'
    capacity: 4
  }
  {
    namePrefix: 'e10impact'
    sku: 'Enterprise_E10'
    capacity: 2
  }
  {
    namePrefix: 'e5impactx4'
    sku: 'Enterprise_E5'
    capacity: 4
  }
  {
    namePrefix: 'e5impact'
    sku: 'Enterprise_E5'
    capacity: 2
  }
]

param textMatrix = concat(matrix, matrix)

So it doesn't seem to be a fundamental limitation of .bicepparam files. (The ability to concatenate arrays.) The system just doesn't like when I try to dynamically build the different sub-arrays with a [for] loop.

[anthony-c-martin]

FWIW you could probably use the map function instead as a workaround:

using './deploy.bicep'

var matrix = [
  {
    namePrefix: 'e10impactx4'
    sku: 'Enterprise_E10'
    capacity: 4
  }
  {
    namePrefix: 'e10impact'
    sku: 'Enterprise_E10'
    capacity: 2
  }
  {
    namePrefix: 'e5impactx4'
    sku: 'Enterprise_E5'
    capacity: 4
  }
  {
    namePrefix: 'e5impact'
    sku: 'Enterprise_E5'
    capacity: 2
  }
]
var type1 = map(matrix, item => {
  namePrefix: item.namePrefix
  sku: item.sku
  capacity: item.capacity
  clusteringPolicy: 'EnterpriseCluster'
})
var type2 = map(matrix, item => {
  namePrefix: '${item.namePrefix}-ent'
  sku: item.sku
  capacity: item.capacity
  clusteringPolicy: 'OSSCluster'
})

param testMatrix = concat(type1, type2)

[DrEsteban]

That worked!! Thanks @anthony-c-martin! I'll be keeping this option in mind in the future.

Do you agree my original approach should be valid, intuitively? Or at least have a better error message to direct the user?

[anthony-c-martin]

Do you agree my original approach should be valid, intuitively? Or at least have a better error message to direct the user?

Yes, completely agree that intuitively it should work - we either need to fix the underlying problem, or improve the error message. I just wanted to unblock you with a workaround while we investigate further!

[cedricbraekevelt]

@anthony-c-martin is it correct that this issue is not yet fixed in 0.34.44? I have used 3 files:

• shared.bicep which contains:

targetScope = 'subscription'

@export()
var location = deployment().location

@export()
var deploymentResourceGroup = 'rg-deployment-prd-westeurope'

-main.bicep which contains:

param test string

• main.bicepparam which contains:

using 'main.bicep'

import {location, deploymentResourceGroup}  from 'shared.bicep'

param test = location

With location it gives me the error (BCP338):

With deploymentResourceGroup it gives no error:

If I try the above without bicepparam (and the parameters switched to (types) vars everything seems to work fine :)
I suppose the error is also related to the use of a function in the assignment of the variable?

[anthony-c-martin]

@cedricbraekevelt could you create a separate issue for this? Although the error code (BCP388) is the same, I believe it's caused by a different issue.