tibia-study/EditMinimapMarkerDialog.qml at main · ReloadBot/tibia-study · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
import QtQuick
import QtQuick.Controls
import QtQuick.Layouts


TibiaDialog {
  id: enterTextDialog
  caption: qsTrId("editminimapmark_caption")
  width: 285

  property QtObject controller: null
  property alias text: enteredTextField.text
  property int symbolID: 0


  function sendEnteredDataToController() {
    if(null != controller) {
      controller.onOkClicked(enteredTextField.text, symbolID);
    }
  } //function sendEnteredDataToController()


  onReturnPressedFunction: sendEnteredDataToController
  onCancelPressedFunction: controller!=null ? controller.onCancelClicked : null
  initialFocusItem: enteredTextField

  ColumnLayout {
    id: columns
    anchors { left: parent.left; right: parent.right}
    spacing: TibiaStyle.marginRelated


    TibiaText {
      Layout.fillWidth: true
      wrapMode: Text.Wrap
      text: qsTrId("editminimapmark_description")
      styleType: "Dialog"
    } //TibiaText

    TibiaTextField{
      id: enteredTextField
      Layout.fillWidth: true
      KeyNavigation.tab: enteredTextField
      focus:true
      maximumLength: 100
    } //TibiaTextField


    TibiaText {
      Layout.fillWidth: true
      Layout.topMargin: TibiaStyle.marginRelated //double the margin from marginRelated to Unrelated
      wrapMode: Text.Wrap
      text: qsTrId("editminimapmark_select_type")
      styleType: "Dialog"
    } //TibiaText

    GridLayout {
      columnSpacing: TibiaStyle.marginRelated
      rowSpacing: TibiaStyle.marginRelated
      columns: TibiaStyle.numberOfMinimapMarkersPerSelectRow

      ButtonGroup {
        id: selectedMinimapMarker
      } //ButtonGroup

      Repeater {
        model: TibiaStyle.numberOfMinimapMarkers

        delegate: TibiaIconSelectionButton {
          iconPath: "image://minimap-markers/" + modelData
          width: 16
          height: 16
          onClicked: { symbolID = modelData; }
          checked: (modelData == symbolID)
          ButtonGroup.group: selectedMinimapMarker
        } //TibiaIconButton
      } //Repeater

    } //RowLayout


    TibiaHorizontalSeparator {
      Layout.fillWidth: true
    } //TibiaHorizontalSeparator


    RowLayout {
      Layout.fillWidth: true
      spacing: TibiaStyle.marginUnrelated

      Item {
        Layout.fillWidth: true
      } //Item

      TibiaButton {
        id: okButton
        text: qsTrId("ok")
        onClicked: { sendEnteredDataToController(); }
      } //TibiaButton

      TibiaButton {
        id: cancelButton
        text: qsTrId("cancel")
        onClicked: controller!=null ?  controller.onCancelClicked() : undefined
      } //TibiaButton
    } //RowLayout

  }//ColumnLayout
} //TibiaDialog