JavaClaw/build.gradle at main · JoseWalker/JavaClaw · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
plugins {
    alias(libs.plugins.spring.boot) apply false
}

description = 'JavaClaw'

allprojects {
    group = 'ai.javaclaw'
    version = System.getenv('CI_COMMIT_TAG')?.replace("v", "") ?: "v1.0.0-SNAPSHOT".replace("v", "")

    repositories {
        mavenCentral()
        maven { url = 'https://repo.spring.io/snapshot' }
        maven { url = 'https://repo.spring.io/milestone' }
        maven {
            name = 'central-portal-snapshots'
            url = 'https://central.sonatype.com/repository/maven-snapshots/'
        }
    }
}

// Explicitly configure only real projects
configure(subprojects.findAll { it.buildFile.exists() }) {
    plugins.withType(JavaPlugin).configureEach {
        dependencies {
            implementation(platform(libs.bom.spring.boot))
            implementation(platform(libs.bom.spring.ai))
            implementation(platform(libs.bom.spring.modulith))

            testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
        }

        plugins.withId('org.springframework.boot') {
            dependencies {
                developmentOnly(platform(libs.bom.spring.boot))
            }
        }

        java {
            toolchain {
                languageVersion = JavaLanguageVersion.of(25)
            }
        }

        tasks.named('test') {
            useJUnitPlatform()
        }
    }
}