zero-cache-chart/flake.nix at main · synapdeck/zero-cache-chart · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
{
  description = "zero-cache Helm chart version manager";

  inputs = {
    nixpkgs.url = "https://flakehub.com/f/NixOS/nixpkgs/0.1";
    flake-parts.url = "https://flakehub.com/f/hercules-ci/flake-parts/0.1";
    pyproject-nix = {
      url = "https://flakehub.com/f/pyproject-nix/pyproject.nix/0.1";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    uv2nix = {
      url = "https://flakehub.com/f/pyproject-nix/uv2nix/0.1";
      inputs.pyproject-nix.follows = "pyproject-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    pyproject-build-systems = {
      url = "https://flakehub.com/f/pyproject-nix/build-system-pkgs/0.1";
      inputs.pyproject-nix.follows = "pyproject-nix";
      inputs.uv2nix.follows = "uv2nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = inputs @ {
    flake-parts,
    nixpkgs,
    pyproject-nix,
    uv2nix,
    pyproject-build-systems,
    ...
  }:
    flake-parts.lib.mkFlake {inherit inputs;} {
      systems = ["x86_64-linux" "aarch64-linux" "aarch64-darwin" "x86_64-darwin"];

      flake.chartMetadata = import ./chart.nix;

      flake.chart = let
        helmFiles = builtins.path {
          path = ./.;
          name = "zero-cache-chart-src";
          filter = path: type: let
            base = builtins.baseNameOf path;
            relPath = builtins.substring (builtins.stringLength (toString ./.) + 1) (-1) (toString path);
          in
            builtins.elem base ["Chart.yaml" "values.yaml" "Chart.lock" ".helmignore"]
            || nixpkgs.lib.hasPrefix "templates" relPath;
        };
      in
        helmFiles;

      perSystem = {
        pkgs,
        system,
        ...
      }: let
        workspace = uv2nix.lib.workspace.loadWorkspace {
          workspaceRoot = ./.;
        };

        overlay = workspace.mkPyprojectOverlay {
          sourcePreference = "wheel";
        };

        pythonSet =
          (pkgs.callPackage pyproject-nix.build.packages {
            python = pkgs.python3;
          }).overrideScope (
            nixpkgs.lib.composeManyExtensions [
              pyproject-build-systems.overlays.default
              overlay
            ]
          );

        inherit (pkgs.callPackages pyproject-nix.build.util {}) mkApplication;

        venv = pythonSet.mkVirtualEnv "zero-cache-chart-env" workspace.deps.default;
        devVenv = pythonSet.mkVirtualEnv "zero-cache-chart-dev-env" workspace.deps.all;

        unwrapped = mkApplication {
          venv = venv;
          package = pythonSet.zero-cache-chart;
        };
      in {
        packages.default = pkgs.symlinkJoin {
          name = "zero-cache-chart";
          paths = [unwrapped];
          nativeBuildInputs = [pkgs.makeWrapper];
          postBuild = ''
            wrapProgram $out/bin/zero-cache-chart \
              --prefix PATH : ${pkgs.lib.makeBinPath [pkgs.kubernetes-helm pkgs.oras]}
          '';
        };

        devShells.default = pkgs.mkShell {
          packages = [
            devVenv
            pkgs.kubernetes-helm
            pkgs.kubeconform
            pkgs.helm-docs
            pkgs.oras
            pkgs.uv
          ];

          env = {
            UV_NO_SYNC = "1";
            UV_PYTHON = pythonSet.python.interpreter;
            UV_PYTHON_DOWNLOADS = "never";
          };

          shellHook = ''
            unset PYTHONPATH
          '';
        };
      };
    };
}