Connection.quark/ServerMessageQueue.sc at master · scztt/Connection.quark · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
ServerMessageQueue {
	var server;
	var <synced = true;
	var <bundles, <condition;
	var <>latency;

	*new {
		|server|
		^super.new.init(server)
	}

	init {
		|inServer|

		server = inServer;
		bundles = List(64);
		latency = server.latency;
		ServerQuit.add(this);
	}

	doOnServerQuit {
		synced = true;
		condition = nil;
		bundles.clear;
	}

	processBundles {
		var bundle;

		if (condition.isNil) {
			while { bundles.notEmpty } {
				bundle = bundles.removeAt(0);

				if (bundle == \sync) {
					condition = Condition(false);
					server.sendBundle(latency, ["/sync", server.addr.makeSyncResponder(condition)]);
					fork {
						condition.wait();
						condition = nil;
						this.processBundles();
					};
					^false;
				} {
					server.listSendBundle(nil, bundle);
				}
			}
		}
	}

	makeBundle {
		|func|
		bundles.add(server.makeBundle(false, func));
		this.processBundles()
	}

	makeBundleSync {
		|func|
		bundles.add(server.makeBundle(false, func));
		bundles.add(\sync);
		this.processBundles();
	}

	sync {

	}
}