docs/justfile at main · sablier-labs/docs · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
# See https://github.com/sablier-labs/devkit/blob/main/just/base.just

import "./node_modules/@sablier/devkit/just/base.just"

# ---------------------------------------------------------------------------- #
#                                    RECIPES                                   #
# ---------------------------------------------------------------------------- #

# Show available commands
default:
    @just --list

# Remove build files
@clean:
    bun docusaurus clear
    bunx del-cli src/autogen/**/*.mdx

# Check code with ESLint
@eslint-check:
    bun eslint --cache .

alias ec := eslint-check

# Fix code with ESLint
@eslint-write:
    bun eslint --cache --fix .

alias ew := eslint-write

# Run all code checks
@full-check:
    just rws biome-check
    just rws prettier-check
    just rws eslint-check
    just rws tsc-check

# Run all code fixes
@full-write:
    just rws biome-write
    just rws prettier-write
    just rws eslint-write

# ---------------------------------------------------------------------------- #
#                                    AUTOGEN                                   #
# ---------------------------------------------------------------------------- #

# Run all autogen commands with overwrite
[group("autogen")]
@autogen:
    just cli autogen --overwrite

# Generate deployment documentation
[group("autogen")]
@autogen-deployments:
    just cli autogen deployments --overwrite

# Generate GraphQL schema documentation
[group("autogen")]
@autogen-graphql vendor="all" protocol="all":
    just cli autogen graphql \
        --vendor {{ vendor }} \
        --protocol {{ protocol }} \
        --overwrite

# Generate indexer documentation
[group("autogen")]
@autogen-indexers:
    just cli autogen indexers --overwrite

# Generate reference documentation
[group("autogen")]
@autogen-reference:
    bash cli/autogen-reference.sh

# ---------------------------------------------------------------------------- #
#                                  DOCUSAURUS                                  #
# ---------------------------------------------------------------------------- #

# Build the documentation site
[group("docusaurus")]
build: autogen
    bun docusaurus build

# Deploy website to Vercel
[group("docusaurus")]
deploy:
    bun vercel pull --environment=production --token=$VERCEL_TOKEN --yes
    bun vercel build --prod --token=$VERCEL_TOKEN
    bun vercel deploy --prebuilt --prod --token=$VERCEL_TOKEN

# Serve built site
[group("docusaurus")]
serve:
    bun docusaurus serve

# Start development server with autogen
[group("docusaurus")]
start: autogen
    bun docusaurus start

# ---------------------------------------------------------------------------- #
#                                    PRIVATE                                   #
# ---------------------------------------------------------------------------- #

# Helper to run CLI commands through the main entry point
[private]
@cli *args:
    bun cli/index.ts {{ args }}