Fix performance

Author: hvitved

ql/src/codeql_ruby/ast/Module.qll

@@ -20,6 +20,10 @@ class Module extends TModule {
   /** Gets an `include`d module. */
   Module getAnIncludedModule() { result = getAnIncludedModule(this) }
 
+  /** Holds if this module is a class. */
+  pragma[noinline]
+  predicate isClass() { this.getADeclaration() instanceof ClassDeclaration }
+
   /** Gets a textual representation of this module. */
   string toString() {
     this = TResolved(result)

ql/src/codeql_ruby/controlflow/CfgNodes.qll

@@ -123,15 +123,9 @@ abstract private class ExprChildMapping extends Expr {
    */
   abstract predicate relevantChild(Expr child);
 
-  private AstNode getAChildStar() {
-    result = this
-    or
-    result.getParent() = this.getAChildStar()
-  }
-
   pragma[noinline]
   private BasicBlock getABasicBlockInScope() {
-    result.getANode() = TAstCfgNode(this.getAChildStar(), _)
+    result.getANode() = TAstCfgNode(this.getAChild*(), _)
   }
 
   pragma[nomagic]

ql/src/codeql_ruby/dataflow/internal/DataFlowDispatch.qll

@@ -147,11 +147,10 @@ private DataFlow::LocalSourceNode trackInstance(Module tp, TypeTracker t) {
     )
     or
     // `self` in singleton method
-    exists(Self self, MethodBase enclosing, DataFlow::Node objectNode |
+    exists(Self self, MethodBase enclosing |
       self = result.asExpr().getExpr() and
-      singletonMethod(enclosing, objectNode.asExpr().getExpr()) and
+      flowsToSingletonMethodObject(trackInstance(tp), enclosing) and
       enclosing = self.getEnclosingMethod() and
-      trackInstance(tp).flowsTo(objectNode) and
       not self.getEnclosingModule().getEnclosingMethod() = enclosing
     )
     or
@@ -166,9 +165,7 @@ private DataFlow::LocalSourceNode trackInstance(Module tp, TypeTracker t) {
     // a module or class
     exists(Module m |
       result = trackModule(m) and
-      if m.getADeclaration() instanceof ClassDeclaration
-      then tp = TResolved("Class")
-      else tp = TResolved("Module")
+      if m.isClass() then tp = TResolved("Class") else tp = TResolved("Module")
     )
   )
   or
@@ -197,13 +194,26 @@ private predicate singletonMethod(MethodBase method, Expr object) {
   )
 }
 
+pragma[nomagic]
+private predicate flowsToSingletonMethodObject(DataFlow::LocalSourceNode nodeFrom, MethodBase method) {
+  exists(DataFlow::LocalSourceNode nodeTo |
+    nodeFrom.flowsTo(nodeTo) and
+    singletonMethod(method, nodeTo.asExpr().getExpr())
+  )
+}
+
+pragma[nomagic]
+private predicate moduleFlowsToSingletonMethodObject(Module m, MethodBase method) {
+  flowsToSingletonMethodObject(trackModule(m), method)
+}
+
 pragma[nomagic]
 private DataFlow::LocalSourceNode trackSingletonMethod0(MethodBase method, TypeTracker t) {
   t.start() and
-  exists(DataFlow::Node nodeTo | singletonMethod(method, nodeTo.asExpr().getExpr()) |
-    result.flowsTo(nodeTo)
+  (
+    flowsToSingletonMethodObject(result, method)
     or
-    exists(Module m | result = trackModule(m) and trackModule(m).flowsTo(nodeTo))
+    exists(Module m | result = trackModule(m) and moduleFlowsToSingletonMethodObject(m, method))
   )
   or
   exists(TypeTracker t2 | result = trackSingletonMethod0(method, t2).track(t2, t))