Better support for uploading to multiple modrinth projects at once

[pupnewfster]

It would be nice if there was a better system for publishing to multiple Modrinth projects from a single gradle project. Mekanism is setup in multiple modules split by sourcesets, that then get built into individual jars. A more native way in Minotaur to handle cases like this would be useful and allow for easier automated publishing. The solution/workaround (mekanism/Mekanism@188d050) I came up with while performing some experimentation works by creating new TaskModrinthUploads and then using doFirst to change the configured values of the ModrinthExtension before the task is applied and it queries the extension for values.

Some potential solutions from an API perspective that I come up with might be:

• Similar to how the dependencies block is a nested configuration, making it so some of the properties of the ModrinthExtension are nested and then it loops them uploading all to the corresponding projects
• A configuration version of the values set in ModrinthExtension that can be passed to the TaskModrinthUpload when created/applied and just leave it to devs to declare when they are declaring the custom upload tasks.

[pupnewfster]

Adding onto this (I can open it as another request if you would like), one thing that would be useful is to also then have a way to get the version id of uploaded files. That way for all my secondary projects I could mark them as requiring the matching version of the main project instead of just being able to mark them as requiring the main project in general.

[triphora]

Obtaining the version ID of the uploaded file can be obtained via tasks.modrinth.uploadInfo.id if I recall correctly.

[pupnewfster]

Ah yeah, seems I missed that part when suggesting the secondary thing.

[triphora]

Wrong issue to close! Oops.

[jamioflan]

Upvoting this issue, I had to use this suggested workaround on Flan's Mod (mod + Basic Parts + Vender's Game)
FlansMods/FlansModReloaded@06c95ae

[KostromDan]

Yesterday also was forced to imagine workarounds to achieve such functionality.

if (System.getenv("MODRINTH_TOKEN") != null) {
    modrinth {
        token = System.getenv("MODRINTH_TOKEN")
        projectId = "ix1qq8Ux"
        versionType = release_type
        changelog = parsedChangelog
        gameVersions = [project.minecraft_version]
    }

    tasks.register("modrinthForge", com.modrinth.minotaur.TaskModrinthUpload) {
        group = "upload"
        dependsOn(tasks.named("remapForgeJar"))
        doFirst {
            modrinth.versionNumber.set("${project.version}")
            modrinth.versionName.set(tasks.remapForgeJar.archiveFile.get().asFile.name)
            modrinth.uploadFile.set(tasks.remapForgeJar)
            modrinth.loaders.set(["forge"])
        }
    }

    tasks.register("modrinthFabric", com.modrinth.minotaur.TaskModrinthUpload) {
        group = "upload"
        dependsOn(tasks.named("remapFabricJar"))
        doFirst {
            modrinth.versionNumber.set("${project.version}")
            modrinth.versionName.set(tasks.remapFabricJar.archiveFile.get().asFile.name)
            modrinth.uploadFile.set(tasks.remapFabricJar)
            modrinth.loaders.set(["fabric", "legacy-fabric"])
        }
    }
}

It would better if it was smth like this:

if (System.getenv("CF_TOKEN") != null) {
    tasks.register("publishCurseForge", net.darkhax.curseforgegradle.TaskPublishCurseForge) {
        group = "upload"
        apiToken = System.getenv("CF_TOKEN")

        def forgeFile = upload("1154099", tasks.remapForgeJar)
        forgeFile.displayName = tasks.remapForgeJar.archiveFile.get().asFile.name
        forgeFile.changelog = parsedChangelog
        forgeFile.changelogType = "markdown"
        forgeFile.releaseType = release_type
        forgeFile.addGameVersion(project.minecraft_version)
        forgeFile.addModLoader("Forge")

        def fabricFile = upload("1154099", tasks.remapFabricJar)
        fabricFile.displayName = tasks.remapFabricJar.archiveFile.get().asFile.name
        fabricFile.changelog = parsedChangelog
        fabricFile.changelogType = "markdown"
        fabricFile.releaseType = release_type
        fabricFile.addGameVersion(project.minecraft_version)
        fabricFile.addModLoader("Fabric")
    }
}