AUR pointing to https://git.tozt.net/rbw which returns 503

[CupricReki]

git pull https://git.tozt.net/rbw

error: The requested URL returned error: 503 (curl_result = 22, http_code = 503, sha1 = d348fe049bf5c1f1ad03fb30f98471d06aa75b3b)
error: Unable to find d348fe049bf5c1f1ad03fb30f98471d06aa75b3b under https://git.tozt.net/rbw
Cannot obtain needed blob d348fe049bf5c1f1ad03fb30f98471d06aa75b3b
while processing commit e673049e1fe58a1d266ce64722ea467e2edb9c2a.
error: fetch failed.

Suggested PKGBUILD

Please fix the upstream repo or point to this github repository.

# Maintainer: Jesse Luehrs <archlinux@tozt.net>
pkgname=rbw-git
_pkgname=rbw
pkgver=0.1.0.r566.g77464d414a
pkgrel=2
makedepends=('rust' 'cargo' 'git')
depends=('pinentry')
conflicts=("$_pkgname")
provides=("$_pkgname=${pkgver/\.r*/}")
arch=('i686' 'x86_64' 'aarch64')
url="https://github.com/doy/rbw"
source=("$_pkgname"::"git+https://github.com/doy/$_pkgname.git")
sha256sums=('SKIP')
pkgdesc="unofficial bitwarden cli"
license=('MIT')
options=('!lto')

pkgver() {
  cd "$_pkgname"
  git describe --abbrev=10 --long --tags --match 'v*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd "$_pkgname"
  cargo fetch --locked
}

build() {
    cd "${_pkgname}"
    export RUSTUP_TOOLCHAIN=stable

    cargo build --frozen --release --all-features
    ./target/release/rbw gen-completions bash > bash-completions
    ./target/release/rbw gen-completions zsh > zsh-completions
    ./target/release/rbw gen-completions fish > fish-completions
}

check() {
  cd "$_pkgname"
  export RUSTUP_TOOLCHAIN=stable
  cargo test --frozen --all-features
}

package() {
    cd "$_pkgname"
    install -Dm0755 target/release/rbw -t "${pkgdir}/usr/bin"
    install -Dm0755 target/release/rbw-agent -t "${pkgdir}/usr/bin"
    install -Dm0644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
    install -Dm0644 bash-completions "${pkgdir}/usr/share/bash-completion/completions/rbw"
    install -Dm0644 zsh-completions "${pkgdir}/usr/share/zsh/site-functions/_rbw"
    install -Dm0644 fish-completions "${pkgdir}/usr/share/fish/vendor_completions.d/rbw.fish"
}

I'm happy to fix the AUR if you add me as a maintainer. My username is CupricReki