src/CMakeLists.txt: modernize CMake build system and fix package config

src/CMakeLists.txt

@@ -57,59 +57,99 @@ set_target_properties(zoe PROPERTIES
 
 target_include_directories(zoe
 	PUBLIC $<BUILD_INTERFACE:${CMAKE_SOURCE_DIR}/include>
-	PUBLIC $<INSTALL_INTERFACE:../include>
+	PUBLIC $<INSTALL_INTERFACE:include>
 )
 
 # CURL
 find_package(CURL REQUIRED)
-if(ZOE_BUILD_SHARED_LIBS)	
-	target_link_libraries(zoe PRIVATE ${CURL_LIBRARIES})
-else()
-	target_link_libraries(zoe PUBLIC ${CURL_LIBRARIES})
-endif()
-
-target_include_directories(zoe PRIVATE ${CURL_INCLUDE_DIRS})
+target_link_libraries(zoe PRIVATE CURL::libcurl)
 
 # OpenSSL
 find_package(OpenSSL)
+
 if(OpenSSL_FOUND)
+	target_link_libraries(zoe PRIVATE OpenSSL::SSL)
 	target_compile_definitions(zoe PRIVATE WITH_OPENSSL)
+endif()
 
-	if(ZOE_BUILD_SHARED_LIBS)	
-		target_link_libraries(zoe PRIVATE OpenSSL::SSL OpenSSL::Crypto)
+set(ZOE_REQUIRES "libcurl")
+if(OpenSSL_FOUND)
+	string(APPEND ZOE_REQUIRES " libssl")
+endif()
+
+set(ZOE_LIBS "")
+set(ZOE_PRIVATE_LIBS "")
+set(ZOE_LIB_NAME "$<TARGET_FILE_BASE_NAME:zoe>")
+
+if (WIN32)
+    target_link_libraries(zoe PRIVATE ws2_32 crypt32)
+    if(ZOE_BUILD_SHARED_LIBS)
+        set(ZOE_PRIVATE_LIBS "${ZOE_PRIVATE_LIBS} -lws2_32 -lcrypt32")
 	else()
-		target_link_libraries(zoe PUBLIC OpenSSL::SSL OpenSSL::Crypto)
-	endif()
+		set(ZOE_LIBS "${ZOE_LIBS} -lws2_32 -lcrypt32")
+    endif()
 endif()
 
+set(THREADS_PREFER_PTHREAD_FLAG TRUE)
+find_package(Threads)
+target_link_libraries(zoe PRIVATE Threads::Threads)
 
-if (WIN32 OR _WIN32)
-	if(ZOE_BUILD_SHARED_LIBS)
-		target_link_libraries(zoe PRIVATE Ws2_32.lib Crypt32.lib)
+if(CMAKE_USE_PTHREADS_INIT)
+    if(ZOE_BUILD_SHARED_LIBS)
+        set(ZOE_PRIVATE_LIBS "${ZOE_PRIVATE_LIBS} -pthread")
 	else()
-		target_link_libraries(zoe PUBLIC Ws2_32.lib Crypt32.lib)
-	endif()
+		set(ZOE_LIBS "${ZOE_LIBS} -pthread")
+    endif()
 endif()
 
 install(TARGETS zoe
-        EXPORT zoeConfig
-        RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
-        LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
-        ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
-        OBJECTS DESTINATION ${CMAKE_INSTALL_LIBDIR}
+		EXPORT zoeTargets
+		RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
+		LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
+		ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
+		OBJECTS DESTINATION ${CMAKE_INSTALL_LIBDIR}
 )
 
 install(DIRECTORY ../include/zoe DESTINATION include)
 
-install(EXPORT zoeConfig
-    NAMESPACE zoe::
-    DESTINATION share/zoe
+install(EXPORT zoeTargets
+	NAMESPACE zoe::
+	DESTINATION share/zoe
+)
+
+configure_file(
+	"${PROJECT_SOURCE_DIR}/zoe.pc.in"
+	"${CMAKE_CURRENT_BINARY_DIR}/zoe.pc.in.configured"
+  @ONLY
+)
+
+file(GENERATE
+	OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/zoe.pc"
+    INPUT "${CMAKE_CURRENT_BINARY_DIR}/zoe.pc.in.configured"
+)
+
+install(FILES
+	"${CMAKE_CURRENT_BINARY_DIR}/zoe.pc"
+	DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig"
 )
 
 include(CMakePackageConfigHelpers)
+
+configure_package_config_file(zoeConfig.cmake.in
+	${CMAKE_CURRENT_BINARY_DIR}/zoeConfig.cmake
+	INSTALL_DESTINATION share/zoe
+	NO_SET_AND_CHECK_MACRO
+	NO_CHECK_REQUIRED_COMPONENTS_MACRO
+)
+
 write_basic_package_version_file(
-    zoeConfigVersion.cmake
-    VERSION ${PROJECT_VERSION}
-    COMPATIBILITY AnyNewerVersion
+	zoeConfigVersion.cmake
+	VERSION ${PROJECT_VERSION}
+	COMPATIBILITY AnyNewerVersion
+)
+
+install(FILES
+	${CMAKE_CURRENT_BINARY_DIR}/zoeConfig.cmake
+	${CMAKE_CURRENT_BINARY_DIR}/zoeConfigVersion.cmake
+	DESTINATION share/zoe
 )
-install(FILES ${CMAKE_CURRENT_BINARY_DIR}/zoeConfigVersion.cmake DESTINATION share/zoe)

zoe.pc.in

@@ -0,0 +1,15 @@
+prefix=@CMAKE_INSTALL_PREFIX@
+exec_prefix=${prefix}
+libdir=${exec_prefix}/@CMAKE_INSTALL_LIBDIR@
+includedir=${prefix}/include
+
+Name: @PROJECT_NAME@
+Description: A high-performance C++ file download library.
+URL: https://github.com/winsoft666/zoe
+Version: @PROJECT_VERSION@
+Conflicts:
+Libs: -L${libdir} -l@ZOE_LIB_NAME@ @ZOE_LIBS@
+Libs.private: @ZOE_PRIVATE_LIBS@
+Cflags: -I${includedir}
+Requires:
+Requires.private: @ZOE_REQUIRES@

zoeConfig.cmake.in

@@ -0,0 +1,12 @@
+@PACKAGE_INIT@
+
+if(NOT "@ZOE_BUILD_SHARED_LIBS@")
+    include(CMakeFindDependencyMacro)
+    find_dependency(CURL)
+    if("@OpenSSL_FOUND@")
+        find_dependency(OpenSSL)
+    endif()
+    find_dependency(Threads)
+endif()
+
+include("${CMAKE_CURRENT_LIST_DIR}/zoeTargets.cmake")