FZMM-Mod/build.gradle at dev · Zailer43/FZMM-Mod · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
plugins {
    id 'net.fabricmc.fabric-loom-remap' version "${loom_version}"
    id 'maven-publish'
}

version = project.mod_version
group = project.maven_group

base {
    archivesName = "${project.archives_base_name}-mc${project.minecraft_version}"
}

repositories {
    // modmenu
    maven {
        name = "TerraformersMC"
        url = "https://maven.terraformersmc.com/releases/"
    }

    // owo-lib
    maven { url = 'https://maven.wispforest.io' }
    maven { url 'https://jitpack.io' }

    // others
    maven { url = "https://api.modrinth.com/maven" }

}

loom {
    accessWidenerPath = file("src/main/resources/fzmm.accesswidener")
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings loom.officialMojangMappings()
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // Dependencies
    // Fabric API
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"

    def fabricDependencies = [
            'fabric-command-api-v2',
            'fabric-events-interaction-v0',
            'fabric-item-api-v1',
            'fabric-item-group-api-v1',
            'fabric-key-binding-api-v1',
            'fabric-resource-loader-v1',
            'fabric-object-builder-api-v1',
            'fabric-renderer-api-v1'
    ]

    fabricDependencies.forEach {
        modImplementation(fabricApi.module(it, project.fabric_api_version))
    }

    // owo lib
    modImplementation annotationProcessor ("io.wispforest:owo-lib:${project.owo_version}")

    // include this if you don't want force your users to install owo
    // sentinel will warn them and give the option to download it automatically
    include "io.wispforest:owo-sentinel:${project.owo_version}"

    // Mod Menu
    modImplementation "com.terraformersmc:modmenu:${project.modmenu_version}"

    // PlacerholderAPI
    modImplementation(include("maven.modrinth:placeholder-api:${project.placeholder_api_version}"))

    // Optional dependencies
    // Symbol chat
    modImplementation "maven.modrinth:symbol-chat:${project.symbol_chat_version}"
    modImplementation "maven.modrinth:reconfigure:${project.symbol_chat_reconfigure_version}"

    // Test dependencies
    testImplementation "net.fabricmc:fabric-loader-junit:${project.loader_version}"
}

processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": inputs.properties.version
    }
}

tasks.withType(JavaCompile).configureEach {
    it.options.release = 21
}

java {
    withSourcesJar()

    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

jar {
    inputs.property "archivesName", project.base.archivesName

    from("LICENSE") {
        rename { "${it}_${inputs.properties.archivesName}"}
    }
}

test {
    useJUnitPlatform()
}

publishing {
    publications {
        create("mavenJava", MavenPublication) {
            artifactId = project.archives_base_name
            from components.java
        }
    }

    repositories {

    }
}