modelix.openapi/build.gradle.kts at main · modelix/modelix.openapi · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59


plugins {
    base
    alias(libs.plugins.kotlin.jvm) apply false
    alias(libs.plugins.kotlin.serialization) apply false
    alias(libs.plugins.gitVersion)
    `maven-publish`
}

version = computeVersion().also { println("Version: $it") }

fun computeVersion(): String {
    val versionFile = file("version.txt")
    return if (versionFile.exists()) {
        versionFile.readText().trim()
    } else {
        val gitVersion: groovy.lang.Closure<String> by extra
        gitVersion()
        .replace("""\.dirty$""".toRegex(), "-dirty")
        .let {
            // Normalize the version so that is always a valid NPM version.
            if (it.matches("""\d+\.\d+.\d+-.*""".toRegex())) it else "0.0.1-$it"
        }
        .also { versionFile.writeText(it) }
    }
}

group = "org.modelix"

subprojects {
    group = rootProject.group
    version = rootProject.version
    apply(plugin = "maven-publish")

    repositories {
        maven { url = uri("https://artifacts.itemis.cloud/repository/maven-mps/") }
        mavenCentral()
        mavenLocal()
    }

    publishing {
        repositories {
            maven {
                name = "itemis"
                url =
                    if (version.toString().contains("SNAPSHOT")) {
                        uri("https://artifacts.itemis.cloud/repository/maven-mps-snapshots/")
                    } else {
                        uri("https://artifacts.itemis.cloud/repository/maven-mps-releases/")
                    }
                credentials {
                    username = project.findProperty("artifacts.itemis.cloud.user").toString()
                    password = project.findProperty("artifacts.itemis.cloud.pw").toString()
                }
            }
        }
    }
}