cantus/flake.nix at main · CodedNil/cantus · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
{
  description = "A beautiful interactive music widget for wayland";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    systems.url = "github:nix-systems/default-linux";
  };

  outputs =
    {
      self,
      nixpkgs,
      systems,
      ...
    }:
    let
      inherit (nixpkgs) lib;
      eachSystem = f: lib.genAttrs (import systems) (system: f nixpkgs.legacyPackages.${system});
    in
    {
      devShells = eachSystem (pkgs: {
        default = pkgs.mkShell {
          name = "cantus";
          inputsFrom = [ self.packages.${pkgs.stdenv.system}.cantus ];
          packages = with pkgs; [
            rustfmt
            clippy
          ];
          shellHook = ''
            export LD_LIBRARY_PATH=${
              pkgs.lib.makeLibraryPath [
                pkgs.wayland
                pkgs.vulkan-loader
                pkgs.libxkbcommon
              ]
            }:$LD_LIBRARY_PATH
          '';
        };
      });

      packages = eachSystem (pkgs: {
        default = self.packages.${pkgs.stdenv.system}.cantus;
        cantus = pkgs.callPackage ./nix/package.nix { };
      });

      homeManagerModules = {
        default = self.homeManagerModules.cantus;
        cantus = import ./nix/module.nix { inherit self; };
      };
    };
}