Installer.iss

; Script generated by the Inno Setup Script Wizard.
; SEE THE DOCUMENTATION FOR DETAILS ON CREATING INNO SETUP SCRIPT FILES!

#define MyAppName "Falco Engine"
#define MyAppVersion "2.6.0.2"
#define MyAppPublisher "Falco Software Company"
#define MyAppURL "http://www.falcoware.com/"
#define MyAppExeName "Editor.exe"

[Setup]
; NOTE: The value of AppId uniquely identifies this application.
; Do not use the same AppId value in installers for other applications.
; (To generate a new GUID, click Tools | Generate GUID inside the IDE.)
AppId={{5B3081A6-7090-4DF5-8604-ED4F6AEDF37C}
AppName={#MyAppName}
AppVersion={#MyAppVersion}
;AppVerName={#MyAppName} {#MyAppVersion}
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}
AppUpdatesURL={#MyAppURL}
DefaultDirName={pf}\{#MyAppName}
DisableProgramGroupPage=yes
OutputBaseFilename=FalcoEngineSetup
SetupIconFile=Editor\res\Editor.ico
WizardImageFile=x64\Logo\back_picture.bmp
WizardSmallImageFile=x64\Logo\Logo.bmp
Compression=lzma
SolidCompression=yes
DisableWelcomePage=no

[Languages]
Name: "english"; MessagesFile: "compiler:Default.isl"

[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked

[Components]
Name: "Editor"; Description: "Editor"; Types: full compact custom; Flags: fixed
Name: "DemoProject"; Description: "Demo Project"; Types: full;

[Files]
Source: "x64\Release\Editor.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "Mono\*"; DestDir: "{app}\Mono\"; Flags: ignoreversion recursesubdirs createallsubdirs
Source: "x64\Release\Editor\*"; DestDir: "{app}\Editor\"; Flags: ignoreversion recursesubdirs createallsubdirs
Source: "x64\Release\BuiltinResources\*"; DestDir: "{app}\BuiltinResources\"; Flags: ignoreversion recursesubdirs createallsubdirs
Source: "x64\Release\Editor.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "x64\Release\FalcoEngine.dll"; DestDir: "{app}"; Flags: ignoreversion
Source: "x64\Release\Mono_installer.conf"; DestDir: "{app}"; DestName: "Mono.conf"; Flags: ignoreversion;
Source: "Ogre\source\LICENSE"; DestDir: "{app}\License"; DestName: "OGRE3D_License.txt"; Flags: ignoreversion;
Source: "x64\Release\mono-2.0-sgen.dll"; DestDir: "{app}"; Flags: ignoreversion
Source: "x64\Release\cg.dll"; DestDir: "{app}"; Flags: ignoreversion
Source: "x64\Release\Player.exe"; DestDir: "{app}"; Flags: ignoreversion
Source: "x64\Release\SDL2.dll"; DestDir: "{app}"; Flags: ignoreversion
Source: "x64\Release\OpenAL32.dll"; DestDir: "{app}"; Flags: ignoreversion
Source: "x64\Release\wrap_oal.dll"; DestDir: "{app}"; Flags: ignoreversion
Source: "x64\Release\freetype.dll"; DestDir: "{app}"; Flags: ignoreversion
;Source: "OpenAL\installer\oalinst.exe"; DestDir: "{app}\Redist\"; Flags: ignoreversion
Source: "TestProject\*"; DestDir: {code:GetDataDir}; Flags: ignoreversion recursesubdirs createallsubdirs; Components: DemoProject
; NOTE: Don't use "Flags: ignoreversion" on any shared system files

[Icons]
Name: "{commonprograms}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"
Name: "{commondesktop}\{#MyAppName}"; Filename: "{app}\{#MyAppExeName}"; Tasks: desktopicon

[Run]
;Filename: "{app}\Redist\oalinst.exe"; Description: Install Open AL; Flags: shellexec waituntilterminated postinstall
Filename: "{app}\{#MyAppExeName}"; Description: "{cm:LaunchProgram,{#StringChange(MyAppName, '&', '&&')}}"; Flags: shellexec nowait postinstall skipifsilent

[Code]
var
  DataDirPage: TInputDirWizardPage;
  DemoProjectPageID: Integer;

procedure InitializeWizard;
begin
  DataDirPage := CreateInputDirPage(wpSelectComponents,
        'Select demo project directory', 'Where should demo project files be installed?',
        'Select the folder in which Setup should install demo project files, then click Next.',
        False, '');
   DataDirPage.Add('Demo project installation directory');
   DataDirPage.Values[0] := GetPreviousData('DemoProject', '');
   DemoProjectPageID := DataDirPage.ID;
end;

function NextButtonClick(CurPageID: Integer): Boolean;
begin
 if DataDirPage <> nil then begin
  if DataDirPage.Values[0] = '' then
     DataDirPage.Values[0] := ExpandConstant('{sd}\DemoProject');
 end;
  Result := True;
end;

function ShouldSkipPage(PageID: Integer): Boolean;
begin
  Result := False;
  if PageID = DemoProjectPageID then
    Result := not IsComponentSelected('DemoProject');
end;

procedure RegisterPreviousData(PreviousDataKey: Integer);
begin
  // Store the selected folder for further reinstall/upgrade
  SetPreviousData(PreviousDataKey, 'DemoProject', DataDirPage.Values[0]);
end;

function UpdateReadyMemo(Space, NewLine, MemoUserInfoInfo, MemoDirInfo, MemoTypeInfo,
  MemoComponentsInfo, MemoGroupInfo, MemoTasksInfo: String): String;
var
  S: String;
begin
  // Fill the 'Ready Memo' with the normal settings and the custom settings
  S := '';
  S := S + MemoDirInfo + NewLine + NewLine;

  if IsComponentSelected('DemoProject') then begin
  S := S + 'Demo Project path' + NewLine;
  S := S + Space + DataDirPage.Values[0] + NewLine;
  end;

  Result := S;
end;

function GetDataDir(Param: String): String;
begin
  { Return the selected DataDir }
  Result := DataDirPage.Values[0];
end;