Windows-SSO/SSO.Windows.pas at main · GDKsoftware/Windows-SSO · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86

unit SSO.Windows;

interface

uses
  SSO.Interfaces;

type
  TSSOWindows = class(TInterfacedObject, ISSOComposite)
  private
    FFallbackMode: TFallbackMode;
  public
    constructor Create; overload;
    constructor Create(const FallbackMode: TFallbackMode); overload;

    procedure SetFallbackMode(const Mode: TFallbackMode);

    function GetUPN: string;
    function GetUserInfo: IWindowsUserInfo;
  end;

implementation

uses
  SSO.NetAPI32, SSO.Secur32, SSO.Envvars, SSO.WindowsUserInfo;

{ TSSOWindows }

constructor TSSOWindows.Create;
begin
  Create(TFallbackMode.Minimal);
end;

constructor TSSOWindows.Create(const FallbackMode: TFallbackMode);
begin
  inherited Create;

  FFallbackMode := FallbackMode;
end;

procedure TSSOWindows.SetFallbackMode(const Mode: TFallbackMode);
begin
  FFallbackMode := Mode;
end;

function TSSOWindows.GetUPN: string;
var
  UserInfo: IWindowsUserInfo;
begin
  UserInfo := GetUserInfo;

  if UserInfo.UserFound then
    Result := UserInfo.FullQualifiedUserName
  else
    raise ESSOException.Create('Could not determine the current Windows user.');
end;

function TSSOWindows.GetUserInfo: IWindowsUserInfo;
var
  Username, Domain: string;
  SecurQuery: ISSOQuery;
  NTQuery: ISSOQuery;
  EnvQuery: ISSOQuery;
  UserFound: Boolean;
begin
  SecurQuery := TSSOSecur32Query.Create;
  UserFound := SecurQuery.TryGetUsername(Username, Domain);

  if not(UserFound) then
  begin
    NTQuery := TSSONetAPI32Query.Create;
    UserFound := NTQuery.TryGetUsername(Username, Domain);
  end;

  if not(UserFound) and (FFallbackMode = TFallbackMode.AlwaysReturnSomething) then
  begin
    EnvQuery := TSSOEnvvarsQuery.Create;

    UserFound := EnvQuery.TryGetUsername(Username, Domain);
  end;

  Result := TWindowsUserInfo.Create(Username, Domain, UserFound);
end;

end.