tensor/tensor.pro at master · Quiark/tensor · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
TEMPLATE = app

QT += qml quick
CONFIG += c++14 qml_debug

include(lib/libqmatrixclient.pri)

HEADERS += \
    client/models/messageeventmodel.h \
    client/models/roomlistmodel.h \
    client/imageprovider.h

SOURCES += client/main.cpp \
    client/models/messageeventmodel.cpp \
    client/models/roomlistmodel.cpp \
    client/imageprovider.cpp

RESOURCES += client/resources.qrc

# Additional import path used to resolve QML modules in Qt Creator's code model
QML_IMPORT_PATH =

# Default rules for deployment.
include(deployment.pri)

ICON = tensor.icns
RC_ICONS = tensor.ico

DISTFILES += \
    android/AndroidManifest.xml \
    android/gradle/wrapper/gradle-wrapper.jar \
    android/gradlew \
    android/res/values/libs.xml \
    android/build.gradle \
    android/gradle/wrapper/gradle-wrapper.properties \
    android/gradlew.bat \
    notes.md \
    screen/revolutions.ini

ANDROID_PACKAGE_SOURCE_DIR = $$PWD/android

# qtdeploy config
!android {
    win32 {
            DEPLOY_COMMAND = windeployqt
            TARGET_EXT = .exe
    }
    macx {
            DEPLOY_COMMAND = macdeployqt
            TARGET_EXT = .app
    }

    # was:
    # debug, debug|release
    CONFIG( release ) {
        # debug
        #DEPLOY_TARGET = $$shell_quote($$shell_path($${OUT_PWD}/debug/$${TARGET}$${TARGET_EXT}))
    #} else {
        # release
        DEPLOY_TARGET = $$shell_quote($$shell_path($${OUT_PWD}/release/$${TARGET}$${TARGET_EXT}))
    }

    #  # Uncomment the following line to help debug the deploy command when running qmake
    #  warning($${DEPLOY_COMMAND} $${DEPLOY_TARGET})

    # Use += instead of = if you use multiple QMAKE_POST_LINKs
    QMAKE_POST_LINK = $${DEPLOY_COMMAND} --qmldir $$PWD/client/qml $${DEPLOY_TARGET}
}

android {
    # this is needed for NDK > 14 until qmake is updated to reflect the new locations
    QMAKE_CXXFLAGS += --sysroot=$$NDK_ROOT/sysroot
    contains(ANDROID_TARGET_ARCH,armeabi-v7a) {
        # openssl
        ANDROID_EXTRA_LIBS = \
            $$PWD/../../libs/android-openssl/jni/openssl/arch-armeabi-v7a/lib/libcrypto.so \
            $$PWD/../../libs/android-openssl/jni/openssl/arch-armeabi-v7a/lib/libssl.so
        QMAKE_INCDIR += $$NDK_ROOT/sysroot/usr/include/arm-linux-androideabi
    }
}