SyncAPI/build.gradle at main · dmcg310/SyncAPI · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
import com.github.spotbugs.snom.SpotBugsTask

plugins {
	id 'java'
	id 'jacoco'
	id 'checkstyle'
	id 'com.github.spotbugs' version '6.4.8'
	id 'org.springframework.boot' version '4.0.1'
	id 'io.spring.dependency-management' version '1.1.7'
}

group = 'com.syncapi'
version = '0.0.1-SNAPSHOT'
description = 'API testing and documentation platform'

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(21)
	}
}

repositories {
	mavenCentral()
}

dependencies {
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
	implementation 'org.springframework.boot:spring-boot-starter-security'
	implementation 'org.springframework.boot:spring-boot-starter-validation'
	implementation 'org.springframework.boot:spring-boot-starter-webmvc'
	implementation 'io.jsonwebtoken:jjwt-api:0.13.0'
	runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.13.0'
	runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.13.0'
	runtimeOnly 'org.postgresql:postgresql'
	developmentOnly 'org.springframework.boot:spring-boot-devtools'
	testImplementation "org.testcontainers:testcontainers:2.0.3"
	testImplementation 'org.testcontainers:testcontainers-postgresql'
	testImplementation 'org.springframework.security:spring-security-test'
	testImplementation 'org.springframework.boot:spring-boot-starter-test'
	testImplementation 'org.springframework.boot:spring-boot-starter-data-jpa-test'
	testImplementation 'org.springframework.boot:spring-boot-starter-security-test'
	testImplementation 'org.springframework.boot:spring-boot-starter-validation-test'
	testImplementation 'org.springframework.boot:spring-boot-starter-webmvc-test'
	testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

checkstyle {
	toolVersion = '10.12.4'
}

spotbugs {
	toolVersion = '4.9.8'
	effort = 'max'
	reportLevel = 'medium'
	excludeFilter = file('spotbugs-exclude.xml')
}

tasks.withType(SpotBugsTask).configureEach {
	reports {
		html.required = true
		xml.required = false
	}
}

tasks.named('check') {
	dependsOn 'checkstyleMain', 'spotbugsMain'
}

tasks.named('test') {
	useJUnitPlatform()
	finalizedBy jacocoTestReport
	jvmArgs '-XX:+EnableDynamicAgentLoading'
}

jacocoTestReport {
	dependsOn test
	reports {
		xml.required = true
		html.required = true
	}
}