chaincode/build.gradle at main · MedTechChain/chaincode · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
plugins {
    id 'com.github.johnrengelman.shadow' version '8.1.1'
    id 'application'
    id 'checkstyle'
    id 'jacoco'
}

group 'nl.medtechchain'

dependencies {
    compileOnly 'org.projectlombok:lombok:1.18.34'
    annotationProcessor 'org.projectlombok:lombok:1.18.34'

    implementation 'org.hyperledger.fabric-chaincode-java:fabric-chaincode-shim:2.5.0'
    implementation 'com.fasterxml.jackson.core:jackson-databind:2.17.2'
    implementation 'com.google.protobuf:protobuf-java:3.25.4'
    implementation 'com.google.protobuf:protobuf-java-util:3.25.4'
    implementation 'com.google.privacy.differentialprivacy:differentialprivacy:3.0.0'
    implementation 'com.google.ortools:ortools-java:9.9.3963'
    implementation ':medtechchain.proto:1.0.0'

    testImplementation 'org.junit.jupiter:junit-jupiter:5.10.2'
    testImplementation 'org.assertj:assertj-core:3.25.3'
    testImplementation 'org.mockito:mockito-core:5.11.0'
}

repositories {
    mavenCentral()
    maven {
        url 'https://jitpack.io'
    }
    flatDir {
        dirs 'libs'
    }
}

tasks.compileJava {
    options.release.set(11)
}

application {
    mainClass = 'org.hyperledger.fabric.contract.ContractRouter'
}

checkstyle {
    toolVersion '10.14.0'
    configFile file("config/checkstyle/checkstyle.xml")
}

configurations.checkstyle {
    resolutionStrategy.capabilitiesResolution.withCapability("com.google.collections:google-collections") {
        select("com.google.guava:guava:0")
    }
}


checkstyleMain {
    source ='src/main/java'
}

checkstyleTest {
    source ='src/test/java'
}

jacocoTestReport {
    dependsOn test
}

jacocoTestCoverageVerification {
    violationRules {
        rule {
            limit {
                minimum = 0.8
            }
        }
    }

    finalizedBy jacocoTestReport
}

test {
    useJUnitPlatform()
    testLogging {
        events "passed", "skipped", "failed"
    }
}

shadowJar {
    archiveFileName.set('medtechchain.jar')
    archiveClassifier.set(null)

    manifest {
        attributes 'Main-Class': 'org.hyperledger.fabric.contract.ContractRouter'
    }
}


check.dependsOn jacocoTestCoverageVerification
installDist.dependsOn check

distZip.dependsOn shadowJar
distTar.dependsOn shadowJar

startScripts.dependsOn shadowJar