extremum-xdoc-java/build.gradle at develop · smekalka/extremum-xdoc-java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
plugins {
    id 'java-library'
    id 'org.springframework.boot' version '2.7.6'
    id 'io.spring.dependency-management' version '1.0.15.RELEASE'
    id 'maven-publish'
    id 'signing'
}

group = 'io.extremum'
version = '3.0.0'
sourceCompatibility = '1.8'

repositories {
    mavenCentral()
    mavenLocal()
}

dependencies {
    ext.extremumVersion = "3.0.0"
    implementation 'org.springframework.boot:spring-boot-starter'
    implementation 'org.springframework:spring-webmvc'
    implementation("io.extremum:extremum-shared-models:$extremumVersion")
    implementation("io.extremum:extremum-jackson-mapper:$extremumVersion")
    implementation("com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:2.14.1")
    implementation("com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.14.1")
    implementation("org.reflections:reflections:0.10.2")
    implementation("com.squareup.okhttp:okhttp:2.7.5")

    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'

    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.boot:spring-boot-starter-web'
    testImplementation("com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:2.14.1")
    testImplementation("com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.14.1")
}

java {
    withJavadocJar()
    withSourcesJar()
}

publishing {
    publications {
        maven(MavenPublication) {
            groupId = group
            artifactId = "xdoc-java"
            version = this.version

            from(components["java"])

            pom {
                name.set("xdoc-java")
                description.set("Xdoc for java functions")
                url.set("https://github.com/smekalka/extremum-xdoc-java")
                inceptionYear.set("2022")

                scm {
                    url.set("https://github.com/smekalka/extremum-xdoc-java")
                    connection.set("scm:https://github.com/smekalka/extremum-xdoc-java.git")
                    developerConnection.set("scm:git://github.com/smekalka/extremum-xdoc-java.git")
                }

                licenses {
                    license {
                        name.set("Business Source License 1.1")
                        url.set("https://github.com/smekalka/extremum-xdoc-java/blob/develop/LICENSE.md")
                        distribution.set("repo")
                    }
                }

                developers {
                    developer {
                        id.set("urgimchak")
                        name.set("Maksim Tyutyaev")
                        email.set("maksim.tyutyaev@smekalka.com")
                    }
                }
            }
        }
    }

    repositories {
        maven {
            var releasesRepoUrl = "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/"
            var snapshotsRepoUrl = "https://s01.oss.sonatype.org/content/repositories/snapshots/"
            name = "OSSRH"
            var isReleaseVersion = !(version as String).endsWith("-SNAPSHOT")
            url = uri(isReleaseVersion ? releasesRepoUrl : snapshotsRepoUrl)
            credentials {
                username = System.getProperty("ossrhUsername")
                password = System.getProperty("ossrhPassword")
            }
        }
    }
}

signing {
    sign publishing.publications.maven
}

javadoc {
    if (JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}

bootJar {
    enabled = false
}

jar {
    enabled = true
    archiveClassifier.set("")
}

tasks.named('test') {
    useJUnitPlatform()
}