build.gradle

plugins {
    id 'java-gradle-plugin'
    id 'java-library'
    id 'maven-publish'
    id 'io.spring.javaformat' version '0.0.47'
    id 'com.gradle.plugin-publish' version '2.1.1'
}

group = 'io.github.reqstool'
version = '0.1.0'

java {
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

repositories {
    mavenCentral()
}

gradlePlugin {
    website = 'https://reqstool.github.io'
    vcsUrl = 'https://github.com/reqstool/reqstool-java-gradle-plugin.git'

    plugins {
        reqstoolPlugin {
            id = 'io.github.reqstool.gradle-plugin'
            implementationClass = 'io.github.reqstool.gradle.RequirementsToolPlugin'
            displayName = 'Reqstool Gradle Plugin'
            description = 'Gradle plugin for assembling and attaching reqstool ZIP artifacts'
            tags.set(['reqstool', 'requirements', 'verification', 'testing'] )
        }
    }
}

dependencies {
    // Jackson for YAML processing
    implementation 'com.fasterxml.jackson.core:jackson-databind:2.21.1'
    implementation 'com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:2.21.1'
    
    // SnakeYAML for reqstool_config.yml generation
    implementation 'org.yaml:snakeyaml:2.6'
    
    // Testing - JUnit BOM for version management
    testImplementation platform('org.junit:junit-bom:6.0.3')
    testImplementation 'org.junit.jupiter:junit-jupiter-api'
    testImplementation 'org.junit.jupiter:junit-jupiter-params'
    testRuntimeOnly 'org.junit.jupiter:junit-jupiter-engine'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

test {
    useJUnitPlatform()
}

publishing {
    publications {
        withType(MavenPublication) {
            pom {
                developers {
                    developer {
                        name = 'Reqstool Contributors'
                        organization = 'reqstool'
                        organizationUrl = 'https://github.com/reqstool'
                    }
                }
            }
        }
    }
}