Build/TWTL.nsi at master · TWTL/Build · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
; TWTL Installer NSIS Script

; inclusion and definitions
!include "MUI2.nsh"
!include ".\TWTL.defs.Files.nsh"
!include ".\TWTL.macro.RemoveFilesAndSubDirs.nsh"

!define ORGNAME "NOTRESPONDING"
!define APPNAME "TWTL"
!define VERSION_MAJOR 1
!define VERSION_MINOR 0
Unicode True
SetCompress Off

!define REG_KEY_INST_INFO \
  "Software\${APPNAME}"
!define REG_KEY_UNINST_INFO \
  "Software\Microsoft\Windows\CurrentVersion\Uninstall\${APPNAME}"

!define VERSION_STRING "${VERSION_MAJOR}.${VERSION_MINOR}"

; Beginning of installer description
Name "${APPNAME}"
Icon "TWTL.ico"
OutFile "TWTLInstaller.exe"

InstallDir "$ProgramFiles\${APPNAME}"
ShowInstDetails Show
XPStyle On
RequestExecutionLevel Admin

!define MUI_ICON "TWTL.ico"
!define MUI_UNICON "TWTL.ico"
!define MUI_HEADERIMAGE
!define MUI_HEADERIMAGE_BITMAP "TWTL.MUIHeaderImage.bmp"
!define MUI_HEADERIMAGE_UNBITMAP_NOSTRETCH
!define MUI_WELCOMEFINISHPAGE
!define MUI_WELCOMEFINISHPAGE_BITMAP "TWTL.MUIWelcomeFinishPage.bmp"
!define MUI_WELCOMEFINISHPAGE_BITMAP_NOSTRETCH
!define MUI_UNWELCOMEFINISHPAGE
!define MUI_UNWELCOMEFINISHPAGE_BITMAP "TWTL.MUIWelcomeFinishPage.bmp"
!define MUI_UNWELCOMEFINISHPAGE_BITMAP_NOSTRETCH
!define MUI_ABORTWARNING
!define MUI_COMPONENTSPAGE_NODESC

!insertmacro MUI_PAGE_WELCOME
!insertmacro MUI_PAGE_LICENSE "License.txt"
!insertmacro MUI_PAGE_COMPONENTS
!insertmacro MUI_PAGE_DIRECTORY
!insertmacro MUI_PAGE_INSTFILES
!insertmacro MUI_PAGE_FINISH

!insertmacro MUI_UNPAGE_WELCOME
!insertmacro MUI_UNPAGE_CONFIRM
!insertmacro MUI_UNPAGE_INSTFILES
!insertmacro MUI_UNPAGE_FINISH

!insertmacro MUI_LANGUAGE "Korean"
!insertmacro MUI_LANGUAGE "English"

Function .onInit
  !insertmacro MUI_LANGDLL_DISPLAY
FunctionEnd

Function un.onInit
  !insertmacro MUI_LANGDLL_DISPLAY
FunctionEnd

InstType "Full"
InstType "Minimal"

Section "Basic installation"
  SectionIn RO
  ; File installation
  SetOutPath $InstDir
  CreateDirectory $InstDir
  File License.txt
  File TWTL.ico
  File /oname=${INST_SERVICE_EXEC_NAME} "${BUILD_SERVICE_EXEC_PATH}"
  File /oname=${INST_ENGINE_EXEC_NAME} "${BUILD_ENGINE_EXEC_PATH}"
  File /oname=${INST_ENGINE_DLL1_NAME} "${BUILD_ENGINE_DLL1_PATH}"
  File /oname=${INST_ENGINE_DLL2_NAME} "${BUILD_ENGINE_DLL2_PATH}"
  File /oname=${INST_GUI_EXEC_NAME} "${BUILD_GUI_EXEC_PATH}"
  SetOutPath $InstDir\"${INST_GUI_DATA_NAME}"
  File /nonfatal /a /r "${BUILD_GUI_DATA_PATH}"
  ; Registry installation
  WriteRegStr HKLM \
    "${REG_KEY_INST_INFO}" \
    "SvcPath" "$InstDir\${INST_SERVICE_EXEC_NAME}"
  WriteRegStr HKLM \
    "${REG_KEY_INST_INFO}" \
    "EnginePath" "$InstDir\${INST_ENGINE_EXEC_NAME}"
  WriteRegStr HKLM \
    "${REG_KEY_INST_INFO}" \
    "GUIPath" "$InstDir\${INST_GUI_EXEC_NAME}"
  ; Service installation (startup: Section "Start service now")
  Exec '"$InstDir\${INST_SERVICE_EXEC_NAME}" Install'
  ; Uninstaller generation and registry uninstallation information
  WriteUninstaller "$InstDir\${INST_UNINST_EXEC_NAME}"
  WriteRegStr HKLM \
    "${REG_KEY_UNINST_INFO}" \
    "InstallLocation" "$\"$InstDir$\""
  WriteRegStr HKLM \
    "${REG_KEY_UNINST_INFO}" \
    "DisplayName" "${APPNAME}"
  WriteRegStr HKLM \
    "${REG_KEY_UNINST_INFO}" \
    "DisplayVersion" "${VERSION_STRING}"
  WriteRegStr HKLM \
    "${REG_KEY_UNINST_INFO}" \
    "DisplayIcon" "$\"$InstDir\TWTL.ico$\""
  WriteRegStr HKLM \
    "${REG_KEY_UNINST_INFO}" \
    "Publisher" "${ORGNAME}"
  WriteRegStr HKLM \
    "${REG_KEY_UNINST_INFO}" \
    "UninstallString" "$\"$InstDir\${INST_UNINST_EXEC_NAME}$\""
  WriteRegDWORD HKLM \
    "${REG_KEY_UNINST_INFO}" \
    "VersionMajor" ${VERSION_MAJOR}
  WriteRegDWORD HKLM \
    "${REG_KEY_UNINST_INFO}" \
    "VersionMinor" ${VERSION_MINOR}
SectionEnd

Section "Start service now"
  SectionIn 1 2
  Exec '"$InstDir\${INST_SERVICE_EXEC_NAME}" Start'
SectionEnd

Section "Create shortcut in Start menu"
  SectionIn 1
  CreateDirectory "$SMPrograms\${APPNAME}"
  CreateShortCut \
    "$SMPrograms\${APPNAME}\${APPNAME}.lnk" \
    "$InstDir\${INST_GUI_EXEC_NAME}" \
    "$InstDir\TWTL.ico"
SectionEnd

Section "Create shortcut in Desktop"
  SectionIn 1
  CreateShortCut \
    "$Desktop\${APPNAME}.lnk" \
    "$InstDir\${INST_GUI_EXEC_NAME}" \
    "$InstDir\TWTL.ico"
SectionEnd

Section "Uninstall"
  ; Stop and delete service
  Exec '"$InstDir\${INST_SERVICE_EXEC_NAME}" Stop'
  Exec '"$InstDir\${INST_SERVICE_EXEC_NAME}" Uninstall'
  sleep 1000 ; stand for service really removed
  ; Uninstall files
  !insertmacro RemoveFilesAndSubDirs "$InstDir"
  RmDir "$InstDir"
  !insertmacro RemoveFilesAndSubDirs "$SMPrograms\${APPNAME}"
  RmDir "$SMPrograms\${APPNAME}"
  Delete "$Desktop\${APPNAME}.lnk"
  ; Uninstall registry
  DeleteRegKey HKLM \
    "${REG_KEY_INST_INFO}"
  DeleteRegKey HKLM \
    "${REG_KEY_UNINST_INFO}"
SectionEnd