build.gradle.kts

plugins {
  id("java")
  id("maven-publish")
  id("com.gradleup.shadow") version "8.3.0"
}

group = "com.sentropic.guiapi"
version = "1.2.3"
description = "GUI API"

repositories {
  mavenCentral()
  maven("https://repo.papermc.io/repository/maven-public/") {
    name = "papermc-repo"
  }
}

dependencies {
  compileOnly("io.papermc.paper:paper-api:1.21.8-R0.1-SNAPSHOT")
  compileOnly("net.dmulloy2:ProtocolLib:5.4.0")
  implementation("net.kyori:adventure-text-serializer-gson:4.24.0")
}

tasks.shadowJar {
  relocate("net.kyori", "com.sentropic.guiapi.libs.kyori")
}

java {
  toolchain.languageVersion = JavaLanguageVersion.of(21)
  withSourcesJar()
  withJavadocJar()
}

tasks.withType<JavaCompile> {
  options.encoding = "UTF-8"
  options.release.set(21)
}

tasks.withType<Javadoc> {
  options.encoding = "UTF-8"
}

tasks.processResources {
  val props = mapOf("version" to version)
  inputs.properties(props)
  filteringCharset = "UTF-8"
  filesMatching("plugin.yml") {
    expand(props)
  }
}

publishing {
  publications {
    create<MavenPublication>("mavenJava") {
      from(components["java"])
      artifactId = "guiapi"
      version = project.version as String?
    }
    repositories {
      maven("https://nexus.jellycraft.net/repository/maven-releases/") {
        name = "jellycraft-repo"

        credentials {
          username = System.getenv("NEXUS_USER")
          password = System.getenv("NEXUS_PASSWORD")
        }

        authentication {
          create<BasicAuthentication>("basic")
        }
      }
    }
  }
}