EmbeddedKit/CMakeLists.txt at master · EmbeddedKitOrg/EmbeddedKit · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
cmake_minimum_required(VERSION 3.20)

list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")

set(CMAKE_PROJECT_NAME demo0)

project(${CMAKE_PROJECT_NAME})

enable_language(C CXX ASM)

set(CMAKE_EXPORT_COMPILE_COMMANDS ON CACHE BOOL "Export compile commands" FORCE)

if("${CMAKE_GENERATOR}" MATCHES "Ninja")
    message(STATUS "Build Generator is Ninja, forcing colored diagnostics.")
    add_compile_options($<$<COMPILE_LANGUAGE:C,CXX>:-fdiagnostics-color=always>)
endif()

# 全局宏定义 (Global Macros)
add_library(global_macros INTERFACE)

target_include_directories(global_macros INTERFACE
    ${CMAKE_CURRENT_SOURCE_DIR}
)

target_compile_definitions(global_macros INTERFACE
    $<$<CONFIG:Debug>:DEBUG>
    $<$<CONFIG:Release>:NDEBUG>

    # 可以像这样拓展MCU
    $<$<STREQUAL:"${MCU_MODEL}","STM32F429ZIT6_GCC">:USE_STM32F429>
    $<$<STREQUAL:"${MCU_MODEL}","GD32F470ZGT6">:USE_GD32F470>
    # 在这里添加你的全局宏
)

# 全局编译选项
add_library(global_options INTERFACE)
target_compile_options(global_options INTERFACE
    -Wall
    -Wextra

    $<$<COMPILE_LANGUAGE:C>:-std=c11>
    $<$<COMPILE_LANGUAGE:CXX>:-std=c++17>

    # 可以在这里添加 MCU 架构参数，或者在 Toolchain 文件中定义

    $<$<CONFIG:Debug>:-O0 -g3>
    $<$<CONFIG:Release>:-O3>
)

# 统一输出目录配置
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/lib)
set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)

# 生成最终固件
set(EMPTY_OBJ ${CMAKE_CURRENT_SOURCE_DIR}/ek_empty_obj.c)

add_executable(${CMAKE_PROJECT_NAME} ${EMPTY_OBJ})

# 设置输出文件名
set_target_properties(${CMAKE_PROJECT_NAME} PROPERTIES OUTPUT_NAME ${CMAKE_PROJECT_NAME})

# 添加子目录
add_subdirectory(L0_Assets)
add_subdirectory(L1_MCU)
# L1_MCU 子目录已生成链接脚本并更新了 LINKER_SCRIPT，在此应用
target_link_options(${CMAKE_PROJECT_NAME} PRIVATE "-T${LINKER_SCRIPT}")
add_subdirectory(L2_Core)
add_subdirectory(L3_Middlewares)
add_subdirectory(L4_Components)
add_subdirectory(L5_App)

target_link_libraries(${CMAKE_PROJECT_NAME}
    $<TARGET_OBJECTS:l5_app>
    $<TARGET_OBJECTS:l4_components>
    l3_middlewares
    $<TARGET_OBJECTS:l2_core>
    $<TARGET_OBJECTS:l1_mcu>
    $<TARGET_OBJECTS:l0_assets>

    global_macros
    global_options
)

# 生成 Hex/Bin/Size
add_custom_command(TARGET ${CMAKE_PROJECT_NAME} POST_BUILD
    COMMAND ${CMAKE_OBJCOPY} -O ihex $<TARGET_FILE:${CMAKE_PROJECT_NAME}> ${CMAKE_PROJECT_NAME}.hex
    COMMAND ${CMAKE_OBJCOPY} -O binary $<TARGET_FILE:${CMAKE_PROJECT_NAME}> ${CMAKE_PROJECT_NAME}.bin
    COMMAND ${CMAKE_SIZE} $<TARGET_FILE:${CMAKE_PROJECT_NAME}>
    COMMENT "Generating BIN/HEX and printing size"
)