MODULE.bazel

module(
    name = "player",
    version = "1.0",
)

bazel_dep(name = "rules_player")
archive_override(
  module_name = "rules_player",
  strip_prefix = "rules_player-2.2.1",
  urls = ["https://github.com/player-ui/rules_player/archive/refs/tags/v2.2.1.tar.gz"],
  integrity = "sha256-vRyADsmF6vA865X9euZw5Z4KnGgpht5qzaa/vLxSkYQ="
)
bazel_dep(name = "platforms", version = "1.0.0")
bazel_dep(name = "aspect_bazel_lib", version = "2.19.4")
bazel_dep(name = "aspect_rules_js", version = "2.3.8")
bazel_dep(name = "bazel_skylib", version = "1.8.1")
bazel_dep(name = "rules_pkg", version = "1.1.0")
bazel_dep(name = "aspect_rules_ts", version = "3.6.3")

# C++
bazel_dep(name = "rules_foreign_cc", version = "0.15.0")
bazel_dep(name = "googletest", version = "1.14.0.bcr.1")

####### Node.js version #########
bazel_dep(name = "rules_nodejs", version = "6.4.0")

node = use_extension("@rules_nodejs//nodejs:extensions.bzl", "node")
node.toolchain(node_version = "22.15.1")

#################################
sh_config_ext = use_extension("@rules_player//shell:defs.bzl", "sh_configure")
use_repo(sh_config_ext, "local_shell_config")

register_toolchains("@local_shell_config//:local_sh_toolchain")

###### Start iOS ######
## Rule Dependencies
bazel_dep(name = "rules_xcodeproj", version = "2.12.1")
bazel_dep(name = "rules_shell", version = "0.5.0")
bazel_dep(name = "rules_apple", version = "4.1.0", repo_name = "build_bazel_rules_apple")
bazel_dep(name = "apple_support", version = "1.22.0", repo_name = "build_bazel_apple_support")
bazel_dep(name = "rules_swift", version = "2.9.0")
bazel_dep(name = "gazelle", version = "0.42.0", repo_name = "bazel_gazelle")
bazel_dep(name = "rules_swift_package_manager", version = "1.0.0")
bazel_dep(name = "swiftlint", version = "0.59.1", repo_name = "SwiftLint")

## This section is handled by rules_swift_package_manager
swift_deps = use_extension(
    "@rules_swift_package_manager//:extensions.bzl",
    "swift_deps",
)
swift_deps.from_package(
    resolved = "//:xcode/Package.resolved",
    swift = "//:xcode/Package.swift",
)

## SPM Dependencies
### Packages need to be listed here to be available as a target in BUILD files.
### Run `bazel mod tidy` to update this list automatically.
use_repo(
    swift_deps,
    "swift_package",
    "swiftpkg_swift_hooks",
    "swiftpkg_swiftlint",
    "swiftpkg_viewinspector",
)

###### End iOS ######
npm = use_extension("@aspect_rules_js//npm:extensions.bzl", "npm")
npm.npm_translate_lock(
    name = "npm",
    data = [
        "//:package.json",
    ],
    npm_package_target_name = "{dirname}",
    npmrc = "//:.npmrc",
    pnpm_lock = "//:pnpm-lock.yaml",
    verify_node_modules_ignored = "//:.bazelignore",
)
use_repo(npm, "npm")

rules_ts_ext = use_extension(
    "@aspect_rules_ts//ts:extensions.bzl",
    "ext",
    dev_dependency = True,
)
rules_ts_ext.deps()
use_repo(rules_ts_ext, "npm_typescript")

# Kotlin
build_constants = use_repo_rule("@rules_player//distribution:defs.bzl", "build_constants")

build_constants(
    name = "build_constants",
    constants = {
        "GROUP": "com.intuit.playerui",
    },
    version_file = "//:VERSION",
)

bazel_dep(name = "rules_java", version = "8.13.0")
bazel_dep(name = "rules_kotlin", version = "2.1.8")
archive_override(
    module_name = "rules_kotlin", 
    urls = ["https://github.com/bazelbuild/rules_kotlin/releases/download/v2.1.8/rules_kotlin-v2.1.8.tar.gz"],
    patches = ["//patches:rules_kotlin.allow_dupe_plugins.patch"],
)

register_toolchains("//jvm:kotlin_toolchain")

# Android
bazel_dep(name = "rules_android", version = "0.6.5")
bazel_dep(name = "rules_android_ndk", version = "0.1.3")
git_override(
    module_name = "rules_android_ndk",
    commit = "3377db4d8306363b4a4ce65aa678814dd90e4ee6",
    remote = "https://github.com/sugarmanz/rules_android_ndk.git",
)

android_ndk_repository_extension = use_extension("@rules_android_ndk//:extension.bzl", "android_ndk_repository_extension")
use_repo(android_ndk_repository_extension, "androidndk")

register_toolchains("@androidndk//:all")

remote_android_extensions = use_extension("@bazel_tools//tools/android:android_extensions.bzl", "remote_android_tools_extensions")
use_repo(remote_android_extensions, "android_gmaven_r8")

# Maven
bazel_dep(name = "rules_jvm_external", version = "6.8")

# Override for AAR publishing support
git_override(
    module_name = "rules_jvm_external",
    # branch = "maven-export-aar-6.8",
    commit = "0dc1a97c0403de02e0bf9a03244212a15dae3333",
    remote = "https://github.com/sugarmanz/rules_jvm_external.git",
)

maven = use_extension("@rules_jvm_external//:extensions.bzl", "maven")
maven.from_toml(
    bom_modules = [
        "org.junit:junit-bom",
    ],
    libs_versions_toml = "//:libs.versions.toml",
)
maven.install(
    fetch_sources = True,
    known_contributing_modules = [
        "bazel_worker_java",
        "player",
    ],
    lock_file = "//:maven-lock.json",
    repositories = [
        "https://repo1.maven.org/maven2",
        "https://maven.google.com/",
        "https://plugins.gradle.org/m2/",
        "https://jcenter.bintray.com/",
        "https://jitpack.io/",
    ],
    version_conflict_policy = "pinned",
)
use_repo(maven, "maven")

bazel_dep(name = "rules_robolectric", version = "4.15.1")

http_file = use_repo_rule("@bazel_tools//tools/build_defs/repo:http.bzl", "http_file")

http_file(
    name = "android_test_orchestrator_apk",
    sha256 = "b7a2e7d0184b03e12c7357f3914d539da40b52a11e90815edff1022c655f459b",
    url = "https://dl.google.com/android/maven2/androidx/test/orchestrator/1.4.2/orchestrator-1.4.2.apk",
)

http_file(
    name = "android_test_services_apk",
    sha256 = "c6bc74268b29bdabad8da962e00e2f6fd613c24b42c69e81b258397b4819f156",
    url = "https://dl.google.com/android/maven2/androidx/test/services/test-services/1.4.2/test-services-1.4.2.apk",
)

# All things Hermes
git_repository = use_repo_rule("@bazel_tools//tools/build_defs/repo:git.bzl", "git_repository")

git_repository(
    name = "hermes",
    build_file = "//third_party/hermes:BUILD",
    commit = "c16bd411cdb20d424f843ea8623c00fa3d493a6c",
    patches = ["//patches:hermes.loosen_host_function_params.patch"],
    remote = "https://github.com/facebook/hermes",
)

git_repository(
    name = "fbjni",
    build_file = "//third_party/fbjni:BUILD",
    # this is not the same release as the fbjni AAR due to this change breaking exception handling in C++ https://github.com/facebookincubator/fbjni/commit/cd6e61a96129bdf70dc1e3c967c5ec29f4d4eeb1
    commit = "1cf763714e99d45c23dfb316d702ebfa8290af64",
    patches = ["//patches:fbjni.install_headers.patch"],
    remote = "https://github.com/facebookincubator/fbjni",
)

RN_VERSION = "0.78.1"

# Pull prefab Android Hermes built against React Native JSI
http_archive = use_repo_rule("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "rn_hermes_android",
    build_file = "//third_party/rn:hermes_android.BUILD",
    sha256 = "e60a59daf0293fcee17877a715fcd26614c4348855a74365a9564cde9a0fbe7c",
    url = "https://repo1.maven.org/maven2/com/facebook/react/hermes-android/{}/hermes-android-{}-release.aar".format(RN_VERSION, RN_VERSION),
)

git_repository(
    name = "react_native",
    build_file = "//third_party/rn:react_native.BUILD",
    commit = "1299ef7be0fe9daf8274b7b2a7c49078723fc533",
    patches = ["//patches:react_native.loosen_host_function_params.patch"],
    remote = "https://github.com/facebook/react-native",
)

http_archive(
    name = "fbjni_artifact",
    build_file = "//third_party/fbjni:artifact.BUILD",
    sha256 = "7e319ae110ac5e5ef18904170aea5c3e753e915d196699d7fd39d36c8e1dfe36",
    url = "https://repo1.maven.org/maven2/com/facebook/fbjni/fbjni/0.7.0/fbjni-0.7.0.aar",
)