new PDF functions

.gitignore

@@ -1,2 +1,3 @@
 *.prefs
 *.cset
+*.launch

IRP/src/CommonModules/Localization/Module.bsl

@@ -2852,6 +2852,9 @@ Strings.Insert("ExternalAccountingOperationExchangeReport", NStr("en = 'External
 	Strings.Insert("Error_UnknownRefType", NStr("en = 'Unknown ref type: %1'", Lang));
 	Strings.Insert("Error_StepsEnablerNotDefined", NStr("en = 'Steps enabler is not defined [%1]'", Lang));
 	Strings.Insert("Error_UnsupportedExternalLinkSC3", NStr("en = 'Not supported External link for [SC] to [%1]'", Lang));
+	Strings.Insert("Error_CreatingPDF", NStr("en = 'Error creating PDF'", Lang));
+	Strings.Insert("Error_ReadingPDF", NStr("en = 'Error reading PDF'", Lang));
+	Strings.Insert("Error_ChromiumNotFound", NStr("en = 'Chromium not found'", Lang));
 #EndRegion
 
 #Region Tasks

IRP/src/CommonModules/PDFFunctionsClientServer/Module.bsl

@@ -0,0 +1,138 @@
+
+// Is PDF.
+// 
+// Parameters:
+//  FileRef - CatalogRef.Files - File ref
+// 
+// Returns:
+//  Boolean - Is PDF
+Function IsPDF(FileRef) Export
+
+	Extension = CommonFunctionsServer.GetRefAttribute(FileRef, "Extension"); // String
+	Return Not StrCompare(Extension, "pdf");
+
+EndFunction
+
+// Set data in PDFViewer.
+// 
+// Parameters:
+//  PDFViewer - PDFDocument - PDFViewer
+//  Data - BinaryData - Data
+//  IsAsync - Boolean - Is async
+Procedure SetDataInPDFViewer(PDFViewer, Data, IsAsync = False) Export
+
+	Try
+		Buffer = GetBinaryDataBufferFromBinaryData(Data);
+		Stream = New MemoryStream(Buffer);
+		If IsAsync Then 
+			PDFViewer.ReadAsync(Stream);
+		Else
+			PDFViewer.Read(Stream);
+		EndIf;
+	Except
+		Raise R().Error_ReadingPDF + Chars.CR + ErrorDescription();
+	EndTry;
+
+EndProcedure
+
+// Read data from PDFViewer.
+// 
+// Parameters:
+//  PDFViewer - PDFDocument - PDFViewer
+///  IsAsync - Boolean - Is async
+// 
+// Returns:
+//  Undefined, BinaryData - Read data from PDFViewer
+Function ReadDataFromPDFViewer(PDFViewer, IsAsync = False) Export
+
+	Try
+		If PDFViewer.PageCount() = 0 Then
+			Return Undefined;
+		EndIf;
+
+		MemoryStream = New MemoryStream();
+
+		If IsAsync Then
+			PDFViewer.WriteAsync(MemoryStream);
+		Else
+			PDFViewer.Write(MemoryStream);
+		EndIf;
+
+		Data = MemoryStream.CloseAndGetBinaryData();
+	Except
+		// document not set
+		Return Undefined;
+	EndTry;
+
+	Return Data;
+
+EndFunction
+
+// Create PDF from HTML.
+// 
+// Parameters:
+//  HTML - String - HTML
+// 
+// Returns:
+//  Structure - Create PDFFrom HTML:
+// * BinaryData - BinaryData, Undefined - PDF from HTML 
+// * Error - String - error text
+Function CreatePDFFromHTML(HTML) Export
+
+	Result = New Structure("BinaryData, Error", Undefined, "");
+
+	PathToChromium = GetPathToChromium();
+	If IsBlankString(PathToChromium) Then
+		Result.Error =  R().Error_ChromiumNotFound;
+		Return Result;
+	EndIf;
+
+	PDFtmp = GetTempFileName(".pdf");
+	HTMLtmp = GetTempFileName(".html");
+
+	TextFile = New TextWriter(HTMLtmp);
+	TextFile.Write(HTML);
+	TextFile.Close();
+
+	PathToChromium = """" + PathToChromium + """";
+	Args = " --headless --disable-gpu --run-all-compositor-stages-before-draw --no-sandbox --print-to-pdf=" + PDFtmp + " " + HTMLtmp;
+
+	Try
+		RunApp(PathToChromium + Args, , True);
+		Result.BinaryData = New BinaryData(PDFtmp);
+	Except 
+		Result.Error = R().Error_CreatingPDF + Chars.LF + ErrorProcessing.DetailErrorDescription(ErrorInfo());
+	EndTry;
+
+	DeleteFiles(HTMLtmp);
+	DeleteFiles(PDFtmp);
+
+	Return Result;
+
+EndFunction
+
+// Get path to chromium.
+// 
+// Returns:
+//  String - Get path to chromium
+Function GetPathToChromium()
+	// On the server side, the path can be set as Constant, 
+	// but on the client side, the paths may differ.
+	// Let's try to find it by enumeration.
+
+	PossiblePaths = New Array; // Array of String
+	PossiblePaths.Add("C:\Program Files\Google\Chrome\Application\chrome.exe");
+	PossiblePaths.Add("C:\Program Files (x86)\Microsoft\Edge\Application\msedge.exe");
+	PossiblePaths.Add("C:\Program Files\Chromium\Application\chrome.exe");
+	PossiblePaths.Add("C:\Program Files (x86)\Chromium\Application\chrome.exe");
+	PossiblePaths.Add("C:\Chromium\Application\chrome.exe");
+
+	For Each Path In PossiblePaths Do
+		PathFile = New File(Path);
+		If PathFile.Exists() Then
+			Return Path;
+		EndIf;
+	EndDo;
+
+	Return "";
+EndFunction

IRP/src/CommonModules/PDFFunctionsClientServer/PDFFunctionsClientServer.mdo

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<mdclass:CommonModule xmlns:mdclass="http://g5.1c.ru/v8/dt/metadata/mdclass" uuid="94100865-4629-4766-a4b1-bf122434924f">
+  <name>PDFFunctionsClientServer</name>
+  <synonym>
+    <key>en</key>
+    <value>PDF functions client server</value>
+  </synonym>
+  <clientManagedApplication>true</clientManagedApplication>
+  <server>true</server>
+  <externalConnection>true</externalConnection>
+  <clientOrdinaryApplication>true</clientOrdinaryApplication>
+</mdclass:CommonModule>

IRP/src/CommonModules/PictureViewerClient/Module.bsl

@@ -218,9 +218,7 @@ Procedure SetPDFForView(FileRef, PDFViewer) Export
 	URI = GetPictureURL(PictureParameters); //String
 	BD = GetFromTempStorage(URI); // BinaryData
 	If Not BD = Undefined Then
-		BDB = GetBinaryDataBufferFromBinaryData(BD);
-		MemoryStream = New MemoryStream(BDB); 
-		PDFViewer.ReadAsync(MemoryStream);
+		PDFFunctionsClientServer.SetDataInPDFViewer(PDFViewer, BD, True);
 	Else
 		CommonFunctionsClientServer.ShowUsersMessage(R().InfoMessage_040);
 	EndIf;

IRP/src/Configuration/Configuration.mdo

@@ -956,6 +956,7 @@
   <commonModules>CommonModule.DocIncomingExchRateAdjustmentInvoiceServer</commonModules>
   <commonModules>CommonModule.DocOutgoingExchRateAdjustmentInvoiceClient</commonModules>
   <commonModules>CommonModule.DocOutgoingExchRateAdjustmentInvoiceServer</commonModules>
+  <commonModules>CommonModule.PDFFunctionsClientServer</commonModules>
   <commonAttributes>CommonAttribute.Author</commonAttributes>
   <commonAttributes>CommonAttribute.Branch</commonAttributes>
   <commonAttributes>CommonAttribute.Comment</commonAttributes>

IRP/src/DataProcessors/AttachedFilesToDocumentsControl/Forms/Form/Module.bsl

@@ -1013,14 +1013,6 @@ Procedure WriteOtherAttachmentInput(Structure)
 
 EndProcedure
 
-&AtClient
-Function IsPDF(FileRef)
-
-	Extension = CommonFunctionsServer.GetRefAttribute(FileRef, "Extension"); // String
-	Return Not StrCompare(Extension, "pdf");
-
-EndFunction
-
 &AtClient
 Procedure CurrentFilesTableSelection(Item, SelectedRow, Field, StandardProcessing)
 
@@ -1030,7 +1022,7 @@ Procedure CurrentFilesTableSelection(Item, SelectedRow, Field, StandardProcessin
 	Structure.Insert("FileRef", FileRef);
 	Structure.Insert("Title", StrTemplate("%1", FileRef));
 	Structure.Insert("Description", "");
-	Structure.Insert("IsPdf", IsPDF(FileRef));
+	Structure.Insert("IsPdf", PDFFunctionsClientServer.IsPDF(FileRef));
 	OpenForm("DataProcessor.AttachedFilesToDocumentsControl.Form.PictureViewer", Structure, , , , , ,FormWindowOpeningMode.LockOwnerWindow);
 
 EndProcedure