rgeometry.github.io/flake.nix at main · rgeometry/rgeometry.github.io · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
{
  description = "RGeometry website";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
  }:
    flake-utils.lib.eachDefaultSystem (
      system: let
        pkgs = nixpkgs.legacyPackages.${system};

        node-modules = pkgs.mkYarnPackage {
          name = "node-modules";
          src = pkgs.lib.cleanSourceWith {
            src = ./.;
            filter = path: type:
              baseNameOf path
              == "package.json"
              || baseNameOf path == "yarn.lock";
          };
        };

        frontend = pkgs.stdenv.mkDerivation {
          name = "frontend";
          src = pkgs.lib.cleanSourceWith {
            src = ./.;
            filter = path: type: let
              baseName = baseNameOf path;
            in
              pkgs.lib.hasSuffix ".pug" baseName
              || pkgs.lib.hasSuffix ".less" baseName
              || pkgs.lib.hasSuffix ".js" baseName
              || pkgs.lib.hasSuffix ".ttf" baseName
              || pkgs.lib.hasSuffix ".md" baseName
              || pkgs.lib.hasSuffix ".parcelrc" baseName
              || baseName == "package.json";
          };
          buildInputs = [pkgs.yarn node-modules];

          buildPhase = ''
            ln -s ${node-modules}/libexec/rgeometry.github.io/node_modules node_modules
            # The optimizer breaks one of the SVGs, so we disable it.
            ${pkgs.yarn}/bin/yarn parcel build --no-optimize index.pug
          '';

          installPhase = ''
            mkdir -p $out
            cp -r dist/* $out/
          '';
        };
      in {
        # Packages
        packages = {
          node-modules = node-modules;
          # Default package
          default = frontend;
        };

        # Apps
        apps = {
          serve = {
            type = "app";
            program = toString (pkgs.writeShellScript "serve-frontend" ''
              set -euo pipefail
              echo "Starting development server..."
              ${pkgs.yarn}/bin/yarn install
              exec ${pkgs.yarn}/bin/yarn parcel serve index.pug
            '');
          };
        };
      }
    );
}