SCIF/build.gradle at master · apl-cornell/SCIF · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
plugins {
    id 'java'
    id "org.xbib.gradle.plugin.jflex" version "1.6.0" // a plugin for building a lexer using jflex
    id "idea"
    id 'application'
}

version = '0.5.0'
group = 'apl'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

ant.importBuild("sherrloc/GenErrorDiagnostic/build.xml") {
    antTargetName -> "slc-" + antTargetName
}

repositories {
    mavenCentral()
}

sourceSets {
    main {
        jflex {
            srcDir "src"
        }
        java {
            srcDirs = ['src', 'build/generated-src/cup']
        }
        resources {
            srcDirs = ['src/config', 'resources']
        }
    }
    test {
        java {
            srcDirs = ['test/src']
        }
        resources {
            srcDirs = ['test/contracts']
        }
    }
}

// Custom CUP task using Cornell CUP from lib/java_cup.jar
abstract class CupTask extends DefaultTask {
    @Inject
    abstract ExecOperations getExecOps()

    @Inject
    abstract ObjectFactory getObjectFactory()

    @InputFiles
    FileTree cupFiles

    @OutputDirectory
    File cupOutput

    @InputFile
    File cupJar

    @TaskAction
    void runCup() {
        cupOutput.mkdirs()
        def cupClasspath = objectFactory.fileCollection().from(cupJar)
        cupFiles.each { cupFile ->
            execOps.javaexec {
                mainClass = "java_cup.Main"
                classpath = cupClasspath
                args = ["-expect", "1000", "-interface", "-parser", "Parser",
                        "-destdir", cupOutput.absolutePath,
                        cupFile.absolutePath]
            }
        }
    }
}

tasks.register("cup", CupTask) {
    cupFiles = fileTree("src") { include "SCIF.cup" }
    cupOutput = file("build/generated-src/cup/parser")
    cupJar = file("lib/java_cup.jar")
}

idea {
    module {
        generatedSourceDirs += file("build/generated-src/cup")
    }
}

compileJava.configure {
    dependsOn("cup", "slc-jar")
}

def fatJar = tasks.register("fatJar", Jar) {
    manifest {
        attributes "Main-Class": "SCIF"
        attributes 'Multi-Release': 'true'
    }

    archiveFileName = "SCIF.jar"

    duplicatesStrategy = DuplicatesStrategy.INCLUDE

    from {
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    } {
        exclude "META-INF/*.SF"
        exclude "META-INF/*.DSA"
        exclude "META-INF/*.RSA"
    }
    with jar
}

test {
    useJUnitPlatform()

    testLogging {
        events "passed", "skipped", "failed", "standardOut", "standardError"
  }
}

tasks.named("assemble") {
    dependsOn(fatJar)
}

configurations {
    priority // hack to force sherrloc to apprear later than jflex and cup
    sourceSets.main.compileClasspath = configurations.priority + sourceSets.main.compileClasspath
    sourceSets.main.runtimeClasspath = configurations.priority + sourceSets.main.runtimeClasspath
    sourceSets.test.compileClasspath = configurations.priority + sourceSets.test.compileClasspath
    sourceSets.test.runtimeClasspath = configurations.priority + sourceSets.test.runtimeClasspath
}

dependencies {
    priority("de.jflex:jflex:1.8.2") {
        exclude group: 'com.github.vbmacher', module: 'java-cup-runtime'
    }
    priority files('lib/java_cup.jar')
    implementation 'org.apache.logging.log4j:log4j-core:2.12.1'
    implementation 'com.owlike:genson:1.5'
    implementation "info.picocli:picocli:4.0.0"
    implementation files("sherrloc/GenErrorDiagnostic/lib/SHErrLoc.jar")
    implementation 'org.junit.jupiter:junit-jupiter:5.7.0'
    testImplementation "org.junit.jupiter:junit-jupiter-api:5.9.0"
    testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:5.9.0"
    testRuntimeOnly "org.junit.platform:junit-platform-launcher"
}

def dummyOutputStream = new OutputStream() {
    @Override
    public void write(int b) {}
}

application {
    mainClass = "SCIF"
}

run {
    enableAssertions = true
}