lingo build failure

[remifan]

Hi, I built with lingo but failed with
lfc 0.10.2-SNAPSHOT 329465817 2025-11-18, Lingua Franca package manager and build tool 0.2.2

[ 97%] Building C object CMakeFiles/MuJoCoBasicDemo.dir/MuJoCoBasicDemo.c.o
/home/remi/Downloads/mujoco-c/build/src-gen/MuJoCoBasicDemo/MuJoCoBasicDemo.c: In function ‘_lf_initialize_trigger_objects’:
/home/remi/Downloads/mujoco-c/build/src-gen/MuJoCoBasicDemo/MuJoCoBasicDemo.c:140:49: error: ‘LF_SOURCE_GEN_DIRECTORY’ undeclared (first use in this function); did you mean ‘LF_TARGET_FILES_DIRECTORY’?
  140 |         mujocobasicdemo_m_self[0]->model_file = LF_SOURCE_GEN_DIRECTORY LF_FILE_SEPARATOR "hello.xml";
      |                                                 ^~~~~~~~~~~~~~~~~~~~~~~
      |                                                 LF_TARGET_FILES_DIRECTORY
/home/remi/Downloads/mujoco-c/build/src-gen/MuJoCoBasicDemo/MuJoCoBasicDemo.c:140:49: note: each undeclared identifier is reported only once for each function it appears in
/home/remi/Downloads/mujoco-c/build/src-gen/MuJoCoBasicDemo/MuJoCoBasicDemo.c:140:72: error: expected ‘;’ before ‘LF_FILE_SEPARATOR’
  140 |         mujocobasicdemo_m_self[0]->model_file = LF_SOURCE_GEN_DIRECTORY LF_FILE_SEPARATOR "hello.xml";
      |                                                                        ^~~~~~~~~~~~~~~~~~
      |                                                                        ;
gmake[3]: *** [CMakeFiles/MuJoCoBasicDemo.dir/build.make:118: CMakeFiles/MuJoCoBasicDemo.dir/MuJoCoBasicDemo.c.o] Error 1
gmake[2]: *** [CMakeFiles/Makefile2:106: CMakeFiles/MuJoCoBasicDemo.dir/all] Error 2
gmake[1]: *** [CMakeFiles/Makefile2:113: CMakeFiles/MuJoCoBasicDemo.dir/rule] Error 2
gmake: *** [Makefile:169: MuJoCoBasicDemo] Error 2

thread 'main' (1513893) panicked at /home/remi/.cargo/registry/src/index.crates.io-1949cf8c6b5b557f/lingua-franca-0.2.2/src/backends/mod.rs:209:21:
build step failed because of MuJoCoBasicDemo with main reactor /home/remi/Downloads/mujoco-c/src/MuJoCoBasicDemo.lf!
note: run with `RUST_BACKTRACE=1` environment variable to display a backtrace

is it version mismatched?

[edwardalee]

I can reproduce this error, although I get the error on LockToSimulator.lf instead. This used to work. Tagging @tanneberger because it seems lingo is not using CMake correctly. The generated flags.make directory defines the missing macro correctly, and running lfc on the file completes correctly. Only lingo fails. Not sure why. Isn't it just invoking lfc?

[remifan]

I can reproduce this error, although I get the error on LockToSimulator.lf instead. This used to work. Tagging @tanneberger because it seems lingo is not using CMake correctly. The generated flags.make directory defines the missing macro correctly, and running lfc on the file completes correctly. Only lingo fails. Not sure why. Isn't it just invoking lfc?

Thanks for the report. Here is my modified .cmake file that works (especially for the Mac users choosing to install Mujoco with GUI installer). Also GLFW's part is included.

# For MuJoCo
if(APPLE)
    # Prefer the MuJoCo.app bundle when installed via the official DMG.
    set(MUJOCO_APP_PATH "/Applications/MuJoCo.app/Contents" CACHE PATH "MuJoCo.app Contents path")
    set(MUJOCO_FRAMEWORK_DIR "${MUJOCO_APP_PATH}/Frameworks")

    if(EXISTS "${MUJOCO_FRAMEWORK_DIR}/mujoco.framework")
        # Check if framework has proper structure (binary symlink at root)
        if(EXISTS "${MUJOCO_FRAMEWORK_DIR}/mujoco.framework/mujoco")
            # Standard framework structure - let CMake handle it
            list(APPEND CMAKE_FRAMEWORK_PATH "${MUJOCO_FRAMEWORK_DIR}")
            find_library(MUJOCO_LIB
                NAMES mujoco
                REQUIRED
            )
            set(MUJOCO_INCLUDE_PATH "${MUJOCO_LIB}/Headers")
        else()
            # Non-standard framework structure - find the dylib directly
            file(GLOB MUJOCO_DYLIB_CANDIDATES
                "${MUJOCO_FRAMEWORK_DIR}/mujoco.framework/Versions/*/libmujoco*.dylib"
            )
            if(MUJOCO_DYLIB_CANDIDATES)
                list(GET MUJOCO_DYLIB_CANDIDATES 0 MUJOCO_LIB)
                message(STATUS "Found MuJoCo library (non-standard framework): ${MUJOCO_LIB}")
            else()
                message(FATAL_ERROR "Could not find MuJoCo library in ${MUJOCO_FRAMEWORK_DIR}/mujoco.framework")
            endif()

            # Create a local include directory structure to handle mujoco/ prefix includes
            set(MUJOCO_LOCAL_INCLUDE "${CMAKE_BINARY_DIR}/mujoco_include")
            set(MUJOCO_HEADERS_LINK "${MUJOCO_LOCAL_INCLUDE}/mujoco")

            # Create the directory and symlink if they don't exist
            file(MAKE_DIRECTORY "${MUJOCO_LOCAL_INCLUDE}")
            if(NOT EXISTS "${MUJOCO_HEADERS_LINK}")
                execute_process(
                    COMMAND ${CMAKE_COMMAND} -E create_symlink
                    "${MUJOCO_FRAMEWORK_DIR}/mujoco.framework/Headers"
                    "${MUJOCO_HEADERS_LINK}"
                )
            endif()

            set(MUJOCO_INCLUDE_PATH "${MUJOCO_LOCAL_INCLUDE}")
        endif()
    else()
        # Fallback to the /opt style installation that we document in README.md.
        set(MUJOCO_PATH "/opt/mujoco" CACHE PATH "MuJoCo base directory")
        list(APPEND CMAKE_PREFIX_PATH "${MUJOCO_PATH}")

        find_library(MUJOCO_LIB
            NAMES mujoco
            PATHS "${MUJOCO_PATH}" "${MUJOCO_PATH}/lib"
            REQUIRED
        )

        find_path(MUJOCO_INCLUDE_PATH
            NAMES mujoco/mujoco.h
            PATHS "${MUJOCO_PATH}" "${MUJOCO_PATH}/include"
            REQUIRED
        )
    endif()
else()
    # Original Linux-style install
    set(MUJOCO_PATH "/opt/mujoco" CACHE PATH "MuJoCo base directory")
    list(APPEND CMAKE_PREFIX_PATH "${MUJOCO_PATH}")

    find_library(MUJOCO_LIB
        NAMES mujoco
        PATHS "${MUJOCO_PATH}" "${MUJOCO_PATH}/lib"
        REQUIRED
    )

    find_path(MUJOCO_INCLUDE_PATH
        NAMES mujoco/mujoco.h
        PATHS "${MUJOCO_PATH}" "${MUJOCO_PATH}/include"
        REQUIRED
    )
endif()

target_include_directories(${LF_MAIN_TARGET} PUBLIC "${MUJOCO_INCLUDE_PATH}")
target_link_libraries(${LF_MAIN_TARGET} PUBLIC "${MUJOCO_LIB}")

# For GLFW (installed via Homebrew)

if(APPLE)
    # Adjust this if you're on Intel macOS (see comment below)
    set(HOMEBREW_PREFIX "/opt/homebrew" CACHE PATH "Homebrew prefix")
else()
    set(HOMEBREW_PREFIX "/usr/local" CACHE PATH "Homebrew prefix")
endif()

# Look for the header
find_path(GLFW_INCLUDE_DIR
    NAMES GLFW/glfw3.h
    PATHS
        "${HOMEBREW_PREFIX}/include"
        "/usr/local/include"
    REQUIRED
)

# Look for the library
find_library(GLFW_LIB
    NAMES glfw
    PATHS
        "${HOMEBREW_PREFIX}/lib"
        "/usr/local/lib"
    REQUIRED
)

target_include_directories(${LF_MAIN_TARGET} PUBLIC "${GLFW_INCLUDE_DIR}")
target_link_libraries(${LF_MAIN_TARGET} PUBLIC "${GLFW_LIB}")

[edwardalee]

This is fixed in this lingo PR: lf-lang/lingo#64