|
| 1 | +#!/usr/bin/perl |
| 2 | + |
| 3 | +# Detect bare 'grep' used as a test assertion where 'test_grep' |
| 4 | +# should be used, and '! test_grep' where 'test_grep !' should |
| 5 | +# be used. Uses the shared shell parser to correctly identify |
| 6 | +# command boundaries, avoiding false positives from 'grep' in |
| 7 | +# arguments, strings, heredocs, or command substitutions. |
| 8 | + |
| 9 | +use strict; |
| 10 | +use warnings; |
| 11 | +use File::Basename; |
| 12 | +do(dirname($0) . "/lib-shell-parser.pl") |
| 13 | + or die "$0: failed to load lib-shell-parser.pl: $@$!\n"; |
| 14 | + |
| 15 | +my $exit_code = 0; |
| 16 | + |
| 17 | +package GrepLintParser; |
| 18 | + |
| 19 | +our @ISA = ('ScriptParser'); |
| 20 | + |
| 21 | +# Tokens that mark the start of a new command. |
| 22 | +my %cmd_start; |
| 23 | +@cmd_start{qw(&& || ; ;; do then else elif), "\n", '{', '('} = (); |
| 24 | + |
| 25 | +# Subset of cmd_start that also ends a pipeline. |
| 26 | +my %pipe_end; |
| 27 | +@pipe_end{qw(&& || ; ;;)} = (); |
| 28 | + |
| 29 | +# Tokens indicating grep is used as a filter (pipe or redirect). |
| 30 | +my %filter_op; |
| 31 | +@filter_op{'|', '>', '>>', '<'} = (); |
| 32 | + |
| 33 | +# Check if the raw source line has a lint-ok annotation. |
| 34 | +# Also check adjacent lines to handle backslash-continuation |
| 35 | +# line number offsets from the parser. |
| 36 | +sub lint_ok { |
| 37 | + my ($raw_lines, $ln) = @_; |
| 38 | + for my $l ($ln - 1, $ln, $ln + 1) { |
| 39 | + next if $l < 1 || $l > @$raw_lines; |
| 40 | + return 1 if $raw_lines->[$l - 1] =~ /lint-ok/; |
| 41 | + } |
| 42 | + return 0; |
| 43 | +} |
| 44 | + |
| 45 | +# Check if the grep at position $pos pipes its output |
| 46 | +# or redirects I/O (i.e. used as a filter, not assertion). |
| 47 | +sub is_filter { |
| 48 | + my ($tokens, $pos) = @_; |
| 49 | + for (my $j = $pos + 1; $j < @$tokens; $j++) { |
| 50 | + my $t = $tokens->[$j]->[0]; |
| 51 | + return 0 if exists $cmd_start{$t}; |
| 52 | + return 1 if exists $filter_op{$t}; |
| 53 | + } |
| 54 | + return 0; |
| 55 | +} |
| 56 | + |
| 57 | +sub check_test { |
| 58 | + my $self = shift @_; |
| 59 | + my $title = ScriptParser::unwrap(shift @_); |
| 60 | + my $body_token = shift @_; |
| 61 | + my $lineno = $body_token->[3]; |
| 62 | + my $body = ScriptParser::unwrap($body_token); |
| 63 | + if ($body eq '-') { |
| 64 | + my $herebody = shift @_; |
| 65 | + if ($herebody) { |
| 66 | + $body = $herebody->{content}; |
| 67 | + $lineno = $herebody->{start_line}; |
| 68 | + } |
| 69 | + } |
| 70 | + return unless $body; |
| 71 | + |
| 72 | + # For double-quoted bodies, build a table mapping inner-parser |
| 73 | + # line numbers to cumulative line-splice adjustments. Line |
| 74 | + # splices (\<newline>) consume a source line without emitting |
| 75 | + # a newline into the body text, so the inner parser's line |
| 76 | + # count falls behind the source. |
| 77 | + my $raw_lines = $self->{raw_lines}; |
| 78 | + my @splice_adj; |
| 79 | + if ($body_token->[0] =~ /^"/) { |
| 80 | + my $splice_count = 0; |
| 81 | + my $body_line = 0; |
| 82 | + for my $src_ln ($lineno .. ($body_token->[4] || $lineno)) { |
| 83 | + my $line = $raw_lines->[$src_ln - 1]; |
| 84 | + # Odd trailing backslashes means a line splice |
| 85 | + # (\<newline>); even means escaped backslashes. |
| 86 | + if (defined($line) && $line =~ /(\\*)\s*$/ && |
| 87 | + length($1) % 2 == 1) { |
| 88 | + $splice_count++; |
| 89 | + } else { |
| 90 | + $splice_adj[++$body_line] = $splice_count; |
| 91 | + } |
| 92 | + } |
| 93 | + } |
| 94 | + |
| 95 | + my $parser = ShellParser->new(\$body); |
| 96 | + my @tokens = $parser->parse(); |
| 97 | + |
| 98 | + my $file = $self->{file}; |
| 99 | + my $cmd_pos = 1; |
| 100 | + my $in_pipe = 0; |
| 101 | + |
| 102 | + for (my $i = 0; $i < @tokens; $i++) { |
| 103 | + my $text = $tokens[$i]->[0]; |
| 104 | + my $rel = $tokens[$i]->[3] || 0; |
| 105 | + my $ln = $rel + ($lineno || 1) - 1; |
| 106 | + $ln += $splice_adj[$rel] if @splice_adj && $rel <= $#splice_adj; |
| 107 | + |
| 108 | + if (exists $cmd_start{$text}) { |
| 109 | + $cmd_pos = 1; |
| 110 | + $in_pipe = 0 if exists $pipe_end{$text}; |
| 111 | + next; |
| 112 | + } |
| 113 | + if ($text eq '|') { |
| 114 | + $cmd_pos = 1; |
| 115 | + $in_pipe = 1; |
| 116 | + next; |
| 117 | + } |
| 118 | + if ($text eq '}' || $text eq ')') { |
| 119 | + $cmd_pos = 0; |
| 120 | + next; |
| 121 | + } |
| 122 | + |
| 123 | + next unless $cmd_pos; |
| 124 | + |
| 125 | + # '!' is a negation prefix, stay in command position |
| 126 | + if ($text eq '!') { |
| 127 | + if ($i + 1 < @tokens && |
| 128 | + $tokens[$i + 1]->[0] eq 'test_grep' && |
| 129 | + !lint_ok($raw_lines, $ln)) { |
| 130 | + print "$file:$ln: error: ", |
| 131 | + 'use "test_grep !" instead of ', |
| 132 | + '"! test_grep"', "\n"; |
| 133 | + $exit_code = 1; |
| 134 | + } |
| 135 | + next; |
| 136 | + } |
| 137 | + |
| 138 | + # bare grep at command position, not in a pipeline |
| 139 | + if ($text eq 'grep' && !$in_pipe && |
| 140 | + !is_filter(\@tokens, $i) && |
| 141 | + !lint_ok($raw_lines, $ln)) { |
| 142 | + print "$file:$ln: error: ", |
| 143 | + "bare grep outside pipeline ", |
| 144 | + "(use test_grep)\n"; |
| 145 | + $exit_code = 1; |
| 146 | + } |
| 147 | + |
| 148 | + $cmd_pos = 0; |
| 149 | + } |
| 150 | +} |
| 151 | + |
| 152 | +package main; |
| 153 | + |
| 154 | +for my $file (@ARGV) { |
| 155 | + open(my $fh, '<:unix:crlf', $file) or die "$0: $file: $!\n"; |
| 156 | + my @raw_lines = <$fh>; |
| 157 | + close $fh; |
| 158 | + my $s = join('', @raw_lines); |
| 159 | + my $parser = GrepLintParser->new(\$s); |
| 160 | + $parser->{file} = $file; |
| 161 | + $parser->{raw_lines} = \@raw_lines; |
| 162 | + $parser->parse(); |
| 163 | +} |
| 164 | +exit $exit_code; |
0 commit comments