api/settings.gradle at develop · q-asker/api · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
// settings.gradle은 Version Catalog 등록 이전 단계라 libs 접근자를 쓸 수 없으므로
// pluginManagement 블록 안에서 TOML을 직접 파싱해 SSOT(단일 진실 원천)을 유지한다
// pluginManagement는 다른 모든 statement보다 먼저 와야 하므로 헬퍼도 이 블록 안에 둔다
pluginManagement {
    def toml = new File(settingsDir, 'gradle/libs.versions.toml').text
    def m = toml =~ /(?m)^\s*foojay\s*=\s*"([^"]+)"/
    if (!m.find()) {
        throw new GradleException("'foojay' not found in gradle/libs.versions.toml [versions]")
    }
    def foojayVersion = m.group(1)
    plugins {
        id 'org.gradle.toolchains.foojay-resolver-convention' version foojayVersion
    }
}

// Foojay 툴체인 리졸버: 위 pluginManagement에서 결정된 버전으로 적용
// 예: Gradle Daemon JVM Criteria(toolchain-version)와 자바 toolchain이 요구하는 JDK가
//     로컬에 없을 때 https://api.foojay.io 에서 자동으로 적합한 JDK를 다운로드하여 사용
//     (별도 설치 없이 프로젝트가 요구하는 JDK 버전을 보장)
plugins {
    id 'org.gradle.toolchains.foojay-resolver-convention'
}

rootProject.name = 'q-asker'

include ':app', ':global', ':admin',
    ':auth-api', ':auth-impl',
    ':oci-api', ':oci-impl',
    ':board-api', ':board-impl',
    ':quiz-ai-api', ':quiz-ai-impl',
    ':quiz-history-api', ':quiz-history-impl',
    ':quiz-make-api', ':quiz-make-impl',
    ':quiz-set-api', ':quiz-set-impl',
    ':document-api', ':document-impl'


project(':app').projectDir = file('app')
project(':global').projectDir = file('modules/global')
project(':admin').projectDir = file('modules/admin')

project(':auth-api').projectDir = file('modules/auth/api')
project(':auth-impl').projectDir = file('modules/auth/impl')

project(':oci-api').projectDir = file('modules/oci/api')
project(':oci-impl').projectDir = file('modules/oci/impl')

project(':board-api').projectDir = file('modules/board/api')
project(':board-impl').projectDir = file('modules/board/impl')

project(':quiz-ai-api').projectDir = file('modules/quiz-ai/api')
project(':quiz-ai-impl').projectDir = file('modules/quiz-ai/impl')

project(':quiz-history-api').projectDir = file('modules/quiz-history/api')
project(':quiz-history-impl').projectDir = file('modules/quiz-history/impl')

project(':quiz-make-api').projectDir = file('modules/quiz-make/api')
project(':quiz-make-impl').projectDir = file('modules/quiz-make/impl')

project(':quiz-set-api').projectDir = file('modules/quiz-set/api')
project(':quiz-set-impl').projectDir = file('modules/quiz-set/impl')

project(':document-api').projectDir = file('modules/document/api')
project(':document-impl').projectDir = file('modules/document/impl')