QL: implement ql/override-swapped-name

Author: erik-krogh

ql/src/queries/style/SwappedParameterNames.ql

@@ -0,0 +1,33 @@
+/**
+ * @name Swapped parameter names in overriding predicate.
+ * @description Swapping the parameter names in an overriding method indicates an implementation mistake.
+ * @kind problem
+ * @problem.severity warning
+ * @id ql/override-swapped-name
+ * @tags correctness
+ *       maintainability
+ * @precision high
+ */
+
+import ql
+
+pragma[noinline]
+private predicate getAnOverridingParameter(
+  ClassPredicate pred, ClassPredicate sup, VarDecl parameter, string parName, string superName,
+  int index
+) {
+  pred.overrides(sup) and
+  parameter = pred.getParameter(index) and
+  parameter.getName() = parName and
+  sup.getParameter(index).getName() = superName
+}
+
+from
+  ClassPredicate pred, ClassPredicate sup, VarDecl parameter, string parName, string superName,
+  int index
+where
+  getAnOverridingParameter(pred, sup, parameter, parName, superName, index) and
+  superName != parName and
+  exists(int other | other != index | sup.getParameter(other).getName() = parName)
+select parameter, parName + " was $@ in the super class.", sup.getParameter(index),
+  "named " + superName

ql/test/queries/style/SwappedParameterNames/SwappedParameterNames.expected

@@ -0,0 +1,2 @@
+| Test.qll:12:27:12:35 | VarDecl | succ was $@ in the super class. | Test.qll:4:27:4:35 | VarDecl | named pred |
+| Test.qll:12:38:12:46 | VarDecl | pred was $@ in the super class. | Test.qll:4:38:4:46 | VarDecl | named succ |

ql/test/queries/style/SwappedParameterNames/SwappedParameterNames.qlref

@@ -0,0 +1 @@
+queries/style/SwappedParameterNames.ql

ql/test/queries/style/SwappedParameterNames/Test.qll

@@ -0,0 +1,13 @@
+import ql
+
+class Sup extends AstNode {
+  abstract predicate step(Expr pred, Expr succ);
+}
+
+class Correct extends Sup {
+  override predicate step(Expr pred, Expr succ) { none() }
+}
+
+class Wrong extends Sup {
+  override predicate step(Expr succ, Expr pred) { none() } // <- swapped parameter names
+}