umadb-java-client/build.gradle at main · DomenicDev/umadb-java-client · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
plugins {
    id 'java'
    id 'com.google.protobuf' version '0.10.0'
    id "com.vanniktech.maven.publish" version "0.36.0"
}

group = 'io.umadb'
version = '0.6-SNAPSHOT'

repositories {
    mavenCentral()
}

def grpcVersion = '1.80.0'
def protocVersion = '3.25.8'
def junitVersion = '6.0.3'
def testcontainersVersion = '2.0.5'

dependencies {
    implementation "io.grpc:grpc-netty-shaded:${grpcVersion}"
    implementation "io.grpc:grpc-protobuf:${grpcVersion}"
    implementation "io.grpc:grpc-stub:${grpcVersion}"

    testImplementation platform("org.junit:junit-bom:${junitVersion}")
    testImplementation 'org.junit.jupiter:junit-jupiter'
    testImplementation "org.testcontainers:testcontainers-junit-jupiter:${testcontainersVersion}"
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

test {
    useJUnitPlatform()
}

protobuf {
    protoc {
        // This pulls the Protobuf compiler version from Maven Central
        artifact = "com.google.protobuf:protoc:${protocVersion}"
    }
    plugins {
        grpc {
            // The gRPC Java code generator
            artifact = "io.grpc:protoc-gen-grpc-java:${grpcVersion}"
        }
    }
    generateProtoTasks {
        all().each { task ->
            task.plugins {
                grpc {}
            }
        }
    }
}

mavenPublishing {

    coordinates("io.github.domenicdev", "umadb-java-client", version.toString())

    pom {
        name = "UmaDB Java Client"
        description = "Thin Java client and wrapper for UmaDB's gRPC API"
        inceptionYear = "2026"
        url = "https://github.com/DomenicDev/umadb-java-client"
        licenses {
            license {
                name = "The Apache License, Version 2.0"
                url = "http://www.apache.org/licenses/LICENSE-2.0.txt"
                distribution = "http://www.apache.org/licenses/LICENSE-2.0.txt"
            }
        }
        developers {
            developer {
                id = "domenicdev"
                name = "Domenic Cassisi"
                url = "https://github.com/DomenicDev"
            }
        }
        scm {
            url = "https://github.com/DomenicDev/umadb-java-client"
            connection = "scm:git:git://github.com/DomenicDev/umadb-java-client.git"
            developerConnection = "scm:git:ssh://git@github.com:DomenicDev/umadb-java-client.git"
        }
    }
}