diff --git a/BaselineOfDebuggingSpy/BaselineOfDebuggingSpy.class.st b/BaselineOfDebuggingSpy/BaselineOfDebuggingSpy.class.st
index 7d92234..3f90c67 100644
--- a/BaselineOfDebuggingSpy/BaselineOfDebuggingSpy.class.st
+++ b/BaselineOfDebuggingSpy/BaselineOfDebuggingSpy.class.st
@@ -9,15 +9,14 @@ Class {
 BaselineOfDebuggingSpy >> baseline: spec [
 
 	<baseline>
-	
-	spec baseline: 'ExperimentModel' with: [ 
-		spec repository:
-			'github://Pharo-XP-Tools/ExperimentModel:main' ].
-	
-	spec for: #common do: [ 
-		spec postLoadDoIt: #postloadAction.
-		spec package: 'DebuggingSpy'.
-		spec package: 'DebuggingSpy-Tests' ]
+	spec baseline: 'ExperimentModel' with: [ spec repository: 'github://Pharo-XP-Tools/ExperimentModel:main' ].
+
+	spec for: #common do: [
+			spec postLoadDoIt: #postloadAction.
+			spec package: 'DebuggingSpy'.
+			spec package: 'DebuggingSpy-Tests'.
+			spec package: 'DebuggingSpy-Browser'.
+			spec package: 'DebuggingSpy-Browser-Tests' ]
 ]
 
 { #category : 'baselines' }
diff --git a/DebuggingSpy-Browser-Tests/DSRecordBrowserTest.class.st b/DebuggingSpy-Browser-Tests/DSRecordBrowserTest.class.st
new file mode 100644
index 0000000..4f8b72f
--- /dev/null
+++ b/DebuggingSpy-Browser-Tests/DSRecordBrowserTest.class.st
@@ -0,0 +1,264 @@
+Class {
+	#name : 'DSRecordBrowserTest',
+	#superclass : 'TestCase',
+	#instVars : [
+		'browser',
+		'logger'
+	],
+	#category : 'DebuggingSpy-Browser-Tests',
+	#package : 'DebuggingSpy-Browser-Tests'
+}
+
+{ #category : 'helpers' }
+DSRecordBrowserTest >> filesPresenter [
+
+	^ browser presenterAt: #fileListPresenter
+]
+
+{ #category : 'helpers' }
+DSRecordBrowserTest >> generateRecordsFile [
+	"Generates a file of random records and returns its file reference."
+
+	| recordFileRef writeStream randomNbOfRecords |
+	randomNbOfRecords := Random new nextInteger: 10.
+
+	recordFileRef := self temporaryDirectory / ('ds-spy-test-' , UUID new asString).
+	recordFileRef ensureCreateFile.
+	writeStream := recordFileRef writeStream.
+
+	writeStream nextPut: $[.
+
+	1 to: randomNbOfRecords do: [ :index |
+			writeStream nextPutAll: (STON toString: (self getRecordForIndex: index)).
+
+			index = randomNbOfRecords ifFalse: [
+					writeStream nextPut: $,.
+					writeStream crlf ] ].
+
+	writeStream nextPut: $].
+
+	writeStream close.
+
+	^ recordFileRef
+]
+
+{ #category : 'helpers' }
+DSRecordBrowserTest >> getRecordForIndex: aNumber [
+	"Generates a record with specified number as dateTime (in seconds) and as windowId"
+
+	^ self recordClass new
+		  dateTime: (DateAndTime fromSeconds: aNumber);
+		  windowId: aNumber;
+		  yourself
+]
+
+{ #category : 'helpers' }
+DSRecordBrowserTest >> recordClass [
+
+	^ DSMouseEnterWindowRecord
+]
+
+{ #category : 'helpers' }
+DSRecordBrowserTest >> recordsFilterPresenter [
+
+	^ browser presenterAt: #recordsFilter
+]
+
+{ #category : 'helpers' }
+DSRecordBrowserTest >> recordsTablePresenter [
+
+	^ browser presenterAt: #recordsTablePresenter
+]
+
+{ #category : 'running' }
+DSRecordBrowserTest >> setUp [
+
+	super setUp.
+	browser := DSRecordBrowser new
+]
+
+{ #category : 'running' }
+DSRecordBrowserTest >> tearDown [
+
+	DSRecordBrowser resetBrowser.
+	super tearDown
+]
+
+{ #category : 'tests' }
+DSRecordBrowserTest >> testAddFile [
+
+	| fileRef |
+	fileRef := self generateRecordsFile.
+
+	browser addFile: fileRef.
+	self assert: browser files size equals: 1.
+	self assert: self filesPresenter items size equals: 1.
+
+	self assert: self filesPresenter selectedItem equals: fileRef
+]
+
+{ #category : 'tests' }
+DSRecordBrowserTest >> testAddFileWhenAlreadyInList [
+
+	| fileRef |
+	fileRef := self generateRecordsFile.
+
+	browser addFile: fileRef.
+	browser addFile: fileRef.
+	self assert: browser files size equals: 1.
+	self assert: self filesPresenter items size equals: 1.
+	self assert: self filesPresenter selectedItem equals: fileRef
+]
+
+{ #category : 'tests' }
+DSRecordBrowserTest >> testBrowserEmpty [
+
+	self assertEmpty: browser files.
+	self assert: self filesPresenter items size equals: 0.
+	self assert: self filesPresenter selectedItem equals: nil.
+	
+]
+
+{ #category : 'tests' }
+DSRecordBrowserTest >> testClosingBrowser [
+
+	DSRecordBrowser toggleBrowser.
+	DSRecordBrowser toggleBrowser.
+	self deny: DSRecordBrowser uniqueInstance window isOpen
+]
+
+{ #category : 'tests' }
+DSRecordBrowserTest >> testCreatingAndOpeningBrowser [
+
+	DSRecordBrowser toggleBrowser.
+	self assert: DSRecordBrowser uniqueInstance window isOpen.
+	DSRecordBrowser toggleBrowser
+]
+
+{ #category : 'tests' }
+DSRecordBrowserTest >> testFilteringAClassOfRecords [
+
+	| fileRef history |
+	fileRef := self generateRecordsFile.
+	history := browser getHistoryFrom: fileRef.
+
+	browser addFile: fileRef.
+	self assert: self recordsTablePresenter roots size equals: history records size.
+
+	self recordsFilterPresenter sourceList selectItem: self recordClass.
+	self recordsFilterPresenter addSelected.
+	
+	self assert: self recordsTablePresenter roots size equals: 0 "Since there is only one type of records in the generated file"
+]
+
+{ #category : 'tests' }
+DSRecordBrowserTest >> testFilteringAllRecords [
+
+	| fileRef history |
+	fileRef := self generateRecordsFile.
+	history := browser getHistoryFrom: fileRef.
+
+	browser addFile: fileRef.
+	self assert: self recordsTablePresenter roots size equals: history records size.
+
+	self recordsFilterPresenter addAll.
+	self assert: self recordsTablePresenter roots size equals: 0
+]
+
+{ #category : 'tests' }
+DSRecordBrowserTest >> testGetHistoryFrom [
+
+	| fileRef |
+	fileRef := self generateRecordsFile.
+	self assert: (browser getHistoryFrom: fileRef) class equals: DSRecordHistory
+]
+
+{ #category : 'tests' }
+DSRecordBrowserTest >> testGetRecordColorAssociationsFrom [
+
+	| fileRef history colorAssociations |
+	fileRef := self generateRecordsFile.
+	history := browser getHistoryFrom: fileRef.
+	colorAssociations := browser getRecordColorAssociationsFrom: history windows.
+
+	history windows do: [ :window |
+			window events do: [ :record |
+					self assert: (colorAssociations anySatisfy: [ :association |
+							 association key = record and: association value = (browser getWindowColorFrom: window) ]) ] ]
+]
+
+{ #category : 'tests' }
+DSRecordBrowserTest >> testRemoveFile [
+
+	| fileRef1 fileRef2 |
+	fileRef1 := self generateRecordsFile.
+	fileRef2 := self generateRecordsFile.
+
+	browser addFile: fileRef1.
+	browser addFile: fileRef2.
+	browser removeFile: fileRef1.
+
+	self assert: browser files size equals: 1.
+	self assert: self filesPresenter items size equals: 1.
+	self assert: self filesPresenter selectedItem equals: fileRef2
+]
+
+{ #category : 'tests' }
+DSRecordBrowserTest >> testRemoveLastFile [
+
+	| fileRef1 |
+	fileRef1 := self generateRecordsFile.
+
+	browser addFile: fileRef1.
+	browser removeFile: fileRef1.
+
+	self assert: browser files size equals: 0.
+	self assert: self filesPresenter items size equals: 0.
+	self assert: self filesPresenter selectedItem equals: nil
+]
+
+{ #category : 'tests' }
+DSRecordBrowserTest >> testStartRecording [
+
+	self assert: browser recorderWindow isNil.
+	self deny: DSRecordRegistry autoSerialize.
+	self deny: DSSpy recordingSession.
+
+	browser startRecording.
+	self assert: DSSpy recordingSession.
+	self assert: DSRecordRegistry autoSerialize.
+	self deny: browser recorderWindow isNil.
+
+	browser stopRecording
+]
+
+{ #category : 'tests' }
+DSRecordBrowserTest >> testUpdateRecordsTable [
+
+	| fileRef history presenterMock |
+	fileRef := self generateRecordsFile.
+	history := browser getHistoryFrom: fileRef.
+	presenterMock := MockObject new on: #selectedItem respond: fileRef.
+	browser updateRecordsTable: presenterMock.
+
+	self recordsTablePresenter roots do: [ :association |
+		self assert: (history records anySatisfy: [ :record | record uuid = association key uuid ]) ]
+]
+
+{ #category : 'tests' }
+DSRecordBrowserTest >> testUpdateRecordsTableWhenAddingFile [
+
+	| fileRef history |
+	fileRef := self generateRecordsFile.
+	history := browser getHistoryFrom: fileRef.
+
+	browser addFile: fileRef.
+
+	self assert: self recordsTablePresenter roots size equals: history records size
+]
+
+{ #category : 'helpers' }
+DSRecordBrowserTest >> timelinePresenter [
+
+	^ browser presenterAt: #graphicTimeline 
+]
diff --git a/DebuggingSpy-Browser-Tests/DSRecorderWindowTest.class.st b/DebuggingSpy-Browser-Tests/DSRecorderWindowTest.class.st
new file mode 100644
index 0000000..d74bc8f
--- /dev/null
+++ b/DebuggingSpy-Browser-Tests/DSRecorderWindowTest.class.st
@@ -0,0 +1,51 @@
+Class {
+	#name : 'DSRecorderWindowTest',
+	#superclass : 'TestCase',
+	#instVars : [
+		'window'
+	],
+	#category : 'DebuggingSpy-Browser-Tests',
+	#package : 'DebuggingSpy-Browser-Tests'
+}
+
+{ #category : 'running' }
+DSRecorderWindowTest >> setUp [
+	super setUp.
+	
+	window := DSTimerWindow new.
+]
+
+{ #category : 'tests' }
+DSRecorderWindowTest >> testEmptyTimerWindow [
+
+	self assert: (Time readFrom: self timerMorph contents readStream) seconds equals: 0
+]
+
+{ #category : 'tests' }
+DSRecorderWindowTest >> testTimeNow [
+
+	self assert: (Time readFrom: self timeNowMorph contents readStream) asSeconds equals: Time now asSeconds
+]
+
+{ #category : 'tests' }
+DSRecorderWindowTest >> testTimer [
+
+	window startTimer.
+	(Delay forMilliseconds: 1000) wait.
+	window stopTimer.
+	self assert: window elapsedTime equals: 1
+]
+
+{ #category : 'layout' }
+DSRecorderWindowTest >> timeNowMorph [
+	"Returns the window's timeNowMorph"
+
+	^ window readSlot: (DSTimerWindow slotNamed: #timeNowMorph)
+]
+
+{ #category : 'layout' }
+DSRecorderWindowTest >> timerMorph [
+	"Returns the window's timerMorph."
+
+	^ window readSlot: (DSTimerWindow slotNamed: #timerMorph)
+]
diff --git a/DebuggingSpy-Browser-Tests/package.st b/DebuggingSpy-Browser-Tests/package.st
new file mode 100644
index 0000000..b20e695
--- /dev/null
+++ b/DebuggingSpy-Browser-Tests/package.st
@@ -0,0 +1 @@
+Package { #name : 'DebuggingSpy-Browser-Tests' }
diff --git a/DebuggingSpy-Browser/DSRecordBrowser.class.st b/DebuggingSpy-Browser/DSRecordBrowser.class.st
new file mode 100644
index 0000000..497628a
--- /dev/null
+++ b/DebuggingSpy-Browser/DSRecordBrowser.class.st
@@ -0,0 +1,443 @@
+"
+Debugging Spy main interface thats includes :
+- an interface that could be opened with a button on the topside bar 
+- a button that adds files to the list displayed on the interface
+- a button to start the instrumentation and another to stop it
+- an interface that shows the content of a selected file
+"
+Class {
+	#name : 'DSRecordBrowser',
+	#superclass : 'SpPresenter',
+	#instVars : [
+		'files',
+		'recordsTablePresenter',
+		'timerWindow',
+		'graphicTimeline',
+		'recordsFilter',
+		'toolbarPresenter',
+		'fileListPresenter',
+		'startRecordButtonPresenter',
+		'stopRecordButtonPresenter'
+	],
+	#classInstVars : [
+		'uniqueInstance'
+	],
+	#category : 'DebuggingSpy-Browser',
+	#package : 'DebuggingSpy-Browser'
+}
+
+{ #category : 'world menu' }
+DSRecordBrowser class >> menuCommandOn: aBuilder [
+	"Adds the DSSpy button on topside bar."
+
+	<worldMenu>
+	(aBuilder item: #DSSpy)
+		order: 100;
+		help: 'Open the Debugging Spy browser.';
+		action: [ self toggleBrowser ]
+]
+
+{ #category : 'initialization' }
+DSRecordBrowser class >> resetBrowser [
+	"Removes the actual browser then another one will be created the next time it needs to be opened."
+
+	<script>
+	uniqueInstance := nil
+]
+
+{ #category : 'open/close' }
+DSRecordBrowser class >> toggleBrowser [
+	"Opens the browser or closes it depending on its state. If it needs to be created, then creates and opens it. See uniqueInstance method."
+
+	uniqueInstance ifNotNil: [
+			^ uniqueInstance window isOpen
+				  ifTrue: [ uniqueInstance window close ]
+				  ifFalse: [ uniqueInstance window open ] ].
+	self uniqueInstance open
+]
+
+{ #category : 'accessing' }
+DSRecordBrowser class >> uniqueInstance [
+
+	^ uniqueInstance ifNil: [ uniqueInstance := self new ]
+]
+
+{ #category : 'files' }
+DSRecordBrowser >> addFile: aFileReference [
+	"Adds a file in the presenter and set is as selected, which updates the records displayed."
+
+	(files includes: aFileReference)
+		ifTrue: [ ^ self inform: 'File already added !' ]
+		ifFalse: [
+				files add: aFileReference.
+				fileListPresenter items: files.
+				fileListPresenter selectItem: aFileReference ]
+]
+
+{ #category : 'layout' }
+DSRecordBrowser >> addRecordButton [
+	"Layout button that opens a file selecting window."
+
+	^ SpToolbarButtonPresenter new
+		  label: 'Add';
+		  icon: (self iconNamed: #smallAdd);
+		  help: 'Add a new record.';
+		  action: [ self openAddFileDialog ];
+		  yourself
+]
+
+{ #category : 'initialization' }
+DSRecordBrowser >> connectPresenters [
+	"Updates the records and the timeline whenever the selected file is changed."
+
+	fileListPresenter whenSelectionChangedDo: [ :presenter |
+			fileListPresenter selectedItem ifNotNil: [
+					self updateRecordsTable: presenter.
+					self updateTimelineChart ] ].
+
+	recordsFilter whenChangedDo: [ fileListPresenter selectedItem ifNotNil: [ self updateRecordsTable: fileListPresenter ] ]
+]
+
+{ #category : 'layout' }
+DSRecordBrowser >> defaultLayout [
+
+	^ SpBoxLayout newVertical
+		  add: toolbarPresenter expand: false;
+		  add: (SpPanedLayout newHorizontal
+				   positionOfSlider: 30 percent;
+				   add: fileListPresenter;
+				   add: (SpBoxLayout newTopToBottom
+						    add: (SpTabLayout new
+								     add: recordsTablePresenter label: 'Records';
+								     add: graphicTimeline label: 'Timeline';
+								     yourself);
+						    yourself);
+				   yourself)
+]
+
+{ #category : 'layout' }
+DSRecordBrowser >> fileList [
+	"Instanciates a new presenter for the added files list."
+
+	^ self newList
+		  items: self files;
+		  display: [ :file | file basenameWithoutExtension ];
+		  actions: self listAddedFilesActions;
+		  yourself
+]
+
+{ #category : 'accessing' }
+DSRecordBrowser >> files [
+
+	^ files ifNil: [ files := OrderedCollection new ]
+]
+
+{ #category : 'layout' }
+DSRecordBrowser >> filterRecordsButton [
+	"Instanciates a new layout button that opens the records filter window."
+
+	^ SpToolbarButtonPresenter new
+		  label: 'Filter';
+		  icon: (self iconNamed: #diff);
+		  help: 'Filter the records.';
+		  action: [ recordsFilter open ];
+		  yourself
+]
+
+{ #category : 'helpers' }
+DSRecordBrowser >> getHistoryFrom: aFileReference [
+
+	^ DSRecordHistory on: (DSSpy materialize: aFileReference)
+]
+
+{ #category : 'helpers' }
+DSRecordBrowser >> getRecordColorAssociationsFrom: aWindowRecordCollection [
+	"Returns a dictionary associating each reacord with its window corresponding color, sorted by each reacord dateTime."
+
+	| recordColorsDictionary |
+	recordColorsDictionary := Dictionary new.
+
+	aWindowRecordCollection do: [ :windowRecord |
+		windowRecord events do: [ :record | recordColorsDictionary at: record put: (self getWindowColorFrom: windowRecord) ] ].
+
+	^ recordColorsDictionary associations sorted: [ :recordA :recordB | recordA key dateTime < recordB key dateTime ]
+]
+
+{ #category : 'helpers' }
+DSRecordBrowser >> getTimelinePointsFrom: aHistory [
+	"Returns a list of plots for the timeline chart."
+
+	^ aHistory windows collectWithIndex: [ :w :index |
+			  RSTimeLinePlot new
+				  entries: {
+						  w events first dateTime asNanoSeconds.
+						  w events last dateTime asNanoSeconds }
+				  at: index;
+				  color: (self getWindowColorFrom: w) ]
+]
+
+{ #category : 'color' }
+DSRecordBrowser >> getWindowColorFrom: aWindowRecord [
+	"Returns the window associated color, and the default color otherwise."
+
+	aWindowRecord isBrowser ifTrue: [ ^ Color fromHexString: '#2A2AB7' ].
+	aWindowRecord isInspector ifTrue: [ ^ Color fromHexString: '#FFC300' ].
+	aWindowRecord isDebugger ifTrue: [ ^ Color fromHexString: '#C41E3D' ].
+
+	aWindowRecord isPlayground ifTrue: [ ^ Color fromHexString: '#70B77E' ].
+	aWindowRecord isBreakpointBrowser ifTrue: [ ^ Color fromHexString: '#7C238C' ].
+	aWindowRecord isCritiqueBrowser ifTrue: [ ^ Color fromHexString: '#A45C15' ].
+	aWindowRecord isEpicea ifTrue: [ ^ Color fromHexString: '#345e54' ].
+	aWindowRecord isIceberg ifTrue: [ ^ Color fromHexString: '#2B5BA9' ].
+	aWindowRecord isRewriter ifTrue: [ ^ Color fromHexString: '#292929' ].
+
+	^ Color gray
+]
+
+{ #category : 'initialization' }
+DSRecordBrowser >> initializePresenters [
+
+	startRecordButtonPresenter := self startRecordButton.
+	stopRecordButtonPresenter := self stopRecordButton.
+	toolbarPresenter := self toolbar.
+	fileListPresenter := self fileList.
+	recordsTablePresenter := self recordsTable.
+	graphicTimeline := self newRoassal.
+	recordsFilter := self recordsFilter
+]
+
+{ #category : 'operations' }
+DSRecordBrowser >> listAddedFilesActions [
+	"List actions for the added files in browser, such as inspecting raw records, inspecting history, or removing the selected file from the list."
+
+	^ SpActionGroup new
+		  addActionWith: [ :anItem |
+				  anItem
+					  name: 'Inspect';
+					  iconName: #inspect;
+					  description: 'Inspect the raw records';
+					  shortcutKey: $i meta;
+					  action: [ (DSSpy materialize: fileListPresenter selectedItem) inspect ] ];
+		  addActionWith: [ :anItem |
+				  anItem
+					  name: 'Inspect history';
+					  iconName: #history;
+					  description: 'Inspect the record history';
+					  shortcutKey: $h meta;
+					  action: [ (self getHistoryFrom: fileListPresenter selectedItem) inspect ] ];
+		  addActionWith: [ :anItem |
+				  anItem
+					  name: 'Remove';
+					  iconName: #remove;
+					  description: 'Remove the record from list';
+					  shortcutKey: $x meta;
+					  action: [ self removeFile: fileListPresenter selectedItem ] ];
+		  yourself
+]
+
+{ #category : 'operations' }
+DSRecordBrowser >> openAddFileDialog [
+	"Opens a dialog where the user can select a file to be addded into the presenter."
+
+	| newFiles |
+	newFiles := StOpenFilePresenter new
+		            beMultipleSelection;
+		            defaultFolder: DSSpy logger loggingDirectory;
+		            openModal.
+	newFiles ifNotNil: [ newFiles do: [ :file | self addFile: file asFileReference ] ]
+]
+
+{ #category : 'accessing' }
+DSRecordBrowser >> recorderWindow [
+
+	^ timerWindow
+]
+
+{ #category : 'layout' }
+DSRecordBrowser >> recordsFilter [
+
+	^ SpChooserPresenter new sourceItems: DSAbstractEventRecord getNonAbstractSubClasses 
+]
+
+{ #category : 'layout' }
+DSRecordBrowser >> recordsTable [
+
+	^ self newTreeTable
+		  addColumn: (SpStringTableColumn new
+				   title: 'Event';
+				   displayBackgroundColor: [ :association | association value ];
+				   evaluated: [ :association | association key eventName asString ];
+				   displayColor: [ :aRecord | Color white ];
+				   yourself);
+		  addColumn: (SpStringTableColumn new
+				   title: 'Event type';
+				   displayBackgroundColor: [ :association | association value ];
+				   evaluated: [ :association | association key class asString ];
+				   displayColor: [ :aRecord | Color white ];
+				   yourself);
+		  addColumn: (SpStringTableColumn new
+				   title: 'Time';
+				   displayBackgroundColor: [ :association | association value ];
+				   evaluated: [ :association | association key dateTime asTime print24 ];
+				   displayColor: [ :aRecord | Color white ];
+				   yourself);
+		  beResizable;
+		  actions: self recordsTableActions;
+		  yourself
+]
+
+{ #category : 'operations' }
+DSRecordBrowser >> recordsTableActions [
+	"List actions that can be done on a record in the table, such as inspecting it."
+
+	^ SpActionGroup new
+		  addActionWith: [ :anItem |
+				  anItem
+					  name: 'Inspect';
+					  iconName: #inspect;
+					  description: 'Inspect the raw records';
+					  shortcutKey: $i meta;
+					  action: [ recordsTablePresenter selectedItem key inspect ] ];
+		  yourself
+]
+
+{ #category : 'files' }
+DSRecordBrowser >> removeFile: aFileReference [
+
+	files := files reject: [ :fileReference | fileReference = aFileReference ].
+	fileListPresenter items: self files.
+	fileListPresenter selectItem: (files ifNotEmpty: [ files last ])
+]
+
+{ #category : 'layout' }
+DSRecordBrowser >> startRecordButton [
+
+	^ SpToolbarButtonPresenter new
+		  label: 'Start';
+		  icon: (self iconNamed: #glamorousGo);
+		  help: 'Start recording events.';
+		  action: [ self startRecording ];
+		  enabled: DSSpy recordingSession not;
+		  yourself
+]
+
+{ #category : 'recording' }
+DSRecordBrowser >> startRecording [
+	"Starts recording events and instianciates a new RecorderWindow that displays a timer and shows that Debugging Spy is recordering."
+
+	timerWindow := DSTimerWindow new.
+	timerWindow 
+		openInWorld;
+		startTimer.
+	DSSpyInstrumenter instrumentSystem.
+	self updateToolbar
+]
+
+{ #category : 'layout' }
+DSRecordBrowser >> stopRecordButton [
+
+	^ SpToolbarButtonPresenter new
+		  label: 'Stop';
+		  icon: (self iconNamed: #stop);
+		  help: 'Stop recording events.';
+		  action: [ self stopRecording ];
+		  enabled: DSSpy recordingSession;
+		  yourself
+]
+
+{ #category : 'recording' }
+DSRecordBrowser >> stopRecording [
+	"Stops the recording session and closes the RecorderWindow."
+
+	DSSpyInstrumenter stopInstrumentation.
+	timerWindow stopTimer.
+	self currentWorld removeMorph: timerWindow.
+	self updateToolbar
+]
+
+{ #category : 'layout' }
+DSRecordBrowser >> timelineChart [
+
+	| history names chart data |
+	fileListPresenter selectedItem ifNil: [ ^ nil ].
+
+	history := self getHistoryFrom: fileListPresenter selectedItem.
+	names := history windows collect: [ :i | i getWindowType ].
+
+	data := self getTimelinePointsFrom: history.
+	data size < 2 ifTrue: [ ^ nil ].
+
+	chart := RSCompositeChart new.
+	chart addAll: data.
+
+	chart verticalTick fromNames: names.
+
+	chart horizontalTick
+		useNiceLabel;
+		numberOfTicks: history windows size // 2;
+		useDiagonalLabel;
+		labelConversion: [ :v | (DateAndTime fromSeconds: v // 1000000000) asTime ]. 
+		
+		"Plots are instancied using their dateTime as nano seconds to prevent events that last less than a second to be hided, so we convert them into seconds to get the label."
+
+	chart build.
+	^ chart
+]
+
+{ #category : 'layout' }
+DSRecordBrowser >> toolbar [
+	"Instanciates a new toolbar to be displayed on layout."
+
+	^ self newToolbar
+		  addItem: self addRecordButton;
+		  addItem: startRecordButtonPresenter;
+		  addItem: stopRecordButtonPresenter;
+		  addItem: self filterRecordsButton
+]
+
+{ #category : 'operations' }
+DSRecordBrowser >> updateRecordsTable: filesPresenter [
+	"Updates the records presenter and add to each record its corresponding color."
+
+	| fileRef recordColorAssociations |
+	recordColorAssociations := Array new.
+	fileRef := filesPresenter selectedItem.
+
+	fileRef ifNotNil: [
+			recordColorAssociations := self getRecordColorAssociationsFrom: (self getHistoryFrom: fileRef) windows.
+			recordColorAssociations := recordColorAssociations reject: [ :association |
+				                           recordsFilter chosenItems includes: association key class ] ].
+
+	recordsTablePresenter roots: recordColorAssociations 
+]
+
+{ #category : 'operations' }
+DSRecordBrowser >> updateTimelineChart [
+	"Regenerates the timeline chart using the selected record's data"
+
+	| chart |
+	chart := self timelineChart.
+	chart
+		ifNil: [ graphicTimeline script: [ :canvas |  ] ]
+		ifNotNil: [ graphicTimeline script: [ :canvas | chart renderIn: canvas ] ].
+	graphicTimeline refresh
+]
+
+{ #category : 'layout' }
+DSRecordBrowser >> updateToolbar [
+
+	startRecordButtonPresenter enabled: DSSpy recordingSession not.
+	stopRecordButtonPresenter enabled: DSSpy recordingSession
+]
+
+{ #category : 'accessing' }
+DSRecordBrowser >> windowIcon [
+
+	^ self iconNamed: #smallObjects 
+]
+
+{ #category : 'accessing' }
+DSRecordBrowser >> windowTitle [
+
+	^ 'Debugging record browser'
+]
diff --git a/DebuggingSpy-Browser/DSTimerWindow.class.st b/DebuggingSpy-Browser/DSTimerWindow.class.st
new file mode 100644
index 0000000..efb4d62
--- /dev/null
+++ b/DebuggingSpy-Browser/DSTimerWindow.class.st
@@ -0,0 +1,153 @@
+"
+This class is a window displaying some informations while DebuggingSpy is recording.
+"
+Class {
+	#name : 'DSTimerWindow',
+	#superclass : 'SystemWindow',
+	#instVars : [
+		'timerMorph',
+		'running',
+		'startTime',
+		'timer',
+		'timeNowMorph'
+	],
+	#category : 'DebuggingSpy-Browser',
+	#package : 'DebuggingSpy-Browser'
+}
+
+{ #category : 'initialization' }
+DSTimerWindow >> buildUI [
+	"Builds the windows UI that contains : an icon that shows that Debugging Spy is recording, a chronometer, a timer that shows actual time and a stop recording button."
+
+	timerMorph := self timerMorph.
+	timeNowMorph := self timeNowMorph.
+
+	self
+		addMorph: self recordingIcon;
+		addMorph: timerMorph;
+		addMorph: timeNowMorph;
+		addMorph: self stopButton
+]
+
+{ #category : 'resize/collapse' }
+DSTimerWindow >> collapseOrExpand [
+
+	^ self
+]
+
+{ #category : 'timer' }
+DSTimerWindow >> elapsedTime [
+	"Returns the elapsed time since the timer's start."
+
+	^ Time current asSeconds - startTime
+]
+
+{ #category : 'initialization' }
+DSTimerWindow >> initialize [
+
+	super initialize.
+	running := false.
+	self minimumExtent: self size.
+	self initializeProperties.
+	self buildUI
+]
+
+{ #category : 'initialization' }
+DSTimerWindow >> initializeProperties [
+
+	self
+		setLabel: 'DSSpy recorder';
+		extent: self size;
+		beSticky;
+		makeUnclosable;
+		removeLabelArea;
+		removeBoxes;
+		beUnresizeable
+]
+
+{ #category : 'accessing' }
+DSTimerWindow >> margin [
+	"Space around the window"
+
+	^ 5 @ 32
+]
+
+{ #category : 'wiw support' }
+DSTimerWindow >> morphicLayerNumber [
+	"To ensure the recorder window is always displayed at screen and cannot be covered"
+
+	^ 12
+]
+
+{ #category : 'opening' }
+DSTimerWindow >> openInWorld [
+
+	super openInWorld.
+	self position: self currentWorld extent - self extent - self margin
+]
+
+{ #category : 'layout' }
+DSTimerWindow >> recordingIcon [
+	"Instanciates a new icon that shows that Debugging Spy is recording."
+
+	^ ImageMorph new
+		  image: (self iconNamed: #glamorousRedCircle);
+		  position: 0 @ 7;
+		  yourself
+]
+
+{ #category : 'accessing' }
+DSTimerWindow >> size [
+
+	^ 150 @ 30
+]
+
+{ #category : 'timer' }
+DSTimerWindow >> startTimer [
+
+	running ifTrue: [ ^ self ].
+
+	startTime := Time current asSeconds.
+	running := true.
+	timer := [
+		         [ running ] whileTrue: [
+				         timerMorph contents: (Time fromSeconds: self elapsedTime) print24.
+				         timeNowMorph contents: Time now print24.
+				         (Delay forMilliseconds: 50) wait ] ] fork
+]
+
+{ #category : 'layout' }
+DSTimerWindow >> stopButton [
+	"Instanciates a new morph button that stops the recording and closes the window when clicked."
+
+	^ PluggableButtonMorph new
+		  label: (IconicListItemMorph new icon: (self iconNamed: #stop));
+		  model: DSRecordBrowser uniqueInstance;
+		  actionSelector: #stopRecording;
+		  position: 125 @ 4;
+		  yourself
+]
+
+{ #category : 'timer' }
+DSTimerWindow >> stopTimer [
+
+	running := false
+]
+
+{ #category : 'layout' }
+DSTimerWindow >> timeNowMorph [
+	"Instanciates a new morph that shows the actual time."
+
+	^ StringMorph new
+		  contents: Time now print24;
+		  position: 75 @ 6
+]
+
+{ #category : 'layout' }
+DSTimerWindow >> timerMorph [
+	"Insanciates a new morph that contains the seconds timer on the window."
+
+	^ StringMorph new
+		  contents: '00:00:000';
+		  position: 15 @ 6
+]
diff --git a/DebuggingSpy-Browser/package.st b/DebuggingSpy-Browser/package.st
new file mode 100644
index 0000000..0831d90
--- /dev/null
+++ b/DebuggingSpy-Browser/package.st
@@ -0,0 +1 @@
+Package { #name : 'DebuggingSpy-Browser' }
diff --git a/DebuggingSpy/DSAbstractBrowserRecord.class.st b/DebuggingSpy/DSAbstractBrowserRecord.class.st
index 323bd07..3564384 100644
--- a/DebuggingSpy/DSAbstractBrowserRecord.class.st
+++ b/DebuggingSpy/DSAbstractBrowserRecord.class.st
@@ -9,6 +9,12 @@ Class {
 	#tag : 'Records'
 }
 
+{ #category : 'testing' }
+DSAbstractBrowserRecord class >> isAbstract [
+
+	^ self = DSAbstractBrowserRecord
+]
+
 { #category : 'actions api' }
 DSAbstractBrowserRecord >> record: aCommandObject [
 
diff --git a/DebuggingSpy/DSAbstractDebugPointEventRecord.class.st b/DebuggingSpy/DSAbstractDebugPointEventRecord.class.st
index 7957707..5ddcfd3 100644
--- a/DebuggingSpy/DSAbstractDebugPointEventRecord.class.st
+++ b/DebuggingSpy/DSAbstractDebugPointEventRecord.class.st
@@ -18,6 +18,12 @@ Class {
 	#tag : 'Records'
 }
 
+{ #category : 'testing' }
+DSAbstractDebugPointEventRecord class >> isAbstract [
+
+	^ self = DSAbstractDebugPointEventRecord
+]
+
 { #category : 'converting' }
 DSAbstractDebugPointEventRecord >> asDebugPointRecord [
 
diff --git a/DebuggingSpy/DSAbstractDebuggerActionRecord.class.st b/DebuggingSpy/DSAbstractDebuggerActionRecord.class.st
index 98d2ade..e9b7d4e 100644
--- a/DebuggingSpy/DSAbstractDebuggerActionRecord.class.st
+++ b/DebuggingSpy/DSAbstractDebuggerActionRecord.class.st
@@ -8,3 +8,9 @@ Class {
 	#package : 'DebuggingSpy',
 	#tag : 'Records'
 }
+
+{ #category : 'testing' }
+DSAbstractDebuggerActionRecord class >> isAbstract [
+
+	^ self = DSAbstractDebuggerActionRecord
+]
diff --git a/DebuggingSpy/DSAbstractEventRecord.class.st b/DebuggingSpy/DSAbstractEventRecord.class.st
index 0c7ecf5..2ca3c1b 100644
--- a/DebuggingSpy/DSAbstractEventRecord.class.st
+++ b/DebuggingSpy/DSAbstractEventRecord.class.st
@@ -23,6 +23,17 @@ DSAbstractEventRecord class >> for: anObject [
 	^ rec
 ]
 
+{ #category : 'accessing' }
+DSAbstractEventRecord class >> getNonAbstractSubClasses [
+	"Returns a list of all non-abstract subclasses, representing all record classes."
+
+	| classes |
+	classes := (self subclasses reject: [ :subclass | subclass isAbstract ]) asOrderedCollection.
+	self subclasses do: [ :subclass | classes addAll: subclass getNonAbstractSubClasses ].
+
+	^ classes
+]
+
 { #category : 'accessing' }
 DSAbstractEventRecord class >> link [
 
diff --git a/DebuggingSpy/DSAbstractExtendedRecord.class.st b/DebuggingSpy/DSAbstractExtendedRecord.class.st
index 9a4356e..fbe7276 100644
--- a/DebuggingSpy/DSAbstractExtendedRecord.class.st
+++ b/DebuggingSpy/DSAbstractExtendedRecord.class.st
@@ -17,6 +17,12 @@ DSAbstractExtendedRecord class >> for: anObject [
 		  yourself
 ]
 
+{ #category : 'testing' }
+DSAbstractExtendedRecord class >> isAbstract [
+
+	^ self = DSAbstractExtendedRecord
+]
+
 { #category : 'accessing' }
 DSAbstractExtendedRecord >> dateTime [
 
diff --git a/DebuggingSpy/DSAbstractHaltRecord.class.st b/DebuggingSpy/DSAbstractHaltRecord.class.st
index 659fa0c..6ee292d 100644
--- a/DebuggingSpy/DSAbstractHaltRecord.class.st
+++ b/DebuggingSpy/DSAbstractHaltRecord.class.st
@@ -13,6 +13,12 @@ Class {
 	#tag : 'Records'
 }
 
+{ #category : 'testing' }
+DSAbstractHaltRecord class >> isAbstract [
+
+	^ self = DSAbstractHaltRecord
+]
+
 { #category : 'accessing' }
 DSAbstractHaltRecord >> method [
 
diff --git a/DebuggingSpy/DSAbstractSindarinActionRecord.class.st b/DebuggingSpy/DSAbstractSindarinActionRecord.class.st
index 63bda5e..d61e330 100644
--- a/DebuggingSpy/DSAbstractSindarinActionRecord.class.st
+++ b/DebuggingSpy/DSAbstractSindarinActionRecord.class.st
@@ -8,3 +8,9 @@ Class {
 	#package : 'DebuggingSpy',
 	#tag : 'Records'
 }
+
+{ #category : 'testing' }
+DSAbstractSindarinActionRecord class >> isAbstract [
+
+	^ self = DSAbstractSindarinActionRecord
+]
diff --git a/DebuggingSpy/DSAbstractTaskRecord.class.st b/DebuggingSpy/DSAbstractTaskRecord.class.st
index 7d20053..72e8f90 100644
--- a/DebuggingSpy/DSAbstractTaskRecord.class.st
+++ b/DebuggingSpy/DSAbstractTaskRecord.class.st
@@ -15,6 +15,12 @@ Class {
 	#tag : 'Records'
 }
 
+{ #category : 'testing' }
+DSAbstractTaskRecord class >> isAbstract [
+
+	^ self = DSAbstractTaskRecord
+]
+
 { #category : 'accessing' }
 DSAbstractTaskRecord >> description [
 
diff --git a/DebuggingSpy/DSClipboardActionRecord.class.st b/DebuggingSpy/DSClipboardActionRecord.class.st
index e7c0fab..fa424c4 100644
--- a/DebuggingSpy/DSClipboardActionRecord.class.st
+++ b/DebuggingSpy/DSClipboardActionRecord.class.st
@@ -15,6 +15,12 @@ Class {
 	#tag : 'Records'
 }
 
+{ #category : 'testing' }
+DSClipboardActionRecord class >> isAbstract [
+
+	^ self = DSClipboardActionRecord
+]
+
 { #category : 'accessing' }
 DSClipboardActionRecord >> clipboardText [
 
diff --git a/DebuggingSpy/DSCodeActionRecord.class.st b/DebuggingSpy/DSCodeActionRecord.class.st
index bc029a3..099a922 100644
--- a/DebuggingSpy/DSCodeActionRecord.class.st
+++ b/DebuggingSpy/DSCodeActionRecord.class.st
@@ -13,6 +13,12 @@ Class {
 	#tag : 'Records'
 }
 
+{ #category : 'testing' }
+DSCodeActionRecord class >> isAbstract [
+
+	^ self = DSCodeActionRecord
+]
+
 { #category : 'actions api' }
 DSCodeActionRecord >> record: anEditor [
 
diff --git a/DebuggingSpy/DSDebugPointRecord.class.st b/DebuggingSpy/DSDebugPointRecord.class.st
index ecc792e..bb706cd 100644
--- a/DebuggingSpy/DSDebugPointRecord.class.st
+++ b/DebuggingSpy/DSDebugPointRecord.class.st
@@ -24,6 +24,12 @@ DSDebugPointRecord class >> debugpointremoved: event [
 	^ self subclassResponsibility
 ]
 
+{ #category : 'testing' }
+DSDebugPointRecord class >> isAbstract [
+
+	^ self = DSDebugPointRecord
+]
+
 { #category : 'testing' }
 DSDebugPointRecord >> canOpenDebuggers [
 
diff --git a/DebuggingSpy/DSMethodDebugPointRecord.class.st b/DebuggingSpy/DSMethodDebugPointRecord.class.st
index d79380e..33051fc 100644
--- a/DebuggingSpy/DSMethodDebugPointRecord.class.st
+++ b/DebuggingSpy/DSMethodDebugPointRecord.class.st
@@ -47,6 +47,12 @@ DSMethodDebugPointRecord class >> for: anEvent [
 	^ anEvent
 ]
 
+{ #category : 'testing' }
+DSMethodDebugPointRecord class >> isAbstract [
+
+	^ self = DSMethodDebugPointRecord 
+]
+
 { #category : 'accessing' }
 DSMethodDebugPointRecord >> eventName [
 
diff --git a/DebuggingSpy/DSMethodEventRecord.class.st b/DebuggingSpy/DSMethodEventRecord.class.st
index 3651e2e..f6ad772 100644
--- a/DebuggingSpy/DSMethodEventRecord.class.st
+++ b/DebuggingSpy/DSMethodEventRecord.class.st
@@ -21,6 +21,12 @@ DSMethodEventRecord class >> added: aMethod [
 		  yourself
 ]
 
+{ #category : 'testing' }
+DSMethodEventRecord class >> isAbstract [
+
+	^ self = DSMethodEventRecord
+]
+
 { #category : 'instance creation' }
 DSMethodEventRecord class >> modified: aMethod [
 
diff --git a/DebuggingSpy/DSMouseEventRecord.class.st b/DebuggingSpy/DSMouseEventRecord.class.st
index 5300f4e..3b34266 100644
--- a/DebuggingSpy/DSMouseEventRecord.class.st
+++ b/DebuggingSpy/DSMouseEventRecord.class.st
@@ -16,6 +16,12 @@ Class {
 	#tag : 'Records'
 }
 
+{ #category : 'testing' }
+DSMouseEventRecord class >> isAbstract [
+
+	^ self = DSMouseEventRecord
+]
+
 { #category : 'actions api' }
 DSMouseEventRecord >> record: aWindow [
 
diff --git a/DebuggingSpy/DSSTONFileLogger.class.st b/DebuggingSpy/DSSTONFileLogger.class.st
index 4b780d7..c43d04a 100644
--- a/DebuggingSpy/DSSTONFileLogger.class.st
+++ b/DebuggingSpy/DSSTONFileLogger.class.st
@@ -80,6 +80,12 @@ DSSTONFileLogger >> loggingFileName [
 		  loggingFilename := self defaultLoggingFileName ]
 ]
 
+{ #category : 'accessing' }
+DSSTONFileLogger >> loggingFileName: aFileName [
+
+	loggingFilename := aFileName
+]
+
 { #category : 'accessing' }
 DSSTONFileLogger >> loggingFileReference [
 
@@ -87,6 +93,12 @@ DSSTONFileLogger >> loggingFileReference [
 		  loggingFileReference := self ensureCreateLoggingFileReference ]
 ]
 
+{ #category : 'accessing' }
+DSSTONFileLogger >> loggingFileReference: aFileReference [
+
+	^ loggingFileReference := aFileReference
+]
+
 { #category : 'initialization' }
 DSSTONFileLogger >> reset [
 
diff --git a/DebuggingSpy/DSSpyInstrumenter.class.st b/DebuggingSpy/DSSpyInstrumenter.class.st
index 14407d3..f2879db 100644
--- a/DebuggingSpy/DSSpyInstrumenter.class.st
+++ b/DebuggingSpy/DSSpyInstrumenter.class.st
@@ -23,6 +23,9 @@ DSSpyInstrumenter class >> stopInstrumentation [
 
 	"Stop the recording session"
 	DSSpy recordingSession: false.
+	
+	"Stop the auto serialization"
+	DSRecordRegistry autoSerialize: false.
 
 	"Stop listening to events for recording"
 	SystemAnnouncer uniqueInstance unsubscribe: DSSpy.
diff --git a/DebuggingSpy/DSWindowEventRecord.class.st b/DebuggingSpy/DSWindowEventRecord.class.st
index 1680639..151b470 100644
--- a/DebuggingSpy/DSWindowEventRecord.class.st
+++ b/DebuggingSpy/DSWindowEventRecord.class.st
@@ -15,6 +15,12 @@ Class {
 	#tag : 'Records'
 }
 
+{ #category : 'testing' }
+DSWindowEventRecord class >> isAbstract [
+
+	^ self = DSWindowEventRecord
+]
+
 { #category : 'actions api' }
 DSWindowEventRecord >> record: aWindowEvent [
 
diff --git a/DebuggingSpy/DSWindowRecord.class.st b/DebuggingSpy/DSWindowRecord.class.st
index a722898..8e50f9c 100644
--- a/DebuggingSpy/DSWindowRecord.class.st
+++ b/DebuggingSpy/DSWindowRecord.class.st
@@ -103,6 +103,14 @@ DSWindowRecord >> events: anObject [
 	events := anObject
 ]
 
+{ #category : 'accessing' }
+DSWindowRecord >> getWindowType [
+
+	toolInfos ifNotNil: [ toolInfos ifNotEmpty: [ ^ toolInfos first toolClassName ] ].
+	type isString ifTrue: [ ^ type ].
+	^ 'External Window'
+]
+
 { #category : 'accessing' }
 DSWindowRecord >> idleTime [
 
@@ -213,13 +221,7 @@ DSWindowRecord >> printOn: ws [
 { #category : 'printing' }
 DSWindowRecord >> printTypeOn: aStream [
 
-	toolInfos ifNotNil: [
-		aStream << toolInfos first toolClassName.
-		^ self ].
-	type isString ifTrue: [
-		aStream << type.
-		^ self ].
-	aStream << 'External Window'
+	aStream << self getWindowType
 ]
 
 { #category : 'accessing' }