ftc-split-deploy/build.gradle at main · CycleZLab/ftc-split-deploy · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
plugins {
    id 'groovy'
    id 'java-gradle-plugin'
    id 'maven-publish'
}

group = 'dev.splitdeploy'
// In CI a release tag like v0.1.0 overrides this; keep it as the next
// planned version for local/composite-build use.
def refName = System.getenv('GITHUB_REF_NAME')
version = (refName ==~ /v\d.*/) ? refName.substring(1) : '0.1.0'

repositories {
    mavenCentral()
}

// `publishAllPublicationsToStagingRepository` lays out a Maven repo in
// build/staging-repo; CI appends it to the gh-pages branch, which GitHub
// Pages serves at https://repo.cyclezlab.com.
publishing {
    repositories {
        maven {
            name = 'staging'
            url = layout.buildDirectory.dir('staging-repo')
        }
    }
}

gradlePlugin {
    website = 'https://github.com/CycleZLab/ftc-split-deploy'
    vcsUrl = 'https://github.com/CycleZLab/ftc-split-deploy'
    plugins {
        splitDeploy {
            id = 'ftc.splitdeploy'
            implementationClass = 'dev.splitdeploy.SplitDeploySettingsPlugin'
            displayName = 'FTC Split Deploy'
            description = 'Fast TeamCode iteration for FTC: packages TeamCode as a split APK and partially installs only that split (a few hundred KB) instead of reinstalling the whole Robot Controller app. Uses only official Android mechanisms (package-manager split sessions) — no custom classloaders.'
        }
    }
}