bootstrap

#!/bin/zsh

set -euo pipefail

DOTFILES_DIR="$(cd "$(dirname "$0")" && pwd)"

link_file() {
  local src="$1" dest="$2"

  if [ -L "$dest" ]; then
    if [ "$(readlink "$dest")" = "$src" ]; then
      return
    fi
    rm "$dest"
  elif [ -e "$dest" ]; then
    mv "$dest" "$dest.old"
    echo "Backed up $dest → $dest.old"
  fi

  ln -sf "$src" "$dest"
  echo "Linked $dest"
}

# For files that external tools modify (git credential helpers, shell
# installers, etc.), use include/source instead of symlinks so writes
# go to the real ~/.file and don't dirty the repo.
include_file() {
  local src="$1" dest="$2" directive="$3"

  if [ -L "$dest" ]; then
    rm "$dest"
  elif [ -e "$dest" ]; then
    if grep -qF "$directive" "$dest" 2>/dev/null; then
      return
    fi
    mv "$dest" "$dest.old"
    echo "Backed up $dest → $dest.old"
  fi

  echo "$directive" > "$dest"
  echo "Created $dest"
}

init() {
  for file in "$DOTFILES_DIR"/.*; do
    local filename="$(basename "$file")"
    case "$filename" in
      .|..|.git|.DS_Store|.gitconfig|.zshrc)
        continue
        ;;
    esac
    link_file "$file" "$HOME/$filename"
  done

  include_file "$DOTFILES_DIR/.gitconfig" "$HOME/.gitconfig" \
    "[include]
    path = $DOTFILES_DIR/.gitconfig"

  include_file "$DOTFILES_DIR/.zshrc" "$HOME/.zshrc" \
    "source \"$DOTFILES_DIR/.zshrc\""

  source "$HOME/.zshrc"

  if type tmux >/dev/null 2>/dev/null && tmux has-session 2>/dev/null; then
    tmux source-file "$HOME/.tmux.conf"
  fi
}

if [[ "${1:-}" == "--force" || "${1:-}" == "-f" ]]; then
  init
else
  # read returns 1 on EOF (no TTY / piped stdin); avoid exiting under set -e
  read "REPLY?This will symlink dotfiles to your home directory. Continue? (y/n) " || REPLY=n
  if [[ "$REPLY" =~ ^[Yy]$ ]]; then
    init
  fi
fi