QL: Merge pull request #80 from github/aschackmull/calltarget-astnode

Refactor Call.getTarget to be an AstNode

Author: aschackmull

ql/src/codeql_ql/ast/Ast.qll

@@ -4,6 +4,7 @@ private import codeql_ql.ast.internal.Module
 private import codeql_ql.ast.internal.Predicate
 import codeql_ql.ast.internal.Type
 private import codeql_ql.ast.internal.Variable
+private import codeql_ql.ast.internal.Builtins
 
 bindingset[name]
 private string directMember(string name) { result = name + "()" }
@@ -31,6 +32,20 @@ class AstNode extends TAstNode {
     )
   }
 
+  predicate hasLocationInfo(
+    string filepath, int startline, int startcolumn, int endline, int endcolumn
+  ) {
+    if exists(getLocation())
+    then getLocation().hasLocationInfo(filepath, startline, startcolumn, endline, endcolumn)
+    else (
+      filepath = "" and
+      startline = 0 and
+      startcolumn = 0 and
+      endline = 0 and
+      endcolumn = 0
+    )
+  }
+
   /**
    * Gets the parent in the AST for this node.
    */
@@ -177,11 +192,62 @@ class Select extends TSelect, AstNode {
   override string getAPrimaryQlClass() { result = "Select" }
 }
 
+class PredicateOrBuiltin extends TPredOrBuiltin, AstNode {
+  string getName() { none() }
+
+  Type getDeclaringType() { none() }
+
+  Type getParameterType(int i) { none() }
+
+  Type getReturnType() { none() }
+
+  int getArity() { result = count(getParameterType(_)) }
+
+  predicate isPrivate() { none() }
+}
+
+class BuiltinPredicate extends PredicateOrBuiltin, TBuiltin {
+  override string toString() { result = getName() }
+
+  override string getAPrimaryQlClass() { result = "BuiltinPredicate" }
+}
+
+private class BuiltinClassless extends BuiltinPredicate, TBuiltinClassless {
+  string name;
+  string ret;
+  string args;
+
+  BuiltinClassless() { this = TBuiltinClassless(ret, name, args) }
+
+  override string getName() { result = name }
+
+  override PrimitiveType getReturnType() { result.getName() = ret }
+
+  override PrimitiveType getParameterType(int i) { result.getName() = getArgType(args, i) }
+}
+
+private class BuiltinMember extends BuiltinPredicate, TBuiltinMember {
+  string name;
+  string qual;
+  string ret;
+  string args;
+
+  BuiltinMember() { this = TBuiltinMember(qual, ret, name, args) }
+
+  override string getName() { result = name }
+
+  override PrimitiveType getReturnType() { result.getName() = ret }
+
+  override PrimitiveType getParameterType(int i) { result.getName() = getArgType(args, i) }
+
+  override PrimitiveType getDeclaringType() { result.getName() = qual }
+}
+
 /**
  * A QL predicate.
  * Either a classless predicate, a class predicate, or a characteristic predicate.
  */
-class Predicate extends TPredicate, AstNode, Declaration {
+class Predicate extends TPredicate, AstNode, PredicateOrBuiltin, Declaration {
   /**
    * Gets the body of the predicate.
    */
@@ -200,7 +266,7 @@ class Predicate extends TPredicate, AstNode, Declaration {
   /**
    * Gets the number of parameters.
    */
-  int getArity() {
+  override int getArity() {
     not this.(ClasslessPredicate).getAlias() instanceof PredicateExpr and
     result = count(getParameter(_))
     or
@@ -209,12 +275,19 @@ class Predicate extends TPredicate, AstNode, Declaration {
     )
   }
 
+  /**
+   * Holds if this predicate is private.
+   */
+  override predicate isPrivate() { hasAnnotation("private") }
+
   /**
    * Gets the return type (if any) of the predicate.
    */
   TypeExpr getReturnTypeExpr() { none() }
 
-  Type getReturnType() { result = this.getReturnTypeExpr().getResolvedType() }
+  override Type getReturnType() { result = this.getReturnTypeExpr().getResolvedType() }
+
+  override Type getParameterType(int i) { result = this.getParameter(i).getType() }
 
   override AstNode getAChild(string pred) {
     result = super.getAChild(pred)
@@ -376,6 +449,8 @@ class ClasslessPredicate extends TClasslessPredicate, Predicate, ModuleDeclarati
     or
     pred_name = directMember("getReturnTypeExpr") and result = this.getReturnTypeExpr()
   }
+
+  override predicate isPrivate() { Predicate.super.isPrivate() }
 }
 
 /**
@@ -394,11 +469,6 @@ class ClassPredicate extends TClassPredicate, Predicate {
 
   override Class getParent() { result.getAClassPredicate() = this }
 
-  /**
-   * Holds if this predicate is private.
-   */
-  predicate isPrivate() { hasAnnotation("private") }
-
   /**
    * Holds if this predicate is annotated as overriding another predicate.
    */
@@ -416,7 +486,7 @@ class ClassPredicate extends TClassPredicate, Predicate {
   /**
    * Gets the type representing this class.
    */
-  ClassType getDeclaringType() { result.getDeclaration() = getParent() }
+  override ClassType getDeclaringType() { result.getDeclaration() = getParent() }
 
   predicate overrides(ClassPredicate other) { predOverrides(this, other) }
 
@@ -453,7 +523,7 @@ class CharPred extends TCharPred, Predicate {
     pred_name = directMember("getBody") and result = this.getBody()
   }
 
-  ClassType getDeclaringType() { result.getDeclaration() = getParent() }
+  override ClassType getDeclaringType() { result.getDeclaration() = getParent() }
 }
 
 /**
@@ -764,7 +834,7 @@ class NewType extends TNewType, TypeDeclaration, ModuleDeclaration {
  * A branch in a `newtype`.
  * E.g. `Bar()` or `Baz()` in `newtype Foo = Bar() or Baz()`.
  */
-class NewTypeBranch extends TNewTypeBranch, TypeDeclaration {
+class NewTypeBranch extends TNewTypeBranch, PredicateOrBuiltin, TypeDeclaration {
   Generated::DatatypeBranch branch;
 
   NewTypeBranch() { this = TNewTypeBranch(branch) }
@@ -786,6 +856,16 @@ class NewTypeBranch extends TNewTypeBranch, TypeDeclaration {
   /** Gets the body of this branch. */
   Formula getBody() { toGenerated(result) = branch.getChild(_).(Generated::Body).getChild() }
 
+  override NewTypeBranchType getReturnType() { result.getDeclaration() = this }
+
+  override Type getParameterType(int i) { result = this.getField(i).getType() }
+
+  override int getArity() { result = count(this.getField(_)) }
+
+  override Type getDeclaringType() { none() }
+
+  override predicate isPrivate() { this.getNewType().isPrivate() }
+
   override QLDoc getQLDoc() { toGenerated(result) = branch.getChild(_) }
 
   NewType getNewType() { result.getABranch() = this }

ql/src/codeql_ql/ast/internal/AstNodes.qll

@@ -1,5 +1,6 @@
 import codeql_ql.ast.Ast as AST
 import TreeSitter
+private import Builtins
 
 cached
 newtype TAstNode =
@@ -65,7 +66,11 @@ newtype TAstNode =
   TYamlEntry(Generated::YamlEntry ye) or
   TYamlKey(Generated::YamlKey yk) or
   TYamlListitem(Generated::YamlListitem yli) or
-  TYamlValue(Generated::YamlValue yv)
+  TYamlValue(Generated::YamlValue yv) or
+  TBuiltinClassless(string ret, string name, string args) { isBuiltinClassless(ret, name, args) } or
+  TBuiltinMember(string qual, string ret, string name, string args) {
+    isBuiltinMember(qual, ret, name, args)
+  }
 
 class TFormula =
   TDisjunction or TConjunction or TComparisonFormula or TQuantifier or TNegation or TIfFormula or
@@ -194,6 +199,10 @@ Generated::AstNode toGenerated(AST::AstNode n) {
 
 class TPredicate = TCharPred or TClasslessPredicate or TClassPredicate or TDBRelation;
 
+class TPredOrBuiltin = TPredicate or TNewTypeBranch or TBuiltin;
+
+class TBuiltin = TBuiltinClassless or TBuiltinMember;
+
 class TModuleMember = TModuleDeclaration or TImport or TSelect or TQLDoc;
 
 class TDeclaration = TTypeDeclaration or TModuleDeclaration or TPredicate or TVarDecl;