miPong5.pde

import processing.sound.*;
SoundFile gol;
SoundFile pala;

float ph, pw;    //alto y ancho de las palas
int puntos1, puntos2;   //contadores de puntuación

float inc;     //incremento de velocidad (= dificultad)
float dedo;    //espacio para el dedo en la pantalla
int maxP=5;      //puntuación máxima (fin de la partida)
float radio;
float vmin, vmax;
float pvinit;   //velocidad inicial de la pala IA
float difvb,difvp; //diferenciales de velocidad bola y pala

Bola bola;
Pala palaIA;
Pala palaPlayer;

void setup() {
  //size(1024,640);  //tamaño pantalla
  fullScreen();   
  //orientation(LANDSCAPE);
  //noSmooth()
  //noCursor();      //desactivado para ANDROID

  dedo = 60*displayDensity;
  ph = 30*displayDensity;
  pw = 5*displayDensity; 
  radio = 6*displayDensity;
  inc = 0.5*displayDensity;     //incremento de velocidades (dificultad)
  vmin = 3.5*displayDensity/3;  //velocidad inicial de la bola
  vmax = 4.5*displayDensity;
  pvinit = 2*displayDensity;  //velocidad inicial de la pala
  difvb = 0.07*displayDensity; //diferencial de la velocidad de la bola
  difvp = 0.1*displayDensity; //diferencial de la velocidad de la pala
  
  gol = new SoundFile(this, "gol1.wav");      //mp3 ANDROID
  pala = new SoundFile(this, "pala1.wav");     //wav windows

  //noStroke();
  //fill(255);
  //color(255,255,255);
  stroke(255);
  rectMode(RADIUS);
  frameRate(45); 

  bola = new Bola();
  palaIA = new Pala(pw, true);
  palaPlayer = new Pala(width-pw-dedo, false);

  strokeWeight(displayDensity);
  background(0, 0, 0);
  textSize(20*displayDensity);  

  fill(255);
  text("Touch to start", width/4, height/3);
  text("(swipe finger\nover grey zone)", width/4, height/2);
  noLoop();
}


void mousePressed() {
  loop();
}


void draw() {
  background(0, 0, 0);
  //zona para el dedo
  noStroke();
  fill(128);
  rect(width-pw, height/2, dedo-pw, height);
  //stroke(255);
  fill(200);
  triangle(width-dedo/2, 20*displayDensity, 
    width-dedo/6, 80*displayDensity, 
    width-dedo/6*5, 80*displayDensity);
  triangle(width-dedo/2, height-20*displayDensity, 
    width-dedo/6, height-80*displayDensity, 
    width-dedo/6*5, height-80*displayDensity);
  stroke(255);
  line(width-dedo/2, 80*displayDensity, 
    width-dedo/2, height-80*displayDensity);
  fill(255);


  //límites del campo
  line(0, 0, width-dedo, 0);
  line(0, height-1, width-dedo, height-1);

  //red
  line((width-dedo)/2, 0, (width-dedo)/2, height); 
  //println(round(frameRate) + "fps");

  //movimiento de la bola
  bola.mover();

  palaIA.tocar(bola);
  palaPlayer.tocar(bola);

  palaIA.mover();
  palaPlayer.mover();

  bola.checkPunto();

  //mostrar puntuación
  text(nf(puntos1, 2), (width-dedo)/2-50*displayDensity, 20*displayDensity);
  text(nf(puntos2, 2), (width-dedo)/2+30*displayDensity, 20*displayDensity);

  if (puntos1==maxP || puntos2==maxP) ganador();
}

class Bola {          //propiedades
  float x;
  float y;
  float r = radio;
  float vx;
  float vy;
  boolean reset=false;
  int signo;

  Bola() {            //constructor

    //posición inicial de la bola
    x = (width-dedo)/2;
    y = height/2;

    //velocidad inicial de la bola
    signo = ceil(random(-1, 1));
    if (signo == 0) {
      signo = -1;
    }
    vx = random(vmin-1, vmax-1)*signo;

    signo = ceil(random(-1, 1));
    if (signo == 0) {
      signo = -1;
    }  
    vy = random(vmin-1, vmax-1)*signo;
  }



  //métodos
  void mover() {
    ellipse(x, y, r*2, r*2);

    x += vx;
    y += vy;

    //rebotes arriba y abajo
    if ( y > height-r || y < r ) {
      vy *= -1;    //cambiamos la dirección
      x += vx;
      y += vy;
    }
  }


  void checkPunto() {
    int check = 0;
    if (x < 0) {
      puntos2++;
      palaIA.pv += difvp*3;    //la IA mejora con cada gol que le metemos
      check=1;
    }
    if (x > (width-dedo)) {
      puntos1++;
      palaIA.pv += difvp;    //la IA mejora, pero menos, con cada gol que mete
      check=-1;
    }    
    if (check != 0) {
      gol.play();
      //posición inicial de la bola
      x = (width-dedo)/2;
      y = height/2;
      //reiniciamos la dificultad pero a la vez la aumentamos
      inc = 1*displayDensity/3 + inc/2;

      //velocidad de la bola
      vx = (random(vmin, vmax)+inc/2)*check; //en x signo no aleatorio,saca el que pierde
      check = ceil(random(-1, 1));
      if (check == 0) {
        check = -1;
      } 
      vy = (random(vmin, vmax)+inc/2)*check;
      //noLoop();
    }
  }
}


void ganador() {
  textSize(18*displayDensity);
  if (puntos1 > puntos2) {
    fill(0, 255, 0, 180);
    text("Winner", (width-dedo)/6, height/4); 
    //fill(255, 0, 0, 180);
    //text("Tu pierdes", 4*(width-dedo)/6, height/4);
  } else {
    //fill(255, 0, 0, 180);
    //text("IA Pierde", (width-dedo)/6, height/4);
    fill(0, 255, 0, 180);
    text("Winner", (width-dedo)/2+(width-dedo)/6, height/4);
  }
  noLoop();

  fill(255);
  text("Touch to\nstart again", (width-dedo)/2+10, height/2+135);

  puntos1=0;
  puntos2=0;
}

class Pala {              //propiedades
  float x;
  float y;
  float w = pw;
  float h = ph;
  boolean IA;
  float pv=pvinit;         //velocidad inicial de la pala IA
  int check;
  float dif;

  Pala(float px, boolean pIA) {  //constructor
    x = px;
    y = height/2;
    IA = pIA;
  }  

  //métodos
  void mover() {
    rect(x, y, w, h);
    if (IA) {      //movimiento de la pala IA
      if (y < bola.y && bola.y > h ) {
        y += pv;
      }
      if (y > bola.y && bola.y < height-h ) {
        y -= pv;
      }
    } else {       //moviemiento de la pala del jugador
      y = mouseY;
    }
    //la dibujamos
  }

  void tocar(Bola bola) {
    check=0;
    dif=bola.y-y;    //para ver por qué parte de la pala golpeamos la bola
    if (IA) {
    //rebotes en la pala de la IA
    if (bola.x < bola.r+2*w && abs(dif)<h) {
      check = -1;
    }
    } else {
    //rebotes en la pala del judador
    if (bola.x > width-bola.r-2*w-dedo && abs(dif)<h) {
      check = 1;
    }
    }
    if (check!=0) {
      pala.play();
      bola.vx += inc*check;   //aumentamos la velocidad horizontal (= dificultad)
      bola.vx *= -1;    //y la invertimos                
      /*
        if (check==-1) {
       bola.vy = map(dif,-h,h,-abs(bola.vx),abs(bola.vx));   //para darle efecto a la bola
       } else {
       bola.vy = map(dif,-h,h,-abs(bola.vx),abs(bola.vx));   //para darle efecto a la bola
       } 
       */
      bola.vy = map(dif, -h, h, -abs(bola.vx), abs(bola.vx));   //para darle efecto a la bola
      bola.x += bola.vx;
      bola.y += bola.vy;        
      inc += difvb;    //incrementamos el diferencial de dificultad   
      //println("1: ",dif1,h, bola.vx, map(dif1,-h,h,-abs(bola.vx),abs(bola.vx))); 
      //println("2: ",dif2,h, bola.vx, map(dif2,-h,h,-abs(bola.vx),abs(bola.vx)));
    }
  }
}