Create new document

[DitriXNew]

При создании документа в метадатах:

• Тип кода - Число
• Длина - 12
• Включить в подсистему
• Create on input = Don`t use
• RealTimePosting = Disable
• Добавить в журнал документов AllDocuments
• Добавить документ в состав критерий отбора RelatedDocuments и одноименную команду там же
• Снять у FullAccess право непосредственного удаления документов
• Добавить в роль FilterForUserSettings Read и View
• Добавить в роль FullAccessInArea все роли кроме удаления
• Добавить в роль FullAccessOnlyRead доступ Read и View, и просмотры истории изменения данных
• Добавить документ в план обмена FullExchange, и убрать авторегистрацию
• В справочник AddAttributeAndPropertySets добавить предопределенный элемент вида "Document_DocumentName"
• Переименовать в AddAttributeAndPropertySets представление в виде "Document Document name", т.е. наименование самого документа с большой буквы
• Скопировать в документ таблицу AddAttributes
  На вкладке характеристик в объекте документа сделать настройки для свойств и доп реквизитов:
• 
• 
• Добавить реквизит документа Company
• В Common Attributes указать что используются в документе - Author и Description всегда. DocumentAmount по необходимости
• Добавить в определяемые типы typeAddPropertyOwners
• Добавить в определяемые типы typeObjectWithItemList (если у документа есть табличная часть ItemList)
• Добавить тип в команду отчета DocumentRegistrationsReport
• Создать два общих модуля DocDocumentNameClient и DocDocumentNameServer, лучше скопировать их похожего документа и удалить лишнее
• В функции SetGroupItemsList оставить те реквизиты, которые должны формировать представление документа
• Добавить формы DocumentForm, ListForm, ChoiceForm именно в таком порядке они должны располагаться в метаданных

В форме ChoiceForm и ListForm

• вывести в таблицу Ref, и скрыть ее.
  
• Вставить области Commands и FormEvents
• В форме документа сформировать группу представлений (можно скопировать)

• Сформировать страницы и группу подвала (даже если она будет пустая)

• Скопировать реквизиты формы:

• В модуле формы документа определить области:

#Region Variables
// Используется для описания переменных, лучше никогда не использовать
#EndRegion

#Region FormEventHandlers
// события самой формы - при открытии, при создании и т.д.
#EndRegion

#Region FormHeaderItemsEventHandlers
// события элементов формы, обычно- реквизиты при изменении, страницы и т.д.
#EndRegion

#Region FormTableItemsEventHandlers
#Region TableName
// События табличной части, 
#EndRegion
#EndRegion

#Region FormCommandsEventHandlers
// события по нажатию кнопок формы (не табличных частей
#EndRegion

#Region Initialize
// инициализация - не использовать
#EndRegion

#Region Public
// все методы, которые являются экспортными, и не относятся к оповещениям внутри формы
#EndRegion

#Region Private
// весь основной код.
#EndRegion

Надо понимать, что в во всех регионах - не должно быть никакой логики прописано, кроме модуля Private - там может быть прописана логика, в остальных местах - должны или вызываться общие модули документа, или функции из региона Privat.

• Скопировать Регионы GroupTitleDecorations, DescriptionEvents, AddAttributes, ExternalCommands

• В модуль объекта документа вставить код:

Procedure BeforeWrite(Cancel, WriteMode, PostingMode)
	If DataExchange.Load Then
		Return;
	EndIf;	
EndProcedure

Procedure OnWrite(Cancel)
	If DataExchange.Load Then
		Return;
	EndIf;	
EndProcedure

Procedure BeforeDelete(Cancel)
	If DataExchange.Load Then
		Return;
	EndIf;
EndProcedure

Procedure Posting(Cancel, PostingMode)
	PostingServer.Post(ThisObject, Cancel, PostingMode, ThisObject.AdditionalProperties);
EndProcedure

Procedure UndoPosting(Cancel)
	UndopostingServer.Undopost(ThisObject, Cancel, ThisObject.AdditionalProperties);
EndProcedure

• Вставить шаблон в модуль менеджера клиента:

#Region Posting

Function PostingGetDocumentDataTables(Ref, Cancel, PostingMode, Parameters, AddInfo = Undefined) Export
	
	Tables = New Structure();
	PostingServer.SetRegisters(Tables, Ref);
	QueryArray = GetQueryTexts();
	PostingServer.FillPostingTables(Tables, Ref, QueryArray);
	Return Tables;
	
EndFunction

Function PostingGetLockDataSource(Ref, Cancel, PostingMode, Parameters, AddInfo = Undefined) Export
	DocumentDataTables = Parameters.DocumentDataTables;
	DataMapWithLockFields = New Map();

	PostingServer.GetLockDataSource(DataMapWithLockFields, DocumentDataTables);
	
	Return DataMapWithLockFields;
EndFunction

Procedure PostingCheckBeforeWrite(Ref, Cancel, PostingMode, Parameters, AddInfo = Undefined) Export
	Return;
EndProcedure

Function PostingGetPostingDataTables(Ref, Cancel, PostingMode, Parameters, AddInfo = Undefined) Export
	PostingDataTables = New Map();
	PostingServer.SetPostingDataTables(PostingDataTables, Parameters);
	Return PostingDataTables;
EndFunction

Procedure PostingCheckAfterWrite(Ref, Cancel, PostingMode, Parameters, AddInfo = Undefined) Export
	CheckAfterWrite(Ref, Cancel, Parameters, AddInfo);
EndProcedure

#EndRegion

#Region Undoposting

Function UndopostingGetDocumentDataTables(Ref, Cancel, Parameters, AddInfo = Undefined) Export
	Return PostingGetDocumentDataTables(Ref, Cancel, Undefined, Parameters, AddInfo);
EndFunction

Function UndopostingGetLockDataSource(Ref, Cancel, Parameters, AddInfo = Undefined) Export
	DocumentDataTables = Parameters.DocumentDataTables;
	DataMapWithLockFields = New Map();
	PostingServer.GetLockDataSource(DataMapWithLockFields, DocumentDataTables);
	Return DataMapWithLockFields;
EndFunction

Procedure UndopostingCheckBeforeWrite(Ref, Cancel, Parameters, AddInfo = Undefined) Export
	Return;
EndProcedure

Procedure UndopostingCheckAfterWrite(Ref, Cancel, Parameters, AddInfo = Undefined) Export
	Parameters.Insert("Unposting", True);
	CheckAfterWrite(Ref, Cancel, Parameters, AddInfo);
EndProcedure

#EndRegion

#Region CheckAfterWrite

Procedure CheckAfterWrite(Ref, Cancel, Parameters, AddInfo = Undefined)
	Return;
EndProcedure

#EndRegion

#Region PostingInfo

Function GetQueryTexts()
	QueryArray = New Array;
	QueryArray.Add(ItemList());
	QueryArray.Add(R4010B_ActualStocks());
	QueryArray.Add(R4011B_FreeStocks());
	QueryArray.Add(R4050B_StockInventory());
	QueryArray.Add(R4051T_StockAdjustmentAsWriteOff());
	QueryArray.Add(R4052T_StockAdjustmentAsSurplus());
	Return QueryArray;
EndFunction

Function ItemList()
	Return
        // Сортировка по номеру строки, и отбор по ссылке документа
		"SELECT
		|	ItemStockAdjustmentItemList.Ref,
		|	ItemStockAdjustmentItemList.Key,
		|	ItemStockAdjustmentItemList.ItemKey,
		|	ItemStockAdjustmentItemList.Unit,
		|	ItemStockAdjustmentItemList.Quantity,
		|	ItemStockAdjustmentItemList.QuantityInBaseUnit,
		|	ItemStockAdjustmentItemList.ItemKeyWriteOff,
		|	ItemStockAdjustmentItemList.Ref.Date,
		|	ItemStockAdjustmentItemList.Ref.Company,
		|	ItemStockAdjustmentItemList.Ref.Store
                |INTO ItemList
		|FROM
		|	Document.ItemStockAdjustment.ItemList AS ItemStockAdjustmentItemList
		|WHERE
		|	ItemStockAdjustmentItemList.Ref = &Ref
		|ORDER BY
		|	ItemStockAdjustmentItemList.LineNumber";
EndFunction

Function R4010B_ActualStocks()
	Return
		"SELECT 
		|	VALUE(AccumulationRecordType.Expense) AS RecordType,
		|*
		|INTO R4010B_ActualStocks
		|FROM
		|	ItemList AS QueryTable
		|WHERE 
		|	NOT QueryTable.IsService 
		|	AND NOT QueryTable.UseShipmentConfirmation";

EndFunction

Function R4011B_FreeStocks()
	Return
		"SELECT 
		|	VALUE(AccumulationRecordType.Expense) AS RecordType,
		|	QueryTable.SalesOrder AS Basis,
		|*
		|
		|INTO R4011B_FreeStocks
		|FROM
		|	ItemList AS QueryTable
		|WHERE NOT QueryTable.IsService
		|	AND NOT QueryTable.UseShipmentConfirmation 
		|	AND QueryTable.SalesOrderExists
		|	AND QueryTable.SalesOrder.UseItemsShipmentScheduling";

EndFunction

Function R4050B_StockInventory()
	Return
		"SELECT 
		|	VALUE(AccumulationRecordType.Expense) AS RecordType,
		|*
		|INTO R4050B_StockInventory
		|FROM
		|	ItemList AS QueryTable
		|WHERE NOT QueryTable.IsService";

EndFunction

Function R4051T_StockAdjustmentAsWriteOff()
	Return
		"SELECT *
		|INTO R4051T_StockAdjustmentAsWriteOff
		|FROM
		|	ItemList AS QueryTable
		|WHERE False";

EndFunction

Function R4052T_StockAdjustmentAsSurplus()
	Return
		"SELECT *
		|INTO R4052T_StockAdjustmentAsSurplus
		|FROM
		|	ItemList AS QueryTable
		|WHERE False";

EndFunction

#EndRegion

[DitriXNew]

у нас есть такой предопределенный тип typeObjectWithItems и регистр сведений SavedItems, это для того что бы Item в табличных частях ItemList не очищался после записи если ItemKey не выбран. И еще обработчик на форме AfterWriteAtServer(), который пишет в этот регистр.