Java, C#: Refactor explicitSsaDefSign in sign analysis

Author: tamasvajk

csharp/ql/src/semmle/code/csharp/dataflow/internal/rangeanalysis/SignAnalysisCommon.qll

@@ -245,6 +245,19 @@ private Sign ssaDefSign(SsaVariable v) {
   )
 }
 
+/** Returns the sign of explicit SSA definition `v`. */
+Sign explicitSsaDefSign(SsaVariable v) {
+  exists(VariableUpdate def | def = getExplicitSsaAssignment(v) |
+    result = exprSign(getExprFromSsaAssignment(def))
+    or
+    anySign(result) and explicitSsaDefWithAnySign(def)
+    or
+    result = exprSign(getIncrementOperand(def)).inc()
+    or
+    result = exprSign(getDecrementOperand(def)).dec()
+  )
+}
+
 /** Returns the sign of implicit SSA definition `v`. */
 private Sign implicitSsaDefSign(SsaVariable v) {
   result = fieldSign(getImplicitSsaDeclaration(v))

csharp/ql/src/semmle/code/csharp/dataflow/internal/rangeanalysis/SignAnalysisSpecific.qll

@@ -32,6 +32,8 @@ module Private {
 
   class Expr = CS::Expr;
 
+  class VariableUpdate = CS::AssignableDefinition;
+
   predicate ssaRead = SU::ssaRead/2;
 }
 
@@ -107,19 +109,28 @@ private module Impl {
     }
   }
 
-  /** Returns the sign of explicit SSA definition `v`. */
-  Sign explicitSsaDefSign(Ssa::ExplicitDefinition v) {
-    exists(AssignableDefinition def | def = v.getADefinition() |
-      result = exprSign(def.getSource())
-      or
-      anySign(result) and
-      not exists(def.getSource()) and
-      not def.getElement() instanceof MutatorOperation
-      or
-      result = exprSign(def.getElement().(IncrementOperation).getOperand()).inc()
-      or
-      result = exprSign(def.getElement().(DecrementOperation).getOperand()).dec()
-    )
+  /** Returns the underlying variable update of the explicit SSA variable `v`. */
+  AssignableDefinition getExplicitSsaAssignment(Ssa::ExplicitDefinition v) {
+    result = v.getADefinition()
+  }
+
+  /** Returns the assignment of the variable update `def`. */
+  Expr getExprFromSsaAssignment(AssignableDefinition def) { result = def.getSource() }
+
+  /** Holds if `def` can have any sign. */
+  predicate explicitSsaDefWithAnySign(AssignableDefinition def) {
+    not exists(def.getSource()) and
+    not def.getElement() instanceof MutatorOperation
+  }
+
+  /** Returns the operand of the operation if `def` is a decrement. */
+  Expr getDecrementOperand(AssignableDefinition def) {
+    result = def.getElement().(DecrementOperation).getOperand()
+  }
+
+  /** Returns the operand of the operation if `def` is an increment. */
+  Expr getIncrementOperand(AssignableDefinition def) {
+    result = def.getElement().(IncrementOperation).getOperand()
   }
 
   /** Gets the variable underlying the implicit SSA variable `v`. */

java/ql/src/semmle/code/java/dataflow/internal/rangeanalysis/SignAnalysisCommon.qll

@@ -245,6 +245,19 @@ private Sign ssaDefSign(SsaVariable v) {
   )
 }
 
+/** Returns the sign of explicit SSA definition `v`. */
+Sign explicitSsaDefSign(SsaVariable v) {
+  exists(VariableUpdate def | def = getExplicitSsaAssignment(v) |
+    result = exprSign(getExprFromSsaAssignment(def))
+    or
+    anySign(result) and explicitSsaDefWithAnySign(def)
+    or
+    result = exprSign(getIncrementOperand(def)).inc()
+    or
+    result = exprSign(getDecrementOperand(def)).dec()
+  )
+}
+
 /** Returns the sign of implicit SSA definition `v`. */
 private Sign implicitSsaDefSign(SsaVariable v) {
   result = fieldSign(getImplicitSsaDeclaration(v))

java/ql/src/semmle/code/java/dataflow/internal/rangeanalysis/SignAnalysisSpecific.qll

@@ -36,6 +36,8 @@ module Private {
 
   class NumericOrCharType = J::NumericOrCharType;
 
+  class VariableUpdate = J::VariableUpdate;
+
   predicate ssaRead = RU::ssaRead/2;
 
   predicate guardControlsSsaRead = RU::guardControlsSsaRead/3;
@@ -96,23 +98,31 @@ private module Impl {
     e instanceof ClassInstanceExpr and e.getType() instanceof NumericOrCharType
   }
 
-  /** Returns the sign of explicit SSA definition `v`. */
-  Sign explicitSsaDefSign(SsaVariable v) {
-    exists(VariableUpdate def | def = v.(SsaExplicitUpdate).getDefiningExpr() |
-      result = exprSign(def.(VariableAssign).getSource())
-      or
-      exists(EnhancedForStmt for | def = for.getVariable())
-      or
-      result = exprSign(def.(PostIncExpr).getExpr()).inc()
-      or
-      result = exprSign(def.(PreIncExpr).getExpr()).inc()
-      or
-      result = exprSign(def.(PostDecExpr).getExpr()).dec()
-      or
-      result = exprSign(def.(PreDecExpr).getExpr()).dec()
-      or
-      exists(AssignOp a | a = def and result = exprSign(a))
-    )
+  /** Returns the underlying variable update of the explicit SSA variable `v`. */
+  VariableUpdate getExplicitSsaAssignment(SsaVariable v) {
+    result = v.(SsaExplicitUpdate).getDefiningExpr()
+  }
+
+  /** Returns the assignment of the variable update `def`. */
+  Expr getExprFromSsaAssignment(VariableUpdate def) {
+    result = def.(VariableAssign).getSource()
+    or
+    exists(AssignOp a | a = def and result = a)
+  }
+
+  /** Holds if `def` can have any sign. */
+  predicate explicitSsaDefWithAnySign(VariableUpdate def) {
+    exists(EnhancedForStmt for | def = for.getVariable())
+  }
+
+  /** Returns the operand of the operation if `def` is a decrement. */
+  Expr getDecrementOperand(Element e) {
+    result = e.(PostDecExpr).getExpr() or result = e.(PreDecExpr).getExpr()
+  }
+
+  /** Returns the operand of the operation if `def` is an increment. */
+  Expr getIncrementOperand(Element e) {
+    result = e.(PostIncExpr).getExpr() or result = e.(PreIncExpr).getExpr()
   }
 
   /** Gets the variable underlying the implicit SSA variable `v`. */