build.gradle

import java.util.zip.ZipFile

plugins {
  id 'org.gradle.test-retry' version '1.0.0'
  id 'org.jenkins-ci.jpi' version '0.39.0'
  id 'ru.vyarus.animalsniffer' version '1.5.0'
  id 'com.github.spotbugs' version '3.0.0'
  id 'codenarc'
}

group = 'org.jenkins-ci.plugins'
description = 'This plugin adds Gradle support to Jenkins'

ext {
  coreBaseVersion = '2.138'
  corePatchVersion = '4'
  coreBomVersion = '3'
}

jenkinsPlugin {
  // Version of Jenkins core this plugin depends on.
  coreVersion = "${coreBaseVersion}.${corePatchVersion}"

  // Human-readable name of plugin.
  displayName = 'Gradle Plugin'

  // URL for plugin on Jenkins wiki or elsewhere.
  url = 'https://github.com/jenkinsci/gradle-plugin'

  // Plugin URL on GitHub. Optional.
  gitHubUrl = 'https://github.com/jenkinsci/gradle-plugin'

  // Plugin ID, defaults to the project name without trailing '-plugin'
  shortName = 'gradle'

  compatibleSinceVersion = '1.0'

  developers {
    developer {
      id = 'wolfs'
      name = 'Stefan Wolf'
    }
  }

  licenses {
    license {
      name = 'MIT License'
      distribution = 'repo'
      url = 'https://opensource.org/licenses/MIT'
    }
  }

  disabledTestInjection = false
}

java {
  sourceCompatibility = 'VERSION_1_8'
}

dependencies {
  api platform("io.jenkins.tools.bom:bom-${coreBaseVersion}.x:${coreBomVersion}")

  implementation 'org.jenkins-ci.plugins:structs'
  implementation 'org.jenkins-ci.plugins.workflow:workflow-api'
  implementation 'org.jenkins-ci.plugins.workflow:workflow-cps'
  implementation 'org.jenkins-ci.plugins.workflow:workflow-job'
  implementation 'org.jenkins-ci.plugins.workflow:workflow-basic-steps'
  implementation 'org.jenkins-ci.plugins.workflow:workflow-durable-task-step'
  implementation 'org.jenkins-ci.plugins.workflow:workflow-step-api'

  signature 'org.codehaus.mojo.signature:java18:1.0@signature'

  testImplementation 'org.jenkins-ci.main:jenkins-test-harness:2.56'
  testImplementation 'org.jenkins-ci.main:jenkins-test-harness-tools:2.2'
  testImplementation 'io.jenkins:configuration-as-code:1.4'
  testImplementation 'org.jenkins-ci.plugins:timestamper:1.8.10'
  testImplementation 'org.jenkins-ci.plugins:pipeline-stage-step:2.3'
  testImplementation 'org.spockframework:spock-core:1.2-groovy-2.4'

  jenkinsServer 'org.jenkins-ci.plugins:git'
}

if (project.hasProperty('maxParallelForks')) {
  project.maxParallelForks = Integer.valueOf(project.maxParallelForks, 10)
} else {
  ext.maxParallelForks = 3
}

animalsniffer {
  toolVersion = '1.18'
  sourceSets = [sourceSets.main]
  // We need to exclude this dependency from animalsniffer since it contains an invalid class
  excludeJars 'icu4j-*'
}

spotbugs {
  toolVersion '3.1.12'
  // This prevents logging some errors when SpotBugs tries to open files as jar files.
  // See https://github.com/gradle/gradle/issues/1094.
  sourceSets = [sourceSets.main]
}

tasks.named("spotbugsMain", com.github.spotbugs.SpotBugsTask) {
  classpath = sourceSets.main.compileClasspath
}

spotbugsMain {
  classes = sourceSets.main.output
}

codenarc {
  toolVersion '1.5'
  sourceSets = [sourceSets.test]
}

test {
  systemProperties['hudson.model.DownloadService.noSignatureCheck'] = 'true'
  ignoreFailures = gradle.ciBuild
  maxParallelForks = project.maxParallelForks
  retry {
    maxRetries = 1
    maxFailures = 10
  }
}

def checkArchiveManifest(File archive) {
  new ZipFile(archive).withCloseable { archiveZip ->
    archiveZip.getInputStream(archiveZip.getEntry('META-INF/MANIFEST.MF')).withStream {
      assert it.text.contains("Plugin-Version: ${project.version}"): "Wrong metadate in file ${archive} - run a clean build"
    }
  }
}

tasks.withType(AbstractArchiveTask) {
  inputs.property('pluginVersion') {
    project.version
  }
}

task checkArchiveManifests {
  dependsOn jar, jpi
  doLast {
    checkArchiveManifest(jar.archiveFile.get().asFile)
    checkArchiveManifest(jpi.archiveFile.get().asFile)
  }
}

tasks.withType(AbstractPublishToMaven) {
  dependsOn checkArchiveManifests
}

defaultTasks.add 'test'
defaultTasks.add 'jpi'

task createWrapperZip(type: Zip) {
  archiveFileName = 'wrapper.zip'
  destinationDirectory = new File(sourceSets.test.output.resourcesDir, 'gradle')

  from(project.rootDir) {
    include('gradle/**')
    include('gradlew*')
  }
}

processTestResources.dependsOn(createWrapperZip)